Google TTS

//Google TTS by Szymekk
client {
    string language = "en"

    int selected = 1

    netReceive("chatmsg", function(netstream st) {
        playURL("http://translate.google.com/translate_tts?tl="+language+"&q=" + st.readString(),"",function(audio a) {
            a.play()
        }, function() {})
    })

    function bool GetMouseOn(vector2 pos, vector2 size) {
        return (localPlayer().getScreenCursor()>pos && (localPlayer().getScreenCursor()<(pos+size)))
    }

    event drawScreen(int w, int h) {
        string title =  "Google TTS"
        string line1 =  "Changes chat text to speech"
        string help1 =  "Open context menu by pressing 'c'"
        string help2 =  "Click on this screen by right mouse button"
        string help3 =  "EA2 -> Enable URL sounds"

        string last =  "Have fun!"

        setDrawColor(color(255,255,255))
        drawBox(vec2(0,0),vec2(w,h))
        setFontColor(color(0,150,255))
        setFont("Trebuchet24",64)
        drawText(vec2(h/2-getTextWidth(title)/2,5), title)
        setFont("Trebuchet24",32)
        drawText(vec2(h/2-getTextWidth(line1)/2,80), line1)

        setFont("Trebuchet24",32)
        drawText(vec2(h/2-getTextWidth(help1)/2,200), help1)
        drawText(vec2(h/2-getTextWidth(help2)/2,232), help2)
        drawText(vec2(h/2-getTextWidth(help3)/2,264), help3)

        drawText(vec2(h/2-getTextWidth(last)/2,364), last)

        if(selected==1)
            setDrawColor(color(50,150,250))
        else
            setDrawColor(color(200,200,200))
        drawBox(vec2(0,128),vec2(h/3,64))

        if(selected==2)
            setDrawColor(color(50,150,250))
        else
            setDrawColor(color(200,200,200))
        drawBox(vec2(h/3,128),vec2(h/3,64))

        if(selected==3)
            setDrawColor(color(50,150,250))
        else
            setDrawColor(color(200,200,200))
        drawBox(vec2(h-h/3-1,128),vec2(h/3+2,64))

        setFont("Trebuchet24",64)
        setFontColor(color(255,255,255))

        drawText(vec2(0,124), "English")

        setFont("Trebuchet24",48)
        drawText(vec2(h/3+4,134), "American")

        setFont("Trebuchet24",64)
        drawText(vec2(h-h/3+16,124), "Polish")
    }

    event enableSoundsFromURL() {
        netstream nst = stream()
        nst.writeString(localPlayer().name())
        nst.sendToServer("enabled")
    }

    event tick() {
        if(GetMouseOn(vec2(0,128),vec2(512/3,64)) && localPlayer().keyUse()) {
            selected = 1
            language = "en"
        }
        if(GetMouseOn(vec2(512/3,128),vec2(512/3,64)) && localPlayer().keyUse()) {
            selected = 2
            language = "en_us"
        }
        if(GetMouseOn(vec2(512-512/3-1,128),vec2(512/3+2,64)) && localPlayer().keyUse()) {
            selected = 3
            language = "pl"
        }
    }
}
server {
    event playerChat(player pl, string s) {
        netstream nst = stream()
        nst.writeString(s)
        nst.netBroadcast("chatmsg")
    }

    netReceive("enabled", function(netstream st) {
        print(st.readString() + " has enabled Google TTS")
    })
}