Codex Companion (UO Pangaea Necromancer Hotkeys)

;==================================
; Script Name: Codex Companion
; Author: Callum O'Lyre
; ICQ: 625-658-845
; Version: 1.0
; Shard: Pangaea
; Public Release: 15.10.2012
; Purpose: To be able to cast Necro Chants by name instead of having
;          to remember their power words. Very similar to my Basic
;          Cleric Hotkey Macro
;=================
; Now enjoy some documentation regarding onhotkey and the many different ways you can
; Hotkey buttons.
;
; The onHotKey command performs the following line of code (brackets do NOT work) when a certain key is pressed.
; The key-specifier can either be A-Z, 0-9, F1-F12 and ESC, BACK, TAB, ENTER, PAUSE, CAPSLOCK, SPACE, PGDN, PGUP,
; END, HOME, LEFT, RIGHT, UP, DOWN, PRNSCR, INSERT, DELETE, NUMLOCK or SCROLLLOCK.
;
; onHotKey {key-specifier} {[alt] | [ctrl] | [shift]}
;
; Ex: onhotkey t alt
;==================================
While #true
{
 onhotkey F1
  {
   GoSub CastNecroChant Darkness
  }
 onhotkey F1 SHIFT
  {
   GoSub CastNecroChant Commune
  }
 onhotkey F2
  {
   GoSub CastNecroChant Spectre'sTouch
  }
 onhotkey F3
  {
   GoSub Meditate
  }
}

;GoSub CastNecroChant <ChantName>
;ChantNames:
;Darkness, Commune, AnimateDead, ControlUndead, Sacrifice
;Spectre'sTouch, Wraith'sBreath, FrostRing, Kill, RaiseDead
;Wraithform, Release, Transfusion, SummonSpirit, Lich, Plague
Sub CastNecroChant
set !lpc #lpc
set #lpc 1000

if %1 = Darkness
 msg Nox $

if %1 = Commune
 msg Dice $

if %1 = AnimateDead
 msg Corpus Sine Nomine Expergefaceret $

if %1 = ControlUndead
 msg Nutu Magistri Supplicare $

if %1 = Sacrifice
 msg Animus Ex Corporis Resolveretur $

if %1 = Spectre'sTouch
 msg Enervare $

if %1 = Wraith'sBreath
 msg Manes Sollicti Mi Compellere $

if %1 = FrostRing
 msg Umbrae Tenebrae Venarent $

if %1 = Kill
 msg Ulties Manum Necarent $

if %1 = RaiseDead
 msg Manes Turbidi Sollictique Vocam $

if %1 = Wraithform
 msg Manes Sollicti Mihi Infundite $

if %1 = Release
 msg Nutu Magistri Se Resolvere $

if %1 = Transfusion
 msg Nutu Magistri Se Compellere $

if %1 = SummonSpirit
 msg Manes Turbidi Sollictique Resolverent $

if %1 = Lich
 msg Umbrae Tenebrae Miserere Animi Non Digna Ferentis $

if %1 = Plague
 msg Fluctus Puter Se Aresceret $

set #lpc !lpc
return

;GoSub Meditate
;Optional param to send, FMC will return from sub only when you are full mana, useful for if you
;are using in a macro where you need to be done with meditation before proceeding onto another
;action, inscription comes to mind, casting spells also would be another reason.
Sub Meditate
set !lpc #lpc
set #lpc 1000
event Macro 13 46

set %jrnl #jindex
while #true
 {
  if #jindex > %jrnl
   {
    set %jrnl %jrnl + 1
    scanjournal %jrnl
    if #charname , :_I_am_already_performing in #journal
     {
      wait 2s
      event Macro 13 46
     }
    if You_are_at_peace. in #journal
     {
      Event Sysmessage Silly Mana User! You are at full mana
      return
     }
    if to_concentrate in #journal
     {
      wait 30s
      event Macro 13 46
     }
    if Meditating in #journal
     {
      Set #lpc !lpc
      if %1 = FMC
       {
        While #MANA <> #MAXMANA
         {
          onhotkey ESC
           {
            Event Sysmessage Stopping Mana Monitoring.
            return MMStop
           }
         }
        return
       }
      return
     }
   }
 }