Fate/Stay Night Realta Nua Selector Script

@echo off
:: Timeout before last selection is used, in seconds
set TIMEOUT=4
:: Path to Fate executable (ASCII characters only)
set FATEPATH="Fate stay night[Realta Nua] -Fate-\Fate stay night[Realta Nua] -Fate-.exe"
:: Path to UBW executable (ASCII characters only)
set UBWPATH="Fate stay night[Realta Nua] -Unlimited Blade Works-\Fate stay night[Realta Nua] -Unlimited Blade Works-.exe"
:: Path to HF executable (ASCII characters only)
set HFPATH="Fate stay night[Realta Nua] -Heaven's Feel-\Fate stay night[Realta Nua] -Heaven's Feel-.exe"

if exist lastchoice.txt set /p default=< lastchoice.txt
echo. & echo Choose which title to launch.  After %TIMEOUT% seconds either the last used selection will be chosen, or Fate if this is the first time running this script.
echo.
echo 1) Fate
echo 2) Unlimited Blade Works
echo 3) Heaven's Feel
echo.
if "%default%" == "1" (
    echo Previous Selection: Fate
) else (if "%default%" == "2" (
    echo Previous Selection: Unlimited Blade Works
) else (if "%default%" == "3" (
    echo Previous Selection: Heaven's Feel
) else (
    set default=1
)))
choice /c 123 /n /t %TIMEOUT% /d %default% /m Selection:
if %ERRORLEVEL% == 1 (
    (echo %ERRORLEVEL%)> lastchoice.txt
    start "" %FATEPATH%
) else (if %ERRORLEVEL% == 2 (
    (echo %ERRORLEVEL%)> lastchoice.txt
    start "" %UBWPATH%
) else (if %ERRORLEVEL% == 3 (
    (echo %ERRORLEVEL%)> lastchoice.txt
    start "" %HFPATH%
)))