ESCAPEMAN - TIbasic z80 - Game by Wistaro

//By Wistaro - (c) Février 2015
//Forum link dedicated to this game: http://tiplanet.org/forum/viewtopic.php?f=11&t=16046

Lbl A
AxesOff:Full
0->Xmin:0->Ymin
1->DeltaX:1->DeltaY
ClrDraw:ClrHome
For(A,20,71,3
Text(18,A,"X
Text(32,A,"X
End
For(A,26,42,2
Pt-On(17,A,2
Pt-On(76,A,2
End
StorePic 1
Text(~1,25,20,"EscapeMan
For(A,0,24,2
Pt-On(29,A,2
Pt-On(64,A,2
End
Line(16,25,0,0
Line(77,43,94,62
Line(77,25,94,0
Line(16,43,0,62
Text(12,50,"Wistaro


Repeat K=45
getKey->K
If K=92:Goto J
If K=93:Goto O
Text(42,33,"1 - Play
Text(52,33,"2 - Exit
End:ClrHome:ClrDraw:Stop
Lbl J:
DelVar |LB:8->dim(|LB:1->|LB(8
Lbl C:ClrDraw
5->|LB(5:5->|LB(6

DelVar [H]:{8,16->dim([H]
DelVar L1DelVar L2seq(A,A,0,93,6)->L1
seq(B,B,0,57,7->L2
"    LOADING..."->Str1
RecallPic 1
Text(~1,25,20,"Level *",|LB(8
For(A,5,14
Text(57,85,int((100*A)/144
Text(L2(9),L1(A),sub(Str1,A,1)
End
9->P
For(A,1,8
For(B,1,16
P+1->P
Text(57,85,int((100*P)/140
randInt(0,10->E
If E<=5:1->D
If E>5 and E<8:0->D
If E>=8:2->D
randInt(0,8->X
If X>=0 and X<5:0->Z
If X=5:.1->Z
If X=6:.2->Z
If X=7:.3->Z
If X=8:.4->Z
If D:D+Z->[H](A,B
End
End
For(A,1,3
Text(57,85,int((100*(P+A))/140
0->[H](1,A
0->[H](2,A
0->[H](8,17-A
End
"thetaO"->Str1
ClrDraw
For(A,1,8
For(B,1,16
If [H](A,B:Text(L2(A),L1(B),sub(Str1,iPart([H](A,B)),1
End:End
DelVar SDelVar T
Lbl T
Line(0,6,74,6
Line(74,6,74,0
Line(81,0,81,12
Line(81,12,91,12
Line(91,12,91,0
Pt-On(84,6,3
1->V:1->W
DelVar theta
Repeat K=45 or |LB(5)<=0 or theta
getKey->K
If V=8 and W>=15:1->theta
If K=105:Then
2+int(|LB(6)/2)->|LB(7
|LB(7->|LB(1
V->|LB(2:W->|LB(3
3+fPart([H](V,W))->[H](V,W
End
If |LB(1)=1:Then
int(|LB(6)/3)+|LB(8->|LB(4
|LB(4->H
|LB(2->S
|LB(3->T
0->|LB(1
"L+M?"->Str3
If T<=H:T-1->H
|LB(4->I
If T>=17-I:16-T->I
For(A,T-H,T+I
If S=V and A=W:|LB(5)-1->|LB(5
If |LB(6)>=10 or iPart([H](S,A))!=2:Then
Text(L2(S),L1(A),"X
fPart([H](S,A->[H](S,A
If Ans!=0:Then
sub(Str3,fPart([H](S,A))*10,1->Str4
Else
"    "->Str4
End
Text(L2(S),L1(A),Str4
End:End
|LB(4->H
If S<=H:S-1->H
|LB(4->I
If S>=8-I:8-S->I
For(A,S-H,S+I
If A=V and T=W:|LB(5)-1->|LB(5
If iPart([H](A,T))!=2 or |LB(6)>=10:Then
Text(L2(A),L1(T),"X
fPart([H](A,T->[H](A,T
If Ans!=0:Then
sub(Str3,fPart([H](A,T))*10,1->Str4
Else
"    "->Str4
End
Text(L2(A),L1(T),Str4
End
End
Text(L2(S),L1(T),"   "
End
If |LB(1)>0:Text(L2(|LB(2)),L1(|LB(3)),"B
If K=22:Then
ClrHome
End
If K:Text(L2(V),L1(W),"   "
If fPart([H](V,W:Then
10fPart([H](V,W->Z
0->Y
If Z=4:randInt(1,3+|LB(8->Y
If Z=1 or Y=1:1+|LB(5->|LB(5
If Z=2 or Y=2:1+|LB(6->|LB(6
If Z=3 or Y=3:|LB(5)-randInt(1,2|LB(8->|LB(5
If Y>=4:|LB(5)-1->|LB(5
0->[H](V,W
End

Text(57,0,"V: ",|LB(5)," - XP: ",|LB(6)," - LvL: ",|LB(8
If W<16:Then
iPart([H](V,W+1:W+(K=26 and not(Ans->W
End
If V<8:Then
iPart([H](V+1,W:V+(K=34 and not(Ans->V
End
If W>1:Then
iPart([H](V,W-1:W-(K=24 and not(Ans->W
End
If V>1:Then
iPart([H](V-1,W:V-(K=25 and not(Ans->V
End
If |LB(1)>0:|LB(1)-1->|LB(1
Text(L2(V),L1(W),"[e]
End
If theta:Then
|LB(8)+1->|LB(8
Text(57,0,"Bravo! LvL suivant...
Pause
Goto C
End
For(A,62,7,~1
Line(0,A,94,A,0
End
For(A,6,0,~1
Line(81,A,91,A,0
End
Text(57,0,"Helas, tu as perdu...
Pause :Goto A
Lbl O
DelVar [H]DelVar L1DelVar |LBDelVar L2
ClrDraw:ClrHome
Disp "