ATTACK OF THE AARDVARKS 64

100 print"{CLR}":s=54272:fori=0to24:pokes+i,0:next:s1=s+7:s2=s+14:pokes+24,15
110 poke53280,2:poke53281,14:gosub720
120 print"{CLR}{2 DOWN}{BLK} instructions (y/n)?"
130 getg$:ifg$=""then130
140 ifg$="y"thengosub880
150 print"{CLR}"spc(9)"{DOWN}{BLK}{RVS}   aardvark  attack   "
160 printspc(10)"{2 DOWN}{WHT}alphanumeric weapons"
170 printspc(14)"{4 DOWN}{WHT}which level?":printspc(10)"{DOWN}{BLK}(1:novice  9:expert)"
180 gethf$:ifhf$<"1"orhf$>"9"then180
190 hf=int(2.5^(9-val(hf$)))
200 sc=0:gosub790
210 :
220 rem new letter
230 gosub820:poke56334,peek(56334)and254:poke1,peek(1)and251
240 fori=0to3:forj=0to3:c(i,j)=0:next:next
250 l=int(rnd(1)*26+1):b=53248+l*8:f=0
260 fori=0to3
270 f=abs(f-1):t=peek(b+2*i+1-f)
280 forj=0to3:m=(fnm(j)andt)/(4^j):c(i,j)=c(i,j)+int(m*(4^f)):next
290 iffthen270
300 next:poke1,peek(1)or4:poke56334,peek(56334)or1
310 :
320 rem flashing
330 pokes+5,0:pokes+6,240:pokes,0:pokes+1,0:pokes+4,33
340 fory=1to70:z=int(rnd(1)*10):zz=1037+z:pokezz+54272,1:pokezz,160
350 pokes+1,rnd(1)*15+10:pokezz+54272,0:next:pokes+4,8
360 fori=0to3:forj=0to3:poke1135-j+40*i,s(c(i,j)):next:next
370 lf=0:fh=0:sh=0
380 :
390 rem start attack
400 pokes1+5,0:pokes1+6,240:pokes1,0:pokes1+1,0:pokes1+4,17:poke198,0
410 forx=1to18:pokes1+1,(19-x)*7
420 getg$:ifg$=""then480
430 iflfthen460
440 if(asc(g$)-64)<>lthen480
450 lf=1:fh=x:n=s:gosub1010
460 ifval(g$)-1<>zand(g$<>"0"orz<>9)then480
470 sh=x:poke198,0:goto590
480 fory=1tohf:next:poke(1037+z+x*40),81+lf*128:next:pokes1+4,8
490 :
500 rem lose round
510 poke198,0:n=s2:gosub1010:fori=2to18:poke53280,iand15:next
520 forxx=0to3:pb=(1797+z+(40*xx)):ifpeek(pb)<>32then540
530 next:goto620
540 ifxx=3orlfthen560
550 pokepb+40,32
560 pokepb,32:goto230
570 :
580 rem scoring
590 n=s2:gosub1010:pokes1+4,8:sc=sc+int((500-5*fh-2*sh)/sqr(fh)):goto230
600 :
610 rem lose routine
620 fory=1to100:poke53280,rnd(1)*255:poke53281,rnd(1)*255:next
630 poke53280,2:poke53281,14:print"{CLR}{DOWN}{BLK}";:fori=1to38:print"*";:next
640 printspc(12)"{DOWN}{WHT}sorry, you lost."
650 printspc(13)"{3 DOWN}{BLU}your score";sc
660 printspc(15)"{DOWN}at level ";hf$
670 printspc(11)"{3 DOWN}{BLK}play again (y/n)?"
680 gety$:ify$=""then680
690 ify$="n"thenprint"{CLR}":end
700 goto150
710 :
720 dims(15),c(3,3)
730 deffnm(x)=3*(4^x)
740 forx=0to15:reads(x):next:return
750 data32,108,123,98,124,225,255,254
760 data126,127,97,252,226,251,236,160
770 :
780 rem screens
790 print"{CLR}"
800 poke214,18:print:printspc(10)"{BLK}{[Q]}  1234567890  {[W]} level "hf$
810 forx=1to4:printspc(10)"{[Q]}  {BLU}{RVS}          {OFF}{BLK}  {[W]}":next
820 print"{HOME}"spc(10)"{BLK}{[Q]}  {RED}**********  {BLK}{[W]}"
830 print"{HOME}":fori=1to6:printspc(27)"[RED}{RVS}    ":next
840 print"{HOME}{DOWN}":fori=1to4:printspc(28)"{BLK}{RVS}   ":next
850 print"{HOME}":fori=1to18:printspc(10)"{BLK}{[Q]}  {CYN}          {BLK}  {[W]}":next
860 poke214,16:print:printspc(27)"score"sc:return
870 :
880 rem instructions
890 print"{CLR}{DOWN}{BLK} ";:fori=1to38:print"*";:next:print
900 print"[DOWN]andromedan aardvarks are attacking earth"
910 printspc(6)"{DOWN}{WHT}they have 26 kinds of bombs":printspc(18)"{DOWN}and"
920 printspc(6)"{DPWN}they're attacking 10 cities!"
930 print"{3 DOWN}{BLK}your alphanumeric radar can save earth"
940 printspc(4)"{3 DOWN}{WHT}first: recognize the bomb (a-z)"
950 printspc(7)"{DOWN}then: save the city (0-9)"
960 printspc(9)"{2 DOWN}{BLK}{RVS}hit any key to play"
970 getg$:ifg$=""then970
980 return
990 :
1000 rem explosion
1010 poken+5,37:poken+6,252:poken,100:poken+1,5:poken+4,129:poken+4,128
1020 return