lib32-gconf.PKGBUILD

# Maintainer: dedoz      <d3d0zz@gmail.com>
# Contributor: josephgbr <rafael.f.f1@gmail.com>

_pkgbase=gconf
pkgname=lib32-${_pkgbase}-nogtk-nopolkit-noldap
pkgver=3.2.6
pkgrel=1
pkgdesc="A configuration database system (32 bit), highly stripped version"
arch=('x86_64')
license=('LGPL')
url="http://www.gnome.org"
depends=('lib32-libxml2' 'lib32-dbus-glib'  "${_pkgbase}")
makedepends=('intltool' 'gcc-multilib' 'gobject-introspection') #gtk-doc
provides=("lib32-gconf")
replaces=('lib32-gconf')
options=('!libtool')
install=${_pkgbase}.install
source=(http://ftp.gnome.org/pub/gnome/sources/GConf/3.2/GConf-${pkgver}.tar.xz
        gconf-reload.patch
        01_xml-gettext-domain.patch)
sha256sums=('1912b91803ab09a5eed34d364bf09fe3a2a9c96751fde03a4e0cfa51a04d784c'
            '567b78d8b4b4bbcb77c5f134d57bc503c34867fcc6341c0b01716bcaa4a21694'
            'c883dec2b96978874a53700cfe7f26f24f8296767203e970bc6402b4b9945eb8')

build() {
  export CC='gcc -m32'
  export CXX='g++ -m32'
  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'

  cd GConf-${pkgver}

  # Patch from fedora - reloads gconf after installing schemas
  patch -Np1 -i "${srcdir}"/gconf-reload.patch
  # http://bugzilla.gnome.org/show_bug.cgi?id=568845
  patch -Np1 -i "${srcdir}"/01_xml-gettext-domain.patch

  # Python2 fix
  sed -i '1s|#!/usr/bin/env python$|&2|' gsettings/gsettings-schema-convert

  ./configure \
  	--prefix=/usr --sysconfdir=/etc --localstatedir=/var \
	--disable-defaults-service --without-openldap --disable-static --disable-orbit \
	--disable-gtk --disable-gsettings-backend --libdir=/usr/lib32 --libexecdir=/usr/lib32/GConf \
	--disable-gtk-doc

  make pkglibdir=/usr/lib32/GConf
}

package() {
  make -C GConf-${pkgver} DESTDIR="${pkgdir}" install
  rm -rf "${pkgdir}"/{etc,usr/{bin,include,share}}
}