Curved World vert shader

#version 120
#extension GL_EXT_texture_array : require
#extension GL_EXT_texture_array : enable
//curved world feature/effect; https://forum.blockland.us/index.php?topic=77967.msg7787623#msg7787623
bool curveTheWorld = true;
bool curveDirectionDown = true;
//adjust the effect
float curvePower = 2.0f; //exponential curve
float curveScale = 0.02f; //'fisheye factor', note that high values make lights higher than their real position

// Varying.
varying vec4 vPos;
varying vec3 worldNormal;
varying vec3 worldPos;

// Misc uniforms.
uniform vec3 camPos;
uniform mat4 obj2World;
uniform mat4 world2Cam;

// Surface calculations, including specular power.
varying vec2 texCoord;
vec4 viewDelta;

// Fogging.
uniform vec4 fogBaseColor;
uniform vec4 fogConsts;
uniform sampler2D fogTex;
varying vec2 fogCoords;

void main()
{
    // Bricks always in world space.
    worldPos = (obj2World * vec4(gl_Vertex.xyz, 1.0f)).xyz;
    worldNormal = ((obj2World * vec4(gl_Normal.xyz, 0.0f)).xyz);

    if(length(gl_Normal.xyz) < 1.1f)
        worldNormal.xyz = normalize(worldNormal.xyz);

    // Do some camera delta math.
    viewDelta.xyz = worldPos - camPos;
    viewDelta.w   = length(viewDelta.xyz);
    viewDelta.xyz = -normalize(viewDelta.xyz);

    // Fog can be done per-vertex.
    fogCoords.x = clamp((fogConsts.y - viewDelta.w) * fogConsts.x, 0.0f, 1.0f);
    fogCoords.y = clamp((worldPos.z - fogConsts.z) * fogConsts.w, 0.0f, 1.0f);

    // Project the brick pos and normal.
    vPos = world2Cam * vec4(worldPos, 1.0f);

    if (curveTheWorld)
    {
        if (curveDirectionDown)
            worldPos.z -= pow(viewDelta.w * curveScale, curvePower);
        else
            worldPos.z += pow(viewDelta.w * curveScale, curvePower);
        gl_Position = gl_ProjectionMatrix * world2Cam * vec4(worldPos, 1.0f);
    }
    else
    {
        gl_Position = gl_ProjectionMatrix * vPos;
    }

    // Pass color through.
    gl_FrontColor = gl_Color;

    // Pass texcoords through.
    texCoord = gl_MultiTexCoord0.st;
}