Advertisement
Not a member of Pastebin yet?
Sign Up,
it unlocks many cool features!
- 0 REM READ STRINGS
- 5 DIM A$(100) : DIM LP$(2) : DIM BP$(3)
- 6 LP$(0) = "." : LP$(1) = "!" : LP$(2) = "..." : BP$(0) = "," : BP$(1) = ";"
- 7 BP$(2) = "--" : BP$(3) = ":"
- 8 DIM V(3) : DIM V$(3)
- 10 OPEN 1,1,0,"IntrospectiveVerse"
- 20 GET#1, S$
- 25 IF ASC(S$) < 32 THEN I = I + 1
- 30 IF ASC(S$) >= 32 THEN A$(I) = A$(I) + S$
- 40 IF ST = 0 THEN GOTO 20
- 50 CLOSE 1 : T = I
- 60 REM CONSTRUCT POEM
- 70 FOR I = 0 TO 3
- 75 V(I) = INT(RND(0)*T)
- 80 IF I = 0 THEN GOTO 110
- 90 FOR J = 0 TO I-1
- 95 IF V(J) = V(I) THEN F = -1
- 100 NEXT J : IF F = -1 THEN F = 0 : GOTO 75
- 110 V$(I) = A$(V(I))
- 120 NEXT I
- 130 REM ADD PUNCTUATION
- 140 FOR I = 0 TO 3
- 145 IF RND(0) < 0.1 THEN GOTO 190
- 150 IF RND(0) < 0.4 OR I = 3 THEN GOTO 170
- 155 V$(I) = V$(I) + BP$(INT(RND(0)*4))
- 160 GOTO 190
- 170 V$(I) = V$(I) + LP$(INT(RND(0)*3))
- 190 NEXT I
- 200 REM PRINT
- 205 FOR I = 1 TO 5 : PRINT : NEXT I
- 210 FOR I = 0 TO 3 : PRINT V$(I) : NEXT I
- 215 PRINT
- 220 REM RETRY
- 230 GET A$ : IF A$ = "" THEN GOTO 230
- 240 GOTO 60
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement