API tools faq
paste
Advertisement
Guest User

Untitled

a guest
Jul 24th, 2015
96
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
text 14.83 KB | None | 0 0
raw download clone embed print report
  1. TEMPLATE = app
  2. TARGET = PonyCoin-qt
  3. macx:TARGET = "PonyCoin-Qt"
  4. VERSION = 0.8.6.3
  5. INCLUDEPATH += src src/json src/qt
  6. QT += core gui network
  7. greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
  8. DEFINES += QT_GUI BOOST_THREAD_USE_LIB BOOST_SPIRIT_THREADSAFE
  9. CONFIG += no_include_pwd
  10. CONFIG += thread
  11. CONFIG += static
  12.  
  13. # for boost 1.37, add -mt to the boost libraries
  14. # use: qmake BOOST_LIB_SUFFIX=-mt
  15. # for boost thread win32 with _win32 sufix
  16. # use: BOOST_THREAD_LIB_SUFFIX=_win32-...
  17. # or when linking against a specific BerkelyDB version: BDB_LIB_SUFFIX=-4.8
  18.  
  19. # Dependency library locations can be customized with:
  20. # BOOST_INCLUDE_PATH, BOOST_LIB_PATH, BDB_INCLUDE_PATH,
  21. # BDB_LIB_PATH, OPENSSL_INCLUDE_PATH and OPENSSL_LIB_PATH respectively
  22.  
  23. win32 {
  24. BOOST_LIB_SUFFIX=-mgw48-mt-s-1_53
  25. BOOST_INCLUDE_PATH=C:/deps/boost
  26. BOOST_LIB_PATH=C:/deps/boost/stage/lib
  27. BDB_INCLUDE_PATH=C:/deps/db/build_unix
  28. BDB_LIB_PATH=C:/deps/db/build_unix
  29. OPENSSL_INCLUDE_PATH=C:/deps/openssl/include
  30. OPENSSL_LIB_PATH=C:/deps/openssl
  31. MINIUPNPC_INCLUDE_PATH=C:/deps/
  32. MINIUPNPC_LIB_PATH=C:/deps/miniupnpc
  33. }
  34.  
  35. OBJECTS_DIR = build
  36. MOC_DIR = build
  37. UI_DIR = build
  38.  
  39. # use: qmake "RELEASE=1"
  40. contains(RELEASE, 1) {
  41. # Mac: compile for maximum compatibility (10.5, 32-bit)
  42. macx:QMAKE_CXXFLAGS += -mmacosx-version-min=10.5 -arch i386 -isysroot /Developer/SDKs/MacOSX10.5.sdk
  43. macx:QMAKE_CFLAGS += -mmacosx-version-min=10.5 -arch i386 -isysroot /Developer/SDKs/MacOSX10.5.sdk
  44. macx:QMAKE_OBJECTIVE_CFLAGS += -mmacosx-version-min=10.5 -arch i386 -isysroot /Developer/SDKs/MacOSX10.5.sdk
  45.  
  46. !win32:!macx {
  47. # Linux: static link and extra security (see: https://wiki.debian.org/Hardening)
  48. LIBS += -Wl,-Bstatic -Wl,-z,relro -Wl,-z,now
  49. }
  50. }
  51.  
  52.  
  53. # for extra security against potential buffer overflows: enable GCCs Stack Smashing Protection
  54. QMAKE_CXXFLAGS *= -fstack-protector-all
  55. QMAKE_LFLAGS *= -fstack-protector-all
  56. # Exclude on Windows cross compile with MinGW 4.2.x, as it will result in a non-working executable!
  57. # This can be enabled for Windows, when we switch to MinGW >= 4.4.x.
  58.  
  59. # for extra security (see: https://wiki.debian.org/Hardening): this flag is GCC compiler-specific
  60. QMAKE_CXXFLAGS *= -D_FORTIFY_SOURCE=2
  61. # for extra security on Windows: enable ASLR and DEP via GCC linker flags
  62. win32:QMAKE_LFLAGS *= -Wl,--dynamicbase -Wl,--nxcompat
  63. # on Windows: enable GCC large address aware linker flag
  64. win32:QMAKE_LFLAGS *= -Wl,--large-address-aware -static
  65. # i686-w64-mingw32
  66. win32:QMAKE_LFLAGS *= -static-libgcc -static-libstdc++
  67.  
  68. # use: qmake "USE_QRCODE=1"
  69. # libqrencode (http://fukuchi.org/works/qrencode/index.en.html) must be installed for support
  70. contains(USE_QRCODE, 1) {
  71. message(Building with QRCode support)
  72. DEFINES += USE_QRCODE
  73. LIBS += -lqrencode
  74. }
  75.  
  76. # use: qmake "USE_UPNP=1" ( enabled by default; default)
  77. # or: qmake "USE_UPNP=0" (disabled by default)
  78. # or: qmake "USE_UPNP=-" (not supported)
  79. # miniupnpc (http://miniupnp.free.fr/files/) must be installed for support
  80. contains(USE_UPNP, -) {
  81. message(Building without UPNP support)
  82. } else {
  83. message(Building with UPNP support)
  84. count(USE_UPNP, 0) {
  85. USE_UPNP=1
  86. }
  87. DEFINES += USE_UPNP=$$USE_UPNP STATICLIB
  88. INCLUDEPATH += $$MINIUPNPC_INCLUDE_PATH
  89. LIBS += $$join(MINIUPNPC_LIB_PATH,,-L,) -lminiupnpc
  90. win32:LIBS += -liphlpapi
  91. }
  92.  
  93. # use: qmake "USE_DBUS=1"
  94. contains(USE_DBUS, 1) {
  95. message(Building with DBUS (Freedesktop notifications) support)
  96. DEFINES += USE_DBUS
  97. QT += dbus
  98. }
  99.  
  100. # use: qmake "USE_IPV6=1" ( enabled by default; default)
  101. # or: qmake "USE_IPV6=0" (disabled by default)
  102. # or: qmake "USE_IPV6=-" (not supported)
  103. contains(USE_IPV6, -) {
  104. message(Building without IPv6 support)
  105. } else {
  106. count(USE_IPV6, 0) {
  107. USE_IPV6=1
  108. }
  109. DEFINES += USE_IPV6=$$USE_IPV6
  110. }
  111.  
  112. contains(BITCOIN_NEED_QT_PLUGINS, 1) {
  113. DEFINES += BITCOIN_NEED_QT_PLUGINS
  114. QTPLUGIN += qcncodecs qjpcodecs qtwcodecs qkrcodecs qtaccessiblewidgets
  115. }
  116.  
  117. INCLUDEPATH += src/leveldb/include src/leveldb/helpers
  118. LIBS += $$PWD/src/leveldb/libleveldb.a $$PWD/src/leveldb/libmemenv.a
  119. !win32 {
  120. # we use QMAKE_CXXFLAGS_RELEASE even without RELEASE=1 because we use RELEASE to indicate linking preferences not -O preferences
  121. genleveldb.commands = cd $$PWD/src/leveldb && CC=$$QMAKE_CC CXX=$$QMAKE_CXX $(MAKE) OPT=\"$$QMAKE_CXXFLAGS $$QMAKE_CXXFLAGS_RELEASE\" libleveldb.a libmemenv.a
  122. } else {
  123. # make an educated guess about what the ranlib command is called
  124. isEmpty(QMAKE_RANLIB) {
  125. QMAKE_RANLIB = $$replace(QMAKE_STRIP, strip, ranlib)
  126. }
  127. LIBS += -lshlwapi
  128. }
  129. genleveldb.target = $$PWD/src/leveldb/libleveldb.a
  130. genleveldb.depends = FORCE
  131. PRE_TARGETDEPS += $$PWD/src/leveldb/libleveldb.a
  132. QMAKE_EXTRA_TARGETS += genleveldb
  133. # Gross ugly hack that depends on qmake internals, unfortunately there is no other way to do it.
  134. QMAKE_CLEAN += $$PWD/src/leveldb/libleveldb.a; cd $$PWD/src/leveldb ; $(MAKE) clean
  135.  
  136. # regenerate src/build.h
  137. !win32|contains(USE_BUILD_INFO, 1) {
  138. genbuild.depends = FORCE
  139. genbuild.commands = cd $$PWD; /bin/sh share/genbuild.sh $$OUT_PWD/build/build.h
  140. genbuild.target = $$OUT_PWD/build/build.h
  141. PRE_TARGETDEPS += $$OUT_PWD/build/build.h
  142. QMAKE_EXTRA_TARGETS += genbuild
  143. DEFINES += HAVE_BUILD_INFO
  144. }
  145.  
  146. QMAKE_CXXFLAGS_WARN_ON = -fdiagnostics-show-option -Wall -Wextra -Wformat -Wformat-security -Wno-unused-parameter -Wstack-protector
  147.  
  148. # Input
  149. DEPENDPATH += src src/json src/qt
  150. HEADERS += src/qt/bitcoingui.h \
  151. src/qt/transactiontablemodel.h \
  152. src/qt/addresstablemodel.h \
  153. src/qt/optionsdialog.h \
  154. src/qt/sendcoinsdialog.h \
  155. src/qt/coincontroldialog.h \
  156. src/qt/coincontroltreewidget.h \
  157. src/qt/addressbookpage.h \
  158. src/qt/signverifymessagedialog.h \
  159. src/qt/aboutdialog.h \
  160. src/qt/editaddressdialog.h \
  161. src/qt/bitcoinaddressvalidator.h \
  162. src/alert.h \
  163. src/addrman.h \
  164. src/base58.h \
  165. src/bignum.h \
  166. src/checkpoints.h \
  167. src/coincontrol.h \
  168. src/compat.h \
  169. src/sync.h \
  170. src/util.h \
  171. src/hash.h \
  172. src/uint256.h \
  173. src/serialize.h \
  174. src/main.h \
  175. src/net.h \
  176. src/key.h \
  177. src/db.h \
  178. src/walletdb.h \
  179. src/script.h \
  180. src/init.h \
  181. src/bloom.h \
  182. src/mruset.h \
  183. src/checkqueue.h \
  184. src/json/json_spirit_writer_template.h \
  185. src/json/json_spirit_writer.h \
  186. src/json/json_spirit_value.h \
  187. src/json/json_spirit_utils.h \
  188. src/json/json_spirit_stream_reader.h \
  189. src/json/json_spirit_reader_template.h \
  190. src/json/json_spirit_reader.h \
  191. src/json/json_spirit_error_position.h \
  192. src/json/json_spirit.h \
  193. src/qt/clientmodel.h \
  194. src/qt/guiutil.h \
  195. src/qt/transactionrecord.h \
  196. src/qt/guiconstants.h \
  197. src/qt/optionsmodel.h \
  198. src/qt/monitoreddatamapper.h \
  199. src/qt/transactiondesc.h \
  200. src/qt/transactiondescdialog.h \
  201. src/qt/bitcoinamountfield.h \
  202. src/wallet.h \
  203. src/keystore.h \
  204. src/qt/transactionfilterproxy.h \
  205. src/qt/transactionview.h \
  206. src/qt/walletmodel.h \
  207. src/qt/walletview.h \
  208. src/qt/walletstack.h \
  209. src/qt/walletframe.h \
  210. src/bitcoinrpc.h \
  211. src/qt/overviewpage.h \
  212. src/qt/csvmodelwriter.h \
  213. src/crypter.h \
  214. src/qt/sendcoinsentry.h \
  215. src/qt/qvalidatedlineedit.h \
  216. src/qt/bitcoinunits.h \
  217. src/qt/qvaluecombobox.h \
  218. src/qt/askpassphrasedialog.h \
  219. src/protocol.h \
  220. src/qt/notificator.h \
  221. src/qt/paymentserver.h \
  222. src/allocators.h \
  223. src/ui_interface.h \
  224. src/qt/rpcconsole.h \
  225. src/version.h \
  226. src/netbase.h \
  227. src/clientversion.h \
  228. src/txdb.h \
  229. src/leveldb.h \
  230. src/threadsafety.h \
  231. src/limitedmap.h \
  232. src/qt/macnotificationhandler.h \
  233. src/qt/splashscreen.h \
  234. src/hashblock.h \
  235. src/sph_blake.h \
  236. src/sph_skein.h \
  237. src/sph_keccak.h \
  238. src/sph_jh.h \
  239. src/sph_groestl.h \
  240. src/sph_bmw.h \
  241. src/sph_types.h \
  242. src/sph_luffa.h \
  243. src/sph_cubehash.h \
  244. src/sph_echo.h \
  245. src/sph_shavite.h \
  246. src/sph_simd.h \
  247. src/sph_types.h
  248.  
  249. SOURCES += src/qt/bitcoin.cpp \
  250. src/qt/bitcoingui.cpp \
  251. src/qt/transactiontablemodel.cpp \
  252. src/qt/addresstablemodel.cpp \
  253. src/qt/optionsdialog.cpp \
  254. src/qt/sendcoinsdialog.cpp \
  255. src/qt/coincontroldialog.cpp \
  256. src/qt/coincontroltreewidget.cpp \
  257. src/qt/addressbookpage.cpp \
  258. src/qt/signverifymessagedialog.cpp \
  259. src/qt/aboutdialog.cpp \
  260. src/qt/editaddressdialog.cpp \
  261. src/qt/bitcoinaddressvalidator.cpp \
  262. src/alert.cpp \
  263. src/version.cpp \
  264. src/sync.cpp \
  265. src/util.cpp \
  266. src/hash.cpp \
  267. src/netbase.cpp \
  268. src/key.cpp \
  269. src/script.cpp \
  270. src/main.cpp \
  271. src/init.cpp \
  272. src/net.cpp \
  273. src/bloom.cpp \
  274. src/checkpoints.cpp \
  275. src/addrman.cpp \
  276. src/db.cpp \
  277. src/walletdb.cpp \
  278. src/qt/clientmodel.cpp \
  279. src/qt/guiutil.cpp \
  280. src/qt/transactionrecord.cpp \
  281. src/qt/optionsmodel.cpp \
  282. src/qt/monitoreddatamapper.cpp \
  283. src/qt/transactiondesc.cpp \
  284. src/qt/transactiondescdialog.cpp \
  285. src/qt/bitcoinstrings.cpp \
  286. src/qt/bitcoinamountfield.cpp \
  287. src/wallet.cpp \
  288. src/keystore.cpp \
  289. src/qt/transactionfilterproxy.cpp \
  290. src/qt/transactionview.cpp \
  291. src/qt/walletmodel.cpp \
  292. src/qt/walletview.cpp \
  293. src/qt/walletstack.cpp \
  294. src/qt/walletframe.cpp \
  295. src/bitcoinrpc.cpp \
  296. src/rpcdump.cpp \
  297. src/rpcnet.cpp \
  298. src/rpcmining.cpp \
  299. src/rpcwallet.cpp \
  300. src/rpcblockchain.cpp \
  301. src/rpcrawtransaction.cpp \
  302. src/qt/overviewpage.cpp \
  303. src/qt/csvmodelwriter.cpp \
  304. src/crypter.cpp \
  305. src/qt/sendcoinsentry.cpp \
  306. src/qt/qvalidatedlineedit.cpp \
  307. src/qt/bitcoinunits.cpp \
  308. src/qt/qvaluecombobox.cpp \
  309. src/qt/askpassphrasedialog.cpp \
  310. src/protocol.cpp \
  311. src/qt/notificator.cpp \
  312. src/qt/paymentserver.cpp \
  313. src/qt/rpcconsole.cpp \
  314. src/noui.cpp \
  315. src/leveldb.cpp \
  316. src/txdb.cpp \
  317. src/qt/splashscreen.cpp \
  318. src/blake.c \
  319. src/bmw.c \
  320. src/groestl.c \
  321. src/jh.c \
  322. src/keccak.c \
  323. src/skein.c \
  324. src/luffa.c \
  325. src/cubehash.c \
  326. src/shavite.c \
  327. src/echo.c \
  328. src/simd.c \
  329. src/checkpointsync.cpp
  330.  
  331.  
  332. RESOURCES += src/qt/bitcoin.qrc \
  333. src/qt/background.qrc \
  334. src/qt/res/images/logo.qrc
  335.  
  336. FORMS += src/qt/forms/sendcoinsdialog.ui \
  337. src/qt/forms/coincontroldialog.ui \
  338. src/qt/forms/addressbookpage.ui \
  339. src/qt/forms/signverifymessagedialog.ui \
  340. src/qt/forms/aboutdialog.ui \
  341. src/qt/forms/editaddressdialog.ui \
  342. src/qt/forms/transactiondescdialog.ui \
  343. src/qt/forms/overviewpage.ui \
  344. src/qt/forms/sendcoinsentry.ui \
  345. src/qt/forms/askpassphrasedialog.ui \
  346. src/qt/forms/rpcconsole.ui \
  347. src/qt/forms/optionsdialog.ui
  348.  
  349. contains(USE_QRCODE, 1) {
  350. HEADERS += src/qt/qrcodedialog.h
  351. SOURCES += src/qt/qrcodedialog.cpp
  352. FORMS += src/qt/forms/qrcodedialog.ui
  353. }
  354.  
  355.  
  356. # Todo: Remove this line when switching to Qt5, as that option was removed
  357. CODECFORTR = UTF-8
  358.  
  359. # for lrelease/lupdate
  360. # also add new translations to src/qt/bitcoin.qrc under translations/
  361. TRANSLATIONS = $$files(src/qt/locale/bitcoin_*.ts)
  362.  
  363. isEmpty(QMAKE_LRELEASE) {
  364. win32:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]\\lrelease.exe
  365. else:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
  366. }
  367. isEmpty(QM_DIR):QM_DIR = $$PWD/src/qt/locale
  368. # automatically build translations, so they can be included in resource file
  369. TSQM.name = lrelease ${QMAKE_FILE_IN}
  370. TSQM.input = TRANSLATIONS
  371. TSQM.output = $$QM_DIR/${QMAKE_FILE_BASE}.qm
  372. TSQM.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm ${QMAKE_FILE_OUT}
  373. TSQM.CONFIG = no_link
  374. QMAKE_EXTRA_COMPILERS += TSQM
  375.  
  376. # "Other files" to show in Qt Creator
  377. OTHER_FILES += README.md \
  378. doc/*.rst \
  379. doc/*.txt \
  380. doc/*.md \
  381. src/qt/res/bitcoin-qt.rc \
  382.  
  383. # platform specific defaults, if not overridden on command line
  384. isEmpty(BOOST_LIB_SUFFIX) {
  385. macx:BOOST_LIB_SUFFIX = -mt
  386. win32:BOOST_LIB_SUFFIX = -mgw48-mt-s-1_53
  387. }
  388.  
  389. isEmpty(BOOST_THREAD_LIB_SUFFIX) {
  390. BOOST_THREAD_LIB_SUFFIX = $$BOOST_LIB_SUFFIX
  391. }
  392.  
  393. isEmpty(BDB_LIB_PATH) {
  394. macx:BDB_LIB_PATH = /opt/local/lib/db48
  395. }
  396.  
  397. isEmpty(BDB_LIB_SUFFIX) {
  398. macx:BDB_LIB_SUFFIX = -4.8
  399. }
  400.  
  401. isEmpty(BDB_INCLUDE_PATH) {
  402. macx:BDB_INCLUDE_PATH = /opt/local/include/db48
  403. }
  404.  
  405. isEmpty(BOOST_LIB_PATH) {
  406. macx:BOOST_LIB_PATH = /opt/local/lib
  407. }
  408.  
  409. isEmpty(BOOST_INCLUDE_PATH) {
  410. macx:BOOST_INCLUDE_PATH = /opt/local/include
  411. }
  412.  
  413. win32:DEFINES += WIN32 WIN32_LEAN_AND_MEAN
  414. win32:RC_FILE = src/qt/res/bitcoin-qt.rc
  415.  
  416. win32:!contains(MINGW_THREAD_BUGFIX, 0) {
  417. # At least qmake's win32-g++-cross profile is missing the -lmingwthrd
  418. # thread-safety flag. GCC has -mthreads to enable this, but it doesn't
  419. # work with static linking. -lmingwthrd must come BEFORE -lmingw, so
  420. # it is prepended to QMAKE_LIBS_QT_ENTRY.
  421. # It can be turned off with MINGW_THREAD_BUGFIX=0, just in case it causes
  422. # any problems on some untested qmake profile now or in the future.
  423. DEFINES += _MT
  424. QMAKE_LIBS_QT_ENTRY = -lmingwthrd $$QMAKE_LIBS_QT_ENTRY
  425. }
  426.  
  427. !win32:!macx {
  428. DEFINES += LINUX
  429. LIBS += -lrt
  430. # _FILE_OFFSET_BITS=64 lets 32-bit fopen transparently support large files.
  431. DEFINES += _FILE_OFFSET_BITS=64
  432. }
  433.  
  434. macx:HEADERS += src/qt/macdockiconhandler.h src/qt/macnotificationhandler.h
  435. macx:OBJECTIVE_SOURCES += src/qt/macdockiconhandler.mm src/qt/macnotificationhandler.mm
  436. macx:LIBS += -framework Foundation -framework ApplicationServices -framework AppKit -framework CoreServices
  437. macx:DEFINES += MAC_OSX MSG_NOSIGNAL=0
  438. macx:ICON = src/qt/res/icons/PonyCoin.icns
  439. macx:QMAKE_CFLAGS_THREAD += -pthread
  440. macx:QMAKE_LFLAGS_THREAD += -pthread
  441. macx:QMAKE_CXXFLAGS_THREAD += -pthread
  442. macx:QMAKE_INFO_PLIST = share/qt/Info.plist
  443.  
  444. # Set libraries and includes at end, to use platform-defined defaults if not overridden
  445. INCLUDEPATH += $$BOOST_INCLUDE_PATH $$BDB_INCLUDE_PATH $$OPENSSL_INCLUDE_PATH $$QRENCODE_INCLUDE_PATH
  446. LIBS += $$join(BOOST_LIB_PATH,,-L,) $$join(BDB_LIB_PATH,,-L,) $$join(OPENSSL_LIB_PATH,,-L,) $$join(QRENCODE_LIB_PATH,,-L,)
  447. LIBS += -lssl -lcrypto -ldb_cxx$$BDB_LIB_SUFFIX
  448. # -lgdi32 has to happen after -lcrypto (see #681)
  449. win32:LIBS += -lws2_32 -lshlwapi -lmswsock -lole32 -loleaut32 -luuid -lgdi32
  450. LIBS += -lboost_system$$BOOST_LIB_SUFFIX -lboost_filesystem$$BOOST_LIB_SUFFIX -lboost_program_options$$BOOST_LIB_SUFFIX -lboost_thread$$BOOST_THREAD_LIB_SUFFIX
  451. win32:LIBS += -lboost_chrono$$BOOST_LIB_SUFFIX
  452. macx:LIBS += -lboost_chrono$$BOOST_LIB_SUFFIX
  453.  
  454. contains(RELEASE, 1) {
  455. !win32:!macx {
  456. # Linux: turn dynamic linking back on for c/c++ runtime libraries
  457. LIBS += -Wl,-Bdynamic
  458. }
  459. }
  460.  
  461. system($$QMAKE_LRELEASE -silent $$TRANSLATIONS)
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!