Second Life: Easy Item-Switcher (RLV req.)

/*
  The MIT License (MIT)

  Copyright (c) 2015 Christine Jacobs

  Permission is hereby granted, free of charge, to any person obtaining a copy of
  this software and associated documentation files (the "Software"), to deal in
  the Software without restriction, including without limitation the rights to
  use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of
  the Software, and to permit persons to whom the Software is furnished to do so,
  subject to the following conditions:

  The above copyright notice and this permission notice shall be included in all
  copies or substantial portions of the Software.

  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS
  FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR
  COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
*/

/*
    Script by Christine Jacobs
    (ChristineJacobs Resident)

    1. Purpose
    This script aims to make changing of items with different styles (such as different colors) easier for the wearer and for other players by providing an intuitive menu.

    2. Requirements
    -a RLV-compatible viewer is required, RLV has to be activated and all attach- and detach-RLV-commands must not be blacklisted

    3. Preparation:
        1. Make sure you have a #RLV-folder set up.
        2. Create a sub-folder. [Example: "Shirt by SomeCreator"]
        3. Build an item on the floor (go to a sandbox if you need a place where you're allowed to do so).
        4. Pick it up and attack it to your avatar.
        5. Resize and reshape it. It will be the area an user can click on to bring up this scripts menu, so make sure that it is at an intuitive position and that it doesn't cover another item (because then you won't be able to click on this one). Set the transparency of the texture to 100% (CTRL+ALT+T shows transparency, in case you loose it).
        6. Detach the new created items. Move it to the folder which you've created in step 2. Give it a name. If you want your item to be accessed by other add ":public" to its name.
        7. Create sub-folders for all the items you want to control with this script. The name has to be unique in its folder and has to start with a question mark (?). It also has to contain : and the text following it has to be the same as the name of the item which you have created before. If you add another : followed by "default" this item will be auto-attached when you attach the item from step 6.
        8. Attach your item from step 3-6. Enjoy :-)

    [Example folder-structure:
        #RLV
        ->    Shirts
            ->    Shirt by SomeCreator
                ->    Shirt:public (Prim) [see step 6]
                ->    ?Blue:Shirt:Default
                    ->    BlueShirt (Mesh)
                    ->    Alpha-Mask
                ->    ?Green:Shirt
                    ->    GreenShirt (Mesh)
                    ->    Alpha-Mask
                ->    ?White:Shirt
                    ->    WhiteShirt (Mesh)
                    ->    Alpha-Mask
    ]
*/

string sGroup;  //the group of items to address with this script
string sTopFolder;  //the folder this object is in
list lMenuItems;    //[Label,Foldername]
integer iMenuItemDefault;

integer iChannelMenu;
integer iChannelRLVResponseFolder;
integer iChannelRLVResponseSubFolder;

integer iListenMenu;
integer iListenRLVRespone;


integer iTimerTimeForMenuResponse = 60; //the time the script should wait for a response from the user of the menu in seconds
integer iTimerTimeEndMenuResponse;

integer iTimerTimeForRLVResponse = 30; //the time the script should wait for a response from the viewer in seconds
integer iTimerTimeEndRLVResponse;

integer iAccessPublic;

integer iMenuPage;

attachById(integer iId){
    if(iId >= 0){
        detach();

        string sFolder = llList2String(lMenuItems,iId*2+1);
        llOwnerSay("@attachover:"+sTopFolder+"/"+sFolder+"=force");
    }
}

attachDefault(){
    if(iMenuItemDefault >= 0){
        attachById(iMenuItemDefault);
    }
}

list buttonsOrder(list lButtons)
{
    //source: http://wiki.secondlife.com/wiki/LlDialog/de
    return llList2List(lButtons, -3, -1) + llList2List(lButtons, -6, -4)
         + llList2List(lButtons, -9, -7) + llList2List(lButtons, -12, -10);
}

channelsReset(){
    listenStop();
    iChannelMenu = intRandom(1001,2147483600);
    iChannelRLVResponseFolder= iChannelMenu + 1;
    iChannelRLVResponseSubFolder= iChannelMenu + 2;
}

detach(){
    integer i;
    for(i=0;i<llGetListLength(lMenuItems);i+=2){
        llOwnerSay("@detach:"+sTopFolder+"/"+llList2String(lMenuItems,i+1)+"=force");
    }
}

folderParse(string sMessage){
    integer i;
    integer iStringIndex;
    string sItem;
    list lItems = llParseString2List(sMessage,[","],[]);
    list lItem;
    string sLabel;

    lMenuItems = [];

    for(i=0;i<llGetListLength(lItems);i++){
        sItem = llList2String(lItems,i);

        if(llGetSubString(sItem,0,0) == "?"){

            lItem = llParseString2List(sItem,[":"],[]);

            if(llGetListLength(lItem) > 1 && llToLower(llList2String(lItem,1)) == sGroup){

                if(llGetListLength(lItem) > 2 && llToLower(llList2String(lItem,2)) == "default"){
                    iMenuItemDefault = llGetListLength(lMenuItems)/2;
                }
                sLabel = llGetSubString(llList2String(lItem,0),1,22);
                lMenuItems += [sLabel,sItem];
            }

        }
    }
}

listenStartMenu(){
    listenStopMenu();

    iListenMenu = llListen(iChannelMenu,"",NULL_KEY,"");

    timerMenuReset();
}

listenStartRLVFolder(){
    listenStopRLV();
    iListenRLVRespone = llListen(iChannelRLVResponseFolder, "" , llGetOwner(), "");
    iTimerTimeEndRLVResponse = llGetUnixTime() + iTimerTimeForRLVResponse ;
    llSetTimerEvent(5);
}

listenStartRLVSubFolder(){
    listenStopRLV();
    iListenRLVRespone = llListen(iChannelRLVResponseSubFolder, "" , llGetOwner(), "");
    iTimerTimeEndRLVResponse = llGetUnixTime() + iTimerTimeForRLVResponse ;
    llSetTimerEvent(5);
}



listenStop(){
    listenStopMenu();
    listenStopRLV();
}

listenStopMenu(){
    llListenRemove(iListenMenu);
    iTimerTimeEndMenuResponse = 0;
}

listenStopRLV(){
    llListenRemove(iListenRLVRespone);
    iTimerTimeEndRLVResponse = 0;
}

integer intRandom(integer min, integer max){
    return min + (integer)(llFrand(max - min + 1));
}



menu(key kAvatar){
    listenStartMenu();

    list lButtons = buttonsOrder(menuItems(iMenuPage));

    llDialog(kAvatar,"Please select an item",lButtons,iChannelMenu);

}

list menuItems(integer iPage){
    integer i;

    list lItems;

    for(i=iPage*18;i<llGetListLength(lMenuItems)-1 && i<(iPage+1)*18;i+=2){
        lItems += llList2String(lMenuItems,i);
    }

    if(iPage > 0){
        lItems += ["«"];
    }else{
        lItems += [" "];
    }
    lItems += ["Cancel"];
    if(llGetListLength(lMenuItems) > (iPage+1)*18){
        lItems += ["»"];
    }else{
        lItems += [" "];
    }

    return lItems;
}



menuResponse(key kId, string sMessage){
    timerMenuReset();
    if(sMessage == "Cancel"){
        listenStopMenu();
    }else if (sMessage == "«"){
        if(iMenuPage>0){
            iMenuPage--;

        }
        menu(kId);
    }else if (sMessage == "»"){
        if(llGetListLength(lMenuItems)>(iMenuPage+1)*18){
            iMenuPage++;

        }
        menu(kId);
    }else{
        integer iIndex = llListFindList(lMenuItems,[sMessage]);
        attachById(iIndex/2);
        menu(kId);
    }
}

nameParse(){
    list lName = llParseString2List(llGetObjectName(),[":"],[]);
    sGroup = llToLower(llList2String(lName,0));

    if(llGetListLength(lName) > 0 && llToLower(llList2String(lName,1)) == "public"){
        iAccessPublic = 1;
    }else{
        iAccessPublic = 0;
    }
}

startup(){
    iMenuItemDefault = -1;


    nameParse();

    channelsReset();
    listenStartRLVFolder();
    llSleep(0.1); //give the script some time to realize where it is
    llOwnerSay("@getpath="+(string)iChannelRLVResponseFolder);
}

timerMenuReset(){
    llSetTimerEvent(5);
    iTimerTimeEndMenuResponse = llGetUnixTime() +iTimerTimeForMenuResponse;
}

default{
    attach(key kId){
        if(kId== NULL_KEY){
            //the item has been dettached, clean up everything
            listenStop();
        }else{
            //the item has been attached
            startup();
        }
    }

    listen( integer iChannel, string sName, key kId, string sMessage){
        if(iChannel == iChannelRLVResponseFolder){
            sTopFolder = sMessage;
            listenStartRLVSubFolder();
            llOwnerSay("@getinv:"+sTopFolder+"="+(string)iChannelRLVResponseSubFolder);
        }else if(iChannel == iChannelRLVResponseSubFolder){
            folderParse(sMessage);
            attachDefault();
            listenStopRLV();
        }else if(iChannel == iChannelMenu){
            if(kId == llGetOwner() || iAccessPublic == 1){
                menuResponse(kId,sMessage);
            }
        }
    }

    state_entry(){
        startup();
    }

    timer(){
        integer time = llGetUnixTime();
        if(iTimerTimeEndRLVResponse < time){
            listenStopRLV();
        }

        if(iTimerTimeEndMenuResponse < time){
            listenStopMenu();
        }


        if(iTimerTimeEndMenuResponse < time && iTimerTimeEndRLVResponse < time){
            llSetTimerEvent(0);
        }


    }

    touch_start(integer iDetected){
        key kAvatar = llDetectedKey(0);
        if(kAvatar == llGetOwner()){
            iMenuPage = 0;
            menu(kAvatar);
        }else if(iAccessPublic == 1){
            iMenuPage = 0;
            menu(kAvatar);
        }
    }

}