Terrain Generation

Information about object: objHeightMap
Sprite:
Solid: false
Visible: true
Depth: 100
Persistent: false
Parent:
Mask:

Create Event:

execute code:

{
    xx = room_width / 32;
    yy = room_height / 32;
    d3d_start();
    surf = surface_create( 33 , 33 );
    surface_set_target( surf );
    draw_set_color( c_black );
    draw_rectangle( 0 , 0 , 33 , 33 , 0 );
    draw_circle_color( 16 , 16 , 4 , c_white , c_black , 0 );
    surface_reset_target();
    for( i = 0; i < 33; i = i + 1 )
    {
        for( j = 0; j < 33; j = j + 1 )
        {
            col[ i , j ] = surface_getpixel( surf , i , j );
            hei[ i , j ] = color_get_value( col[ i , j ] );
        }
    }
    draw_set_color( c_white );
    ter = d3d_model_create();
    d3d_model_primitive_begin( ter , pr_trianglelist );
    for( i = 0; i < 32; i = i + 1 )
    {
        for( j = 0; j < 32; j = j + 1 )
        {
            d3d_model_vertex( ter , i * xx , j * yy , hei[ i , j ] );
            d3d_model_vertex( ter , ( i + 1 ) * xx , j * yy , hei[ i + 1 , j ] );
            d3d_model_vertex( ter , i * xx , ( j + 1 ) * yy , hei[ i , j + 1 ] );
            d3d_model_vertex( ter , ( i + 1 ) * xx , j * yy , hei[ i + 1 , j ] );
            d3d_model_vertex( ter , i * xx , ( j + 1 ) * yy , hei[ i , j + 1 ] );
            d3d_model_vertex( ter , ( i + 1 ) * xx , ( j + 1 ) * yy , hei[ i + 1 , j + 1 ] );
        }
    }
    d3d_model_primitive_end( ter );
}

Draw Event:

execute code:

{
    tex = background_get_texture( bckGrass );
    //d3d_set_projection( room_width / 2 , room_height / 2 + 2 * yy , 32 * xx , room_width / 2 , room_height / 2 , 16 * yy , 0 , -1 , 0 );
    with objPlayer
    {
        d3d_set_projection( x , y , 64 , x + lengthdir_x( 16 , direction ) , y + lengthdir_y( 16 , direction ) , 64 + zdir , 0 , 0 , 1 );
    }
    d3d_model_draw( ter , 0 , 0 , 0 , tex );
}