!searchreplace BASENAME "${__FILE__}" ".nsi" ""
OutFile `${BASENAME}.exe`
Name `${BASENAME}`
Caption "$(^Name)"
ShowInstDetails show
!include LogicLib.nsh

!macro _GetErrorCode dwMessageId
    System::Call Kernel32::FormatMessage(i0x00000100|0x00001000|0x00000200,,i${dwMessageId},i0x0400,*i.r1,,)i.r0
;   IntOp $0 $0 - 2
    System::Call *$1(&t$0.r0)
    System::Call Kernel32::LocalFree(ir1)
!macroend
!macro GetErrorCode RETURN_VALUE
    Push ${RETURN_VALUE}
    System::Store sR0R1
    !insertmacro _GetErrorCode R0
    DetailPrint 'Return Value = $0'
    !insertmacro _GetErrorCode R1
    DetailPrint 'last-error code = $0'
    System::Store l
!macroend

!define COM_CallMethod "!insertmacro _COM_CallMethod "
!macro _COM_CallMethod _vto _ParamsDecl _IFacePtr _Params
    System::Call `${_IFacePtr}->${_vto}${_ParamsDecl} ${_Params}`
!macroend

!define IUnknown->Release "${COM_CallMethod}2 ()i. "
!define ITypeLib->GetLibAttr "${COM_CallMethod}7 (*i)i. "
!define ITypeLib->ReleaseTLibAttr "${COM_CallMethod}12 (i)i. "

Section

StrCpy $R0 D:\PortableApps\BurnAwarePortable\App\BurnAware\FoxSDKU32w.dll
StrCpy $R0 D:\PortableApps\WinampPortable\Macromed\Flash\Flash10h.ocx
StrCpy $R0 C:\WINDOWS\system32\mshtml.dll ; this is not working
StrCpy $R0 C:\WINDOWS\system32\msxml.dll
    System::Call 'Oleaut32::LoadTypeLib(w R0,*i.r1)i.r0'
    !insertmacro GetErrorCode $0
    ${If} $0 = 0
        ${ITypeLib->GetLibAttr} $1 '(.R0).r0'
        ${If} $0 = 0
            System::Call '*$R0(&g16.R1,i.R2,i.R3,&i2.R4,&i2.R5,&i2.R6)'
            ${ITypeLib->ReleaseTLibAttr} $1 (R0)

            DetailPrint 'TLIBATTR structure'
            DetailPrint GUID=$R1
            DetailPrint CLID=$R2
            DetailPrint SYSKIND=$R3
            DetailPrint MajorVerNum=$R4
            DetailPrint MinorVerNum=$R5
            DetailPrint LibFlags=$R6
        ${EndIf}
        ${IUnknown->Release} $1 ()
    ${EndIf}
SectionEnd