Shine Shader

Shader "Unlit/DiagonalShine"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _Wipe ("Wipe", Float) = 0.0
        _Angle ("Angle", Float) = 1
        _Bands("Band", Float) = 0.0
        _Thickness ("Thickness", Float) = 10
        _Strength ("Strength", Float) = 1
        _HighlightColor ("Highlight Color", Color) = (1,1,1,1)
    }
    SubShader
    {
        Tags {
            "RenderType"="Transparent"
            "Queue"="Transparent"
        }

        Pass
        {
            Cull Off
            ZWrite Off
            Blend SrcAlpha OneMinusSrcAlpha

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #define PI 3.14159

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            float _Wipe;
            float _Bands;
            float _Angle;
            float _Thickness;
            float _Strength;
            float4 _HighlightColor;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                return o;
            }

            float4 frag (v2f i) : SV_Target
            {
                // sample the texture
                float4 col = tex2D(_MainTex, i.uv);
                float mask = step(0.05, col.x); // Mask black components of the texture

                float2 uv = i.uv * 1; // Control distance between bands

                // == If you want to control the wipe through script ==
                float xval = sin((uv.x * PI * _Bands + uv.y * PI/_Angle * _Bands) - _Wipe); // Control angle and wipe
                // ==

                // == If you want to repeat the pattern ==
                //float xval = sin((uv.x * PI * _Bands + uv.y * PI/_Angle * _Bands) - (_Time.y * 3)); // Control speed of shine
                // ==

                xval = saturate(xval);
                xval = pow(xval, _Thickness) * _Strength; // Control sharpness + thickness
                float4 xvaladd = float4(xval, xval, xval, col.a); // Mask

                float4 stripe = lerp(col, _HighlightColor + col, xvaladd * mask);
                return stripe;
            }
            ENDCG
        }
    }
}