reconnect.bat

@echo off
@title Reconnect
@color a
set a=-1
set /p limit=Masukan batas reconnect "default 9999" :
if "%limit%"=="" set limit=9999
setlocal enableextensions enabledelayedexpansion
set starttime=%time%

:loop
cls
set /a a=%a%+1
echo reconnect : %a%
if %a%==%limit% goto limit
echo conecting...
@REM ###ganti internet dengan nama dial up yg di pakai###
rasdial internet
IF NOT ERRORLEVEL 1 goto:konek
IF ERRORLEVEL 1 goto:loop

:konek
cls
echo status          : Connected
echo reconnect       : %a% kali
goto waktu

:limit
cls
echo status          : Disconnected
echo reconnect       : %a% kali
goto waktu

:waktu
set endtime=%time%
set /a hrs=%endtime:~0,2%
set /a hrs=%hrs%-%starttime:~0,2%
set /a mins=%endtime:~3,2%
set /a mins=%mins%-%starttime:~3,2%
set /a secs=%endtime:~6,2%
set /a secs=%secs%-%starttime:~6,2%

if %secs% lss 0 (
    set /a secs=!secs!+60
    set /a mins=!mins!-1
)
if %mins% lss 0 (
    set /a mins=!mins!+60
    set /a hrs=!hrs!-1
)
if %hrs% lss 0 (
    set /a hrs=!hrs!+24
)
echo Waktu execute   : %hrs% jam %mins% menit %secs% detik
@REM ###untuk os win XP ganti "IPv4 Address" dengan "IP Address"###
for /f "delims=: tokens=2" %%a in ('ipconfig ^| findstr /R /C:"IPv4 Address"') do (set tempip=%%a)
set tempip=%tempip: =%
echo IP              : %tempip%
pause>nul
exit