;Copyright (C) 2004-2010 John T. Haller of PortableApps.com

;Website: http://portableapps.com/

;This software is OSI Certified Open Source Software.
;OSI Certified is a certification mark of the Open Source Initiative.

;This program is free software; you can redistribute it and/or
;modify it under the terms of the GNU General Public License
;as published by the Free Software Foundation; either version 2
;of the License, or (at your option) any later version.

;This program is distributed in the hope that it will be useful,
;but WITHOUT ANY WARRANTY; without even the implied warranty of
;MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;GNU General Public License for more details.

;You should have received a copy of the GNU General Public License
;along with this program; if not, write to the Free Software
;Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.

!define NAME "StartPortableApps"
!define FULLNAME "Start PortableApps.com"
!define VER "1.999.5.0"
!define WEBSITE "PortableApps.com"

;=== Program Details
Name "${FULLNAME}"
OutFile "${NAME}.exe"
Caption "${FULLNAME} | PortableApps.com"
VIProductVersion "${VER}"
VIAddVersionKey ProductName "${FULLNAME}"
VIAddVersionKey Comments "For additional details, visit ${WEBSITE}"
VIAddVersionKey CompanyName "PortableApps.com"
VIAddVersionKey LegalCopyright "PortableApps.com"
VIAddVersionKey FileDescription "${FULLNAME}"
VIAddVersionKey FileVersion "${VER}"
VIAddVersionKey ProductVersion "${VER}"
VIAddVersionKey InternalName "${FULLNAME}"
VIAddVersionKey LegalTrademarks "PortableApps.com is a registered trademark of Rare Ideas, LLC."
VIAddVersionKey OriginalFilename "${NAME}.exe"
;VIAddVersionKey PrivateBuild ""
;VIAddVersionKey SpecialBuild ""

;=== Runtime Switches
CRCCheck On
WindowIcon Off
SilentInstall Silent
AutoCloseWindow True
RequestExecutionLevel user
XPStyle On

; Best Compression
SetCompress Auto
SetCompressor /SOLID lzma
SetCompressorDictSize 32
SetDatablockOptimize On

;=== Program Icon
Icon "${NAME}.ico"

Section "Main"
    IfFileExists `$EXEDIR\PortableApps\PortableApps.com\PortableAppsPlatform.exe` "" NotFound
        ;=== Check that it's the real deal
        MoreInfo::GetProductName `$EXEDIR\PortableApps\PortableApps.com\PortableAppsPlatform.exe`
        Pop $1
        StrCmp $1 "PortableApps.com Platform" "" InvalidFile
        MoreInfo::GetCompanyName `$EXEDIR\PortableApps\PortableApps.com\PortableAppsPlatform.exe`
        Pop $1
        StrCmp $1 "PortableApps.com" "" InvalidFile
        Exec '"$EXEDIR\PortableApps\PortableApps.com\PortableAppsPlatform.exe"'
        Goto TheEnd

    NotFound:
        MessageBox MB_OK|MB_ICONINFORMATION `Could not find $EXEDIR\PortableApps\PortableApps.com\PortableAppsPlatform.exe.`
        Goto TheEnd
    InvalidFile:
        MessageBox MB_OK|MB_ICONINFORMATION `The PortableAppsPlatform.exe file is not a valid PortableApps.com release and can not be launched.`
        Goto TheEnd
    TheEnd:
SectionEnd