#devotion
#debug 5
#
# -This script uses a lighter for the incense.
# -This script uses automapper to move around.
# -Variables needed for behind the scenes are at the bottom, use variable as a command line option to load those, the
#	triggers will need to be manually added to your triggers file, if you cut/paste them into your command line, then
#	genie auto fills in $gametime with the actual gametime, instead of leaving it as "$gametime".
#	-Also with the triggers, you'll have to change the animal in the last trigger to match your bead.
#	-- Make sure to change the god variable to whichever god you pray to.
#	-- Added in substitutes for bead appraisals.
# -Can perform specific rituals by using them as a variable on the command line (.devotion pray kiss tithe)
#
#
#
#
#
#
action var bead.done YES when ^An? .* scorpion bead suddenly explodes into a shower of silver-grey luminance\!$


if ("$charactername" = "Ozban") then
	{
	  #The pin variable is which anloral pin you have.
	  var pin SCORPION
	  var has.pin YES

	  var has.lighter YES
	  var lighter VIPER
	  var lighter.bag THIGH BAG

	  var receptacle CHALICE
	  var receptacle.bag THIGH BAG

	  var incense.bag THIGH BAG
	  var wine.bag THIGH BAG

	  var flint.bag THIGH BAG
	  var flint.weapon AXE

	  var god Urrem'tier
	}

echo
echo
echo PRAY, CLEAN, KISS, INCENSE, WINE, RECITE, BADGE, DANCE, BEAD, TITHE, MEDITATE, SEED, BATHE
echo
echo
pause 1
put #var god %god

if_1 then goto top
goto start

top:
if_1 then gosub %1
shift
if_1 then goto top
goto exit

start:
if ("$zonename" = "Mer'Kresh") then
	{
	put .automove 272
	  waitfor !AUTOMOVE DONE!
	gosub bead
	gosub pray
	gosub clean.altar
	gosub kiss.altar
	gosub incense
	gosub recite
	gosub faith.badge
	gosub pin
	gosub dance
	gosub wine
	goto exit
	}
put #goto 352
  waitforre ^YOU HAVE ARRIVED

	gosub bead
	gosub pray
	gosub clean.altar
	gosub kiss.altar
	gosub incense
	gosub recite
	gosub faith.badge
	gosub pin
	gosub dance
	gosub wine
	gosub tithe
	gosub seed
	gosub pot
	gosub meditate
	#gosub tamsine
	goto exit

bead.wait:
  pause
  if ("%bead.done" = "YES") then return
  goto bead.wait

pray:
  evalmath faith.time ($gametime-$praytime)
  if (%faith.time >= $praylimit) then  evalmath faith.time ($gametime-$praytime)
  if (%faith.time >= $praylimit) then
	{
	  pause
	  send PRAY $god
	  waitforre ^\[Praying for|god of the Void\.$|^You offer a quiet prayer of thanks for handsome reward of hard effort\.$|^With renewed purpose, you
	  pause
	}
     return

clean:
clean.altar:
  evalmath faith.time ($gametime-$cleantime)
  if (%faith.time >= $cleanlimit) then
	{
	  if (("$roomid" != "352") && ("$zonename" = "Crossing")) then
		{
		  put #goto 352
		  waitforre ^YOU HAVE ARRIVED
		}
	  pause
	  send LOOK ALTAR
	  matchre clean.altar2 ^The altar looks a bit dusty\.
	  matchre return ^The altar is carved of a hard, dark wood\.|^A runner of soft
	  matchwait
	}
     return

clean.altar2:
  send CLEAN ALTAR WITH WATER IN %receptacle
  waitforre ^You finish
  return

kiss:
altar:
kiss.altar:
  evalmath faith.time ($gametime-$kisstime)
  if (%faith.time >= $kisslimit) then
	{
	  if (("$roomid" != "352") && ("$zonename" = "Crossing")) then
		{
		  put #goto 352
		  waitforre ^YOU HAVE ARRIVED
		}
	  pause
	  send KNEEL
	  waitforre ^You kneel|^Subservient
	  send KISS ALTAR
	  waitforre ^You bend forward|You kiss a prayer mat
	  send STAND
	  waitforre ^You stand
	}
     return

badge:
faith.badge:
  evalmath faith.time ($gametime-$badgetime)
  if (%faith.time >= $badgelimit) then
	{
	  pause
	  send REMOVE MY BADGE
	    waitforre ^You take off a|^You remove
	  send PRAY BADGE
	    waitforre ^Roundtime
	    pause
	  send WEAR MY BADGE
	    waitforre ^You put on
	}
     return

recite:
  evalmath faith.time ($gametime-$recitetime)
  if (%faith.time >= $recitelimit) then
	{
	  pause
	  send recite Phelim, give me strength for my righteous vengeance.\;Chadatru, guide my sword to swing in justice.\;Everild, give me the power to conquer my enemies.\;Truffenyi, let me not lose sight of compassion and mercy  Else, I will become like those I despise.\;Urrem'tier, receive into your fetid grasp these wicked souls.\;May the Tamsine's realms never know their evil ways again
	  waitforre ^You lift your voice
	  pause
	}
     return

pin:
  if ("%has.pin" != "YES") then return
  evalmath faith.time ($gametime-$pintime)
  if (%faith.time >= $pinlimit) then goto pin2
  return

		pin2:
		  send LOOK MY %pin PIN
		    matchre pin3 ^A thin layer of dust|^The characteristic soft blue hue of the anloral is smudged by streaks of clumped dust\.|^Unsightly fingers of dirt have conquered|^Traces of the anloral's characteristic
		    matchre return ^It is clean, the anloral bearing
		    matchwait

		pin3:
		  send GET MY %receptacle
		  send CLEAN MY %pin PIN WITH WATER IN MY %receptacle
		    waitforre ^Roundtime|^You pour some|^The immaculate|^I could not|^What were you
		    pause
		  send PUT MY %receptacle IN MY %receptacle.bag
		    waitforre ^You put|^You stow|^You place|^I could not|^What were you
		    return

dance:
  evalmath faith.time ($gametime-$dancetime)
  if (%faith.time >= $dancelimit) then goto dance2
  return
	  dance2:
	    pause
	    send DANCE
	    matchre dance2 ^You begin to dance|^Your actions grow in intensity as you dance|^Your dance reaches its conclusion, but you falter
	    matchre return ^Your dance reaches its conclusion (?:at last|a perfect|flawlessly)|^In your condition\?
	    matchwait 6
	    goto dance2

bead:
  if ("$charactername" = "Darknem") then return
   evalmath faith.time ($gametime-$beadtime)
   if (%faith.time >= $beadlimit) then goto bead2
   return

	bead2:
	   send LOOK MY PRAYER CHAIN
	   matchre bead3 ^Strung on to
	   matchre return ^There are currently no beads on it\.$|^I could not|^What were you
	   matchwait

	bead3:
	   send REMOVE MY PRAYER CHAIN
	   send KNEEL
	     waitforre ^You kneel|^Subservient type, eh\?|^You rise
	   send MEDITATE PRAYER CHAIN
	     waitforre detaches from your prayer bead chain, spinning eerily in midair as it continues to set off a soft silver glow\.$
	   send WEAR MY PRAYER CHAIN
	   put #var beadtime $gametime
	   send STAND
	     waitforre ^You stand|^You are so|^You cannot
	   return

wine:
  evalmath faith.time ($gametime-$winetime)
  if (%faith.time >= $winelimit) then goto get.wine
  return
		get.wine:
		  if (("$roomid" != "352") && ("$zonename" = "Crossing")) then
			{
			  put #goto 352
			  waitforre ^YOU HAVE ARRIVED
			}
		  pause
		  send GET MY WINE
		    matchre pour.wine ^You get
		    matchre buy.wine ^I could not|^What were you
		    matchwait

		pour.wine:
		  send POUR MY WINE ON ALTAR
		  send PUT MY WINE IN MY %wine.bag
		    waitforre ^You put|^You stow|^You place|^I could not|^What were you
		    return

		buy.wine:
		  send #goto teller
		  waitforre ^YOU HAVE ARRIVED
		  send WITHDRAW 250 copper
		    waitforre ^The clerk counts
		  send #goto brother
		    waitforre ^YOU HAVE ARRIVED
		  send order wine
		    waitforre ^Let me but ask the humble|^Brother Durantine nods slowly.
		  send OFFER 250
		    waitforre hands it to you\.$
		  send #goto 352
		    waitforre ^YOU HAVE ARRIVED
		    goto pour.wine

incense:
  if ("%has.lighter" != "YES") then goto incense2
  evalmath faith.time ($gametime-$incensetime)
  if (%faith.time >= $incenselimit) then
	{
	  if (("$roomid" != "352") && ("$zonename" = "Crossing")) then
		{
		  put #goto 352
		  waitforre ^YOU HAVE ARRIVED
		}
	  send GET MY INCENSE
	    waitforre ^You get|^You pick|^You grab
	  send GET MY %lighter
	    waitforre ^You get|^You pick|^You grab
	  send POINT MY %lighter AT MY INC
	    waitforre ^You quickly
	  send PUT MY %lighter IN MY THIGH BAG
	    waitforre ^You put|^You stow|^You place|^I could not|^What were you
	  send WAVE INC AT ALTAR
	    waitforre ^You wave
	  send SNUFF INCENSE
	    waitforre ^You snuff|^But that|^What were|^I could not
	  send PUT MY INC IN MY %incense.bag
	    waitforre ^You put|^You stow|^You place|^I could not|^What were you
	}
     return

incense2:
  evalmath faith.time ($gametime-$incensetime)
  if (%faith.time >= $incenselimit) then
	{
	  if (("$roomid" != "352") && ("$zonename" = "Crossing")) then
		{
		  put #goto 352
		  waitforre ^YOU HAVE ARRIVED
		}
	  send WIELD MY %flint.weapon
	    waitforre ^You sling|^You deftly remove|^You get|^You pick|^You grab|^You draw out|^You wield|^You are already|^With fluid and stealthy|^You slip|^Please rephrase that command\.$|^You're already holding
	  send GET MY INCENSE
	    waitforre ^You get|^You pick|^You grab
	  send LIGHT MY INC WITH MY FLINT
	    waitforre ^You strike a piece of black flint against .*, causing a shower of sparks over.*incense which smolders, then bursts into flames\.$
	    pause
	  send SHEATH MY %flint.weapon
	    waitforre ^With fluid and stealthy movements you slip|^You easily strap|^You sheathe|^Sheathe what|^You secure|^You deftly|^You stow|^You put|^Stow what|^You sling|^You slip|^Sheathe your|all been used\.$|^You can only sheath
	  send WAVE INC AT ALTAR
	    waitforre ^You wave
	  send SNUFF INCENSE
	    waitforre ^You snuff|^But that|^What were|^I could not
	  send PUT MY INC IN MY %incense.bag
	    waitforre ^You put|^You stow|^You place|^I could not|^What were you
	}
     return

tithe:
  evalmath faith.time ($gametime-$tithetime)
  if (%faith.time >= $tithelimit) then
	{
	  pause
	  send #goto bank
	    waitforre ^YOU HAVE ARRIVED
	  move GO WINDOW
	  send WITHDRAW 6 SILVER KRONARS
	    waitforre ^The clerk counts out
	  send #goto 43
	    waitforre ^YOU HAVE ARRIVED
	  send PUT 5 SILVER KRON IN ALMSBOX
	    waitforre ^You drop|^You hear a soft voice
	}
     return

meditate:
  evalmath faith.time ($gametime-$meditatetime)
  if (%faith.time >= $meditatelimit) then
	{
	  if ("$zonename" = "The Crossing") then
	    {
	      put #goto 351
	        waitforre ^YOU HAVE ARRIVED
	    }
	  send MEDITATE
	    waitforre ^Roundtime
	    pause
	  MOVE E
	}
     return

seed:
  evalmath faith.time ($gametime-$seedtime)
  if (%faith.time >= $seedlimit then
	{
	  send #goto 1
	    waitforre ^YOU HAVE ARRIVED
	  send #goto NTR
	    waitforre ^YOU HAVE ARRIVED
	  send #goto 341
	    waitforre ^YOU HAVE ARRIVED
	    goto GatherSeed
	}
     return

		GatherSeed:
		  send gather seed
		    matchre GatherSeed ^You come up empty|^\.\.\.wait|^Sorry, you may only
		    match GotSeed You find a tiny sirese seed
		    matchwait 5
			goto gatherseed

		GotSeed:
		  send #goto Crossing
		    waitforre ^YOU HAVE ARRIVED
		  send #goto Temple
		    waitforre ^YOU HAVE ARRIVED
		  move north
		  send PLANT SEED
		  send GET MY CHALICE
		    waitfor You get
		  send SPRINKLE MY CHALICE ON ROOM
		    waitforre ^You sense that you are|^You sprinkle some holy water
		  send PUT MY CHALICE IN MY THIGH BAG
		    waitfor You put
		  send #goto Crossing
		    waitforre ^YOU HAVE ARRIVED
		    return

pot:
  if ("$Time.season" = "winter") then return
  evalmath faith.time ($gametime-$bathtime)
  if (%faith.time >= $bathlimit) then goto pot2
  return

	pot2:
	  pause
	  put #goto BROTHER
	    waitforre ^YOU HAVE ARRIVED
	  send ORDER LAVENDER
	  send OFFER 25
	    waitforre hands it to you\.$
	  send ORDER CHAMO
	  send OFFER 25
	    waitforre hands it to you\.$
	  put #goto TEMPLE
	    waitforre ^YOU HAVE ARRIVED
	  put #goto 11
	    waitforre ^YOU HAVE ARRIVED
	pot3:
	  send PREP BLESS
	  send FILL POT WITH STREAM
	    waitforre ^Roundtime|^But the stone pot is already full\!
	    pause
	  send CAST WATER IN POT
	    waitforre ^You gesture
	  send POUR POT IN BATH
	    waitforre ^Roundtime|^The pool is already
	    pause
	  goto bath

	more.water:
	   move OUT
	   goto pot3


	bathe:
	bath:
	   put GO BATH
	   matchre more.water ^You notice that the waters (?:are|have) (?:very low|rather shallow|completely evaporated) as you enter the marble bath.
	   matchre bath2 ^You step into the pool and sigh happily as the soothing, balmy waters close around you.
	   matchwait

	bath2:
	   send RUB LAVEN
	   send RUB CHAMO
	     waitforre ^You feel that your|^You sense that you|^Obvious paths
	   put OUT
	     waitforre ^\[Temple Grounds, Beside the Bathing Pool\]|^Obvious (?:paths|exits)
	   put #goto Crossing
	     waitforre ^YOU HAVE ARRIVED
	   put #goto gathering
	     waitforre ^YOU HAVE ARRIVED
	   return


exit:
echo
echo
echo
echo CLEANED, DANCED, PRAYED, POURED WINE, KISSED ALTER, PRAYED ON BADGE, TITHED, MEDITATED, and MEDITATED ON CHAIN. NOW QUIT BEING LAZY.
echo
echo
echo
echo
send COMMUNE
put #var save
put #statusbar 1 Devotion Finished at $time (.devotion)
put #parse !DEVOTION DONE!
put #parse !DEVOTION DONE!
put #parse !DEVOTION DONE!
EXIT

return:
  return

var:
vari:
varia:
variab:
variabl:
variable:
variables:
put #var god Urrem'tier
put #var badgelimit 5400
put #var cleanlimit 600
put #var dancelimit 600
put #var incenselimit 600
put #var kisslimit 600
put #var meditatelimit 600
put #var pinlimit 14400
put #var praylimit 600
put #var recitelimit 600
put #var tithelimit 600
put #var winelimit 600
put #var bathlimit 600
put #var beadlimit 600
put #var seedlimit 600

put #var seedtime 0
put #var beadtime 0
put #var bathtime 0
put #var praytime 0
put #var cleantime 0
put #var kisstime 0
put #var badgetime 0
put #var recitetime 0
put #var pintime 0
put #var dancetime 0
put #var winetime 0
put #var incensetime 0
put #var tithetime 0
put #var meditatetime 0
put #var save

put #alias {quit} {#variable save; #config {reconnect} {False}; quit}
put #alias {QUIT} {#variable save; #config {reconnect} {False}; quit}
put #alias save
return

sub:
subs:
subst:
substi:
substit:
substitu:
substitut:
substitute:
substitutes:
 #-Beads
put #subs {bead is of poor quality for its material type} {bead is of poor (1/5) quality for its material type}
put #subs {bead is of average quality for its material type} {bead is of average (2/5) quality for its material type}
put #subs {bead is of good quality for its material type} {bead is of good (3/5) quality for its material type}
put #subs {bead is of fine quality for its material type} {bead is of fine (4/5) quality for its material type}
put #subs {bead is of exemplary quality for its material type} {bead is of exemplary (5/5) quality for its material type}
put #subs {material type, and poor quality overall\.$} {material type, and poor (1/6) quality overall.}
put #subs {material type, and decent quality overall\.$} {material type, and decent (2/6) quality overall.}
put #subs {material type, and average quality overall\.$} {material type, and average (3/6) quality overall.}
put #subs {material type, and good quality overall\.$} {material type, and good (4/6) quality overall.}
put #subs {material type, and superb quality overall\.$} {material type, and superb (5/6) quality overall.}
put #subs {material type, and flawless quality overall\.$} {material type, and flawless (6/6) quality overall.}

 #-Devotion
put #subs {^You feel unclean and unworthy.} {You feel unclean and unworthy. (1/16)}
put #subs {^You close your eyes and start to concentrate. In a moment a vision appears of a barren garden, parched and thirsting for nourishment. You have an intense desire to tend it.} {You close your eyes and start to concentrate. In a moment a vision appears of a barren garden, parched and thirsting for nourishment. You have an intense desire to tend it. (2/16)}
put #subs {^You call out to your god, but there is no answer.} {You call out to your god, but there is no answer. (3/16)}
put #subs {^After a moment, you sense that your god is barely aware of you.} {After a moment, you sense that your god is barely aware of you. (4/16)}
put #subs {^After a moment, you sense that your efforts have not gone unnoticed.} {After a moment, you sense that your efforts have not gone unnoticed. (5/16)}
put #subs {^After a moment, you sense a distinct link between you and your god.} {After a moment, you sense a distinct link between you and your god. (6/16)}
put #subs {^After a moment, you sense that your god is aware of your devotion.} {After a moment, you sense that your god is aware of your devotion. (7/16)}
put #subs {^After a moment, you sense that your god is pleased with your devotion.} {After a moment, you sense that your god is pleased with your devotion. (8/16)}
put #subs {^After a moment, you sense that your god knows your name.} {After a moment, you sense that your god knows your name. (9/16)}
put #subs {^After a moment, you see a vision of your god, though the visage is cloudy and impossible to make out clearly.} {After a moment, you see a vision of your god, though the visage is cloudy and impossible to make out clearly. (10/16)}
put #subs {^After a moment, you sense a slight pressure on your shoulder, leaving the feeling that your efforts have been acknowledged.} {After a moment, you sense a slight pressure on your shoulder, leaving the feeling that your efforts have been acknowledged. (11/16)}
put #subs {^After a moment, you see a silent vision of your god, radiating forth with a powerful divine brilliance.} {After a moment, you see a silent vision of your god, radiating forth with a powerful divine brilliance. (12/16)}
put #subs {^After a moment, you see a vision of your god who calls to you by name, \"Come here my child and I will show you things of wonder\.\"$} {After a moment, you see a vision of your god who calls to you by name, "Come here my child and I will show you things of wonder." (13/16)}
put #subs {^After a moment, you see a vision of your god who calls to you by name, "Come here, my child, and I will show you things of wonder."} {After a moment, you see a vision of your god who calls to you by name, "Come here, my child, and I will show you things of wonder." (13/16)}
put #subs {^After a moment, you see a vision of your god who calls to you by name, "My child, though you may not always see my face, I am pleased with thee and thy efforts."} {After a moment, you see a vision of your god who calls to you by name, "My child, though you may not always see my face, I am pleased with thee and thy efforts." (14/16)}
put #subs {^After a moment, you see a crystal-clear vision of your god who speaks slowly and deliberately, \"Your unwavering faith and devotion pleases me greatly, (\S+)\.  Go forth and continue your works, and you shall only attain a greater level of purity\.\"} {After a moment, you see a crystal-clear vision of your god who speaks slowly and deliberately, "Your unwavering faith and devotion pleases me greatly, $1.  Go forth and continue your works, and you shall only attain a greater level of purity." (15/16)}
put #subs {^After a moment, you feel a clear presence like a warm blanket covering you beneath the shade of a giant sana'ati tree.} {After a moment, you feel a clear presence like a warm blanket covering you beneath the shade of a giant sana'ati tree. (16/16)}

 #-Osrel Meraud Orb
put #subs {The strength of the sensation evokes the image of a pile of cold ashes.} {The strength of the sensation evokes the image of a pile of cold ashes.(1/10)}
put #subs {The strength of the sensation evokes the image of a pile of smoldering ashes.} {The strength of the sensation evokes the image of a pile of smoldering ashes.(2/10)}
put #subs {The strength of the sensation evokes the image of a nearly burnt-out candle wick.} {The strength of the sensation evokes the image of a nearly burnt-out candle wick.(3/10)}
put #subs {The strength of the sensation evokes the image of a half-melted burning candle.} {The strength of the sensation evokes the image of a half-melted burning candle.(4/10)}
put #subs {The strength of the sensation evokes the image of a tall burning candle.} {The strength of the sensation evokes the image of a tall burning candle.(5/10)}
put #subs {The strength of the sensation evokes the image of a blazing torch.} {The strength of the sensation evokes the image of a blazing torch.(6/10)}
put #subs {The strength of the sensation evokes the image of a small campfire.} {The strength of the sensation evokes the image of a small campfire.(7/10)}
put #subs {The strength of the sensation evokes the image of a roaring bonfire.} {The strength of the sensation evokes the image of a roaring bonfire.(8/10)}
put #subs {The strength of the sensation evokes the image of flaming magma pouring through a volcanic crevasse.} {The strength of the sensation evokes the image of flaming magma pouring through a volcanic crevasse.(9/10)}
put #subs {The strength of the sensation evokes the image of torrents of fiery rain falling upon Elanthia from the World Dragon's maw.} {The strength of the sensation evokes the image of torrents of fiery rain falling upon Elanthia from the World Dragon's maw.(10/10)}
put #subs {The pervasiveness of the sensation evokes the image of a stream in your mind's eye.} {The pervasiveness of the sensation evokes the image of a stream in your mind's eye.(1/9) 0-149 PM}
put #subs {The pervasiveness of the sensation evokes the image of a pond in your mind's eye.} {The pervasiveness of the sensation evokes the image of a pond in your mind's eye.(2/9) 150-209 PM}
put #subs {The pervasiveness of the sensation evokes the image of a river in your mind's eye.} {The pervasiveness of the sensation evokes the image of a river in your mind's eye.(3/9) 210-299 PM}
put #subs {The pervasiveness of the sensation evokes the image of a lake in your mind's eye.} {The pervasiveness of the sensation evokes the image of a lake in your mind's eye.(4/9) 300-419 PM}
put #subs {The pervasiveness of the sensation evokes the image of a sea in your mind's eye.} {The pervasiveness of the sensation evokes the image of a sea in your mind's eye.(5/9) 420-599 PM}
put #subs {The pervasiveness of the sensation evokes the image of a ocean in your mind's eye.} {The pervasiveness of the sensation evokes the image of a ocean in your mind's eye.(6/9) 600+ PM}
put #subs {The pervasiveness of the sensation evokes the image of Drogor's deeps in your mind's eye.} {The pervasiveness of the sensation evokes the image of Drogor's deeps in your mind's eye. (7/9) 750? PM}
put #subs {The pervasiveness of the sensation evokes the image of Elanthia's tides rising toward Katamba in your mind's eye.} {The pervasiveness of the sensation evokes the image of Elanthia's tides rising toward Katamba in your mind's eye. (8/9) <=1000 PM}
put #subs {The pervasiveness of the sensation evokes the image of the sapphirine planet Merewalda in your mind's eye.} {The pervasiveness of the sensation evokes the image of the sapphirine planet Merewalda in your mind's eye. (9/9) <=1200 PM}

put #subs save
return

triggers:
echo
echo NEED TO MANUALLY ADD THE TRIGGERS TO YOUR TRIGGER FILE!!!
echo
return
#
# To find your triggers file, find your genie folder, open the config folder, there should be a file there called triggers, open
#  that with notepad, cut/paste these triggers into that file, save, reload triggers or restart genie. Then run this script.
#

#trigger {^You sprinkle some holy water over the spot where the seed is planted\.$} {#var seedtime $gametime}
#trigger {^You think upon the immortals, and the holy places built in their honor by mortals who have heard them speak, or seen the power of their beings\.} {#var badgetime $gametime}
#trigger {^You finish your job, pleased to see that the altar all but sparkles from your gentle care\.$} {#var cleantime $gametime}
#trigger {^Your dance reaches its conclusion flawlessly, finishing with a graceful flourish and a triumphant smile on your face\.} {#var dancetime $gametime}
#trigger {^Your dance reaches its conclusion a perfect, beautiful creation that ends with deft grace\.$} {#var dancetime $gametime}
#trigger {^Your dance reaches its conclusion at last, a flawless performance to those on high.} {#var dancetime $gametime}
#trigger {^You wave your burnt incense over a.*prayer mat} {#var incensetime $gametime}
#trigger {^You wave your.*incense over.*altar\.} {#var incensetime $gametime}
#trigger {^You bend forward to kiss a square altar, a gesture of your humble devotions to the gods\.$} {#var kisstime $gametime}
#trigger {^You bend forward to kiss a.*, a gesture of your humble devotions to the gods\.} {#var kisstime $gametime}
#trigger {^You bow your head and contemplate your day, the hours before you and those behind, and ready yourself for what lies ahead\.$} {#var meditatetime $gametime}
#trigger {^You pour some holy water from your .* onto your .* pin and clean it, restoring the anloral's azure purity\.$} {#var pintime $gametime}
#trigger {restoring the anloral's azure purity\.$} {#var pintime $gametime}
#trigger {^You lift your voice in praise of the gods, feeling the burning warmth of faith flowing all through your veins\.} {#var recitetime $gametime}
#trigger {^You drop.*into the tithe box\.$} {#var tithetime $gametime}
#trigger {^You quietly pour some of.*wine onto the (?:altar|prayer mat)\.} {#var winetime $gametime}
#trigger {^The warm, balmy waters drag you further into the darkness of sleep\.} {#var bathtime $gametime}

#trigger {^An?.*bead suddenly explodes into a shower of .* luminance\!$} {#var beadtime $gametime}