// LBCNetherWarts.txt

&deposit_crop = nether_wart;

&do_repairing = false;
&repair_tool = gold_hoe;

&do_harvesting = true;
&harvest_tool = diamond_pickaxe;

&do_planting = true;
&replant_crop = nether_wart;

&heading_direction = "north"
#heading_direction_num = 61;

&stepping_direction = "west";
#stepping_direction_num = 2;
//22

&do_checkinv = true;
#chest_x = 8536;
#chest_z = -3024;

#num_levels = 2;

#field_start_x = %XPOS%;
#field_start_z = %ZPOS%;

for(#levelnum,1,%#num_levels%);
        // Process one tier/level
        exec(CropBotField.txt,"cropbotfield","%&do_repairing%","%&repair_tool%","%&do_harvesting%","%&harvest_tool%","%&do_planting%","%&replant_crop%","%&heading_direction%","%#heading_direction_num%","%&stepping_direction%","%#stepping_direction_num%","%&do_checkinv%", "%&deposit_crop%", "%#chest_x%", "%#chest_z%" );
        do; wait(); until(@cropbotfield_complete); unset(@cropbotfield_complete);

        log("Walking to storage chest.");
        // Save last heading direction
        &heading_direction = %@&meesabot_heading_direction%;

        // Save current location
        #return_x = %XPOS%;
        #return_z = %ZPOS%;

        // Move to center column
        exec(WalkToX.txt,"walktox",8536);
        do; wait; until(@walktox_complete); unset(@walktox_complete);

        // Move inside the building
        exec(WalkToZ.txt,"walktoz",-3024);
        do; wait; until(@walktoz_complete); unset(@walktoz_complete);

        // Deposit crop
        log("Depositing %&deposit_crop% into storage chest.");
        look(180,235);
        wait(250ms);
        exec(EmptyItemToDoubleChest.txt,"emptyitemtodoublechest","%&deposit_crop%");
        do; wait; until(@emptyitemtodoublechest_complete); unset(@emptyitemtodoublechest_complete);

        if(%#levelnum% < %#num_levels%);
                // Get one stack back
                log("Getting one stack of %&replant_crop% from chest.");
                look(180,235);
                wait(250ms);
                exec(GetStackOfCropFromChest.txt,"getstackofcropfromchest","%&replant_crop%");
                do; wait; until(@getstackofcropfromchest_complete); unset(@getstackofcropfromchest_complete);
        endif;

        log("Moving back to saved location.");
        // Move back to saved z
        exec(WalkToZ.txt,"walktoz",%#return_z%);
        do; wait; until(@walktoz_complete); unset(@walktoz_complete);

        // Move back to saved x
        exec(WalkToX.txt,"walktox",%#return_x%);
        do; wait; until(@walktox_complete); unset(@walktox_complete);

        if(%#levelnum% < %#num_levels%);
                exec(ProcessLine.txt, "processline", "%&stepping_direction%", "0", "1", "");
                do; wait(); until(@processline_complete); unset(@processline_complete);
            exec(BotWalk.txt, "botwalk", "x,8536 z,-3029 x,8545 z,-3025 x,8534 z,-3028");
            do; wait(); until(@botwalk_complete); unset(@botwalk_complete);
        endif;
next;

set(@cropbotmainauto_complete);