Ocn_NMMx

#property indicator_separate_window
#property indicator_buffers 6
#property indicator_color1 Magenta
#property indicator_color2 Lime
#property indicator_color3 Silver
#property indicator_color4 Silver
#property indicator_color5 Yellow
#property indicator_color6 Aqua
#property indicator_level1 0
#property indicator_levelcolor Gray
#property indicator_levelstyle 2

extern int    NMM_period          = 40;
extern bool   Show_ZH             = true;
extern double ZH_displacement     = 1;
extern int    ZH_symbol           = 115;
extern bool   Show_SD             = true;
extern int    SD_len              = 30;
extern double SD_up               = 2;
extern double SD_dn               = 2;
extern bool   Show_SD_1line_only  = true;
extern bool   Show_SD_2lines_up   = true;
extern bool   Show_SD_2lines_dn   = true;
extern int    NMA_period          = 40;
extern int    NMA_LB_min          = 8;
extern bool   Show_NMA            = true;
extern bool   Show_FastNMA        = true;

double NMM[];
double ZH[];
double SD[];
double SD2[];
double NMM_NMA[];
double NMM_FastNMA[];

int init()
{
  string nmmname = "NMM(" + NMM_period + ")";
  IndicatorShortName(nmmname);
  IndicatorBuffers(6);
  SetIndexBuffer(0, NMM);
  SetIndexLabel(0, nmmname);
  SetIndexBuffer(1, ZH);
  SetIndexLabel(1, "NMM_ZH");
  SetIndexStyle(1, DRAW_ARROW);
  SetIndexArrow(1, ZH_symbol);
  SetIndexBuffer(2, SD);
  SetIndexBuffer(3, SD2);
  if(Show_SD_1line_only)
    {
    SetIndexLabel(2, "NMM_SD(" + SD_len + ")");
    SetIndexLabel(3, "unused");
    }
  else
    {
    if(Show_SD_2lines_up) SetIndexLabel(2, "NMM_SD_up(" + SD_len + ")");
    else                  SetIndexLabel(2, "unused");
    if(Show_SD_2lines_dn) SetIndexLabel(3, "NMM_SD_dn(" + SD_len + ")");
    else                  SetIndexLabel(3, "unused");
    }
  SetIndexBuffer(4, NMM_NMA);
  SetIndexBuffer(5, NMM_FastNMA);
  if(Show_NMA) SetIndexLabel(4, "NMM_NMA(" + NMA_period + ")");
  else         SetIndexLabel(4, "unused");
  if(Show_FastNMA) SetIndexLabel(5, "NMM_FastNMA(" + NMA_period + ", " + NMA_LB_min + ")");
  else             SetIndexLabel(5, "unused");
  return(0);
}

int start()
{
  int limit, i, ii, counted_bars = IndicatorCounted();
  double nmm2, sum, abssum, ratio, nmmnum, maxnmm;

  if(Bars <= NMM_period) return(0);
  if(counted_bars < 0) counted_bars = 0;
  if(counted_bars > NMM_period) limit = Bars - counted_bars;
  else                          limit = Bars - NMM_period - 1;

  for(i = limit; i >= 0; i--)
    {
    nmm2 = 0;
    for(ii = 1; ii <= NMM_period; ii++)
      nmm2 += (MathLog(Close[i]) - MathLog(Close[i+ii])) / MathSqrt(ii);
    NMM[i] = (nmm2 / NMM_period)  * 1000;
    if(Show_ZH) { if(NMM[i] == 0) ZH[i] = ZH_displacement; else ZH[i] = EMPTY_VALUE; }
    }

  if(Show_SD)
    for(i = limit; i >= 0; i--)
      if(i < Bars - NMM_period - 1 - SD_len)
        {
        if(Show_SD_1line_only)
          {
          if(NMM[i] == 0)     SD[i] = 0;
          else if(NMM[i] > 0) SD[i] = iBandsOnArray(NMM, 0, SD_len, SD_up, 0, MODE_UPPER, i);
          else if(NMM[i] < 0) SD[i] = iBandsOnArray(NMM, 0, SD_len, SD_dn, 0, MODE_LOWER, i);
          }
        else
          {
          if(NMM[i] == 0)
            {
            if(Show_SD_2lines_up) SD[i] = 0;
            if(Show_SD_2lines_dn) SD2[i] = 0;
            }
          else
            {
            if(Show_SD_2lines_up) SD[i] = iBandsOnArray(NMM, 0, SD_len, SD_up, 0, MODE_UPPER, i);
            if(Show_SD_2lines_dn) SD2[i] = iBandsOnArray(NMM, 0, SD_len, SD_dn, 0, MODE_LOWER, i);
            }
          }
        }

  if(Show_NMA)
    for(i = limit; i >= 0; i--)
      if(i < Bars - NMM_period - 1 - NMA_period)
        {
        ratio = 0;
        sum = (NMM[i] - NMM[i+1]) + (NMM[i+1] - NMM[i+2]) * (MathSqrt(2)-1);
        for(ii = 2; ii < NMA_period; ii++)
          sum += (NMM[i+ii] - NMM[i+ii+1]) * (MathSqrt(ii+1) - MathSqrt(ii));
        abssum = MathAbs(sum);
        sum = 0;
        for(ii = 0; ii < NMA_period; ii++)
          sum += MathAbs(NMM[i+ii] - NMM[i+ii+1]);
        if(sum != 0) ratio = abssum / sum;
        NMM_NMA[i] = NMM_NMA[i+1] + (NMM[i] - NMM_NMA[i+1]) * ratio;
        }

  if(Show_FastNMA)
    for(i = limit; i >= 0; i--)
      if(i < Bars - NMM_period - 1 - NMA_period)
        {
        maxnmm = 0; ratio = 0;
        int NMA_LB_max;
        for(ii = 1; ii <= NMA_period; ii++)
          {
          nmmnum = (NMM[i] - NMM[i+ii]) / MathSqrt(ii);
          if(MathAbs(nmmnum) > maxnmm) { maxnmm = MathAbs(nmmnum); NMA_LB_max = ii; }
          }
        if(NMA_LB_max < NMA_LB_min) NMA_LB_max = NMA_LB_min;
        sum = (NMM[i] - NMM[i+1]) + (NMM[i+1] - NMM[i+2]) * (MathSqrt(2)-1);
        for(ii = 2; ii < NMA_LB_max; ii++)
          sum += (NMM[i+ii] - NMM[i+ii+1]) * (MathSqrt(ii+1) - MathSqrt(ii));
        abssum = MathAbs(sum);
        sum = 0;
        for(ii = 0; ii < NMA_LB_max; ii++)
          sum += MathAbs(NMM[i+ii] - NMM[i+ii+1]);
        if(sum != 0) ratio = abssum / sum;
        NMM_FastNMA[i] = NMM_FastNMA[i+1] + (NMM[i] - NMM_FastNMA[i+1]) * ratio;
        }

  return(0);
}