Fast_NMA

#property indicator_chart_window
#property indicator_buffers 3
#property indicator_color1 Aqua
#property indicator_color2 Blue
#property indicator_color3 Blue

extern int     NMA_period  = 40;
extern int     NMA_LB_min  = 8;
extern bool    Show_SD     = true;
extern int     SD_len      = 20;
extern double  SD_up       = 1.5;
extern double  SD_dn       = 1.5;

double NMA[];
double SDup[];
double SDdn[];

int init()
{
  string nmaname = "Fast_NMA(" + NMA_period + ", " + NMA_LB_min + ")";
  string sdname = "Fast_NMA_SD(" + SD_len + ")";
  IndicatorShortName(nmaname);
  IndicatorBuffers(3);
  SetIndexBuffer(0, NMA);
  SetIndexLabel(0, nmaname);
  SetIndexBuffer(1, SDup);
  SetIndexLabel(1, sdname+"_up");
  SetIndexBuffer(2, SDdn);
  SetIndexLabel(2, sdname+"_dn");
  return(0);
}

int start()
{
  int limit, i, ii, counted_bars = IndicatorCounted();

  if(Bars <= MathMax(NMA_period, SD_len)) return(0);
  if(counted_bars < 0) counted_bars = 0;
  if(counted_bars > MathMax(NMA_period, SD_len)) limit = Bars - counted_bars;
  else                                           limit = Bars - MathMax(NMA_period, SD_len) - 1;

  for(i = limit; i >= 0; i--)
    {
    double nmmnum, maxnmm = 0, sum, abssum, ratio = 0;
    int NMA_LB_max;
    for(ii = 1; ii <= NMA_period; ii++)
      {
      nmmnum = (MathLog(Close[i]) - MathLog(Close[i+ii])) / MathSqrt(ii);
      if(MathAbs(nmmnum) > maxnmm) { maxnmm = MathAbs(nmmnum); NMA_LB_max = ii; }
      }
    if(NMA_LB_max < NMA_LB_min) NMA_LB_max = NMA_LB_min;
    sum = (MathLog(Close[i]) - MathLog(Close[i+1])) + (MathLog(Close[i+1]) - MathLog(Close[i+2])) * (MathSqrt(2)-1);
    for(ii = 2; ii < NMA_LB_max; ii++)
      sum += (MathLog(Close[i+ii]) - MathLog(Close[i+ii+1])) * (MathSqrt(ii+1) - MathSqrt(ii));
    abssum = MathAbs(sum);
    sum = 0;
    for(ii = 0; ii < NMA_LB_max; ii++)
      sum += MathAbs(MathLog(Close[i+ii]) - MathLog(Close[i+ii+1]));
    if(sum != 0) ratio = abssum / sum;
    NMA[i] = NMA[i+1] + (Close[i] - NMA[i+1]) * ratio;
    if(Show_SD)
      {
      SDup[i] = NMA[i] + SD_up * iStdDev(Symbol(), Period(), SD_len, 0, 0, PRICE_CLOSE, i);
      SDdn[i] = NMA[i] - SD_dn * iStdDev(Symbol(), Period(), SD_len, 0, 0, PRICE_CLOSE, i);
      }
    }

  return(0);
}