SDL 2.0.4 PKGBUILD

pkgname=sdl2-imx
pkgver=2.0.4
pkgrel=1
pkgdesc="SDL2 library with OpenGL ES support for embedded devices"
arch=('armv7h')
url="http://www.libsdl.org"
license=('MIT')
depends=('glibc' 'libgl')
makedepends=('alsa-lib' 'mesa' 'libxkbcommon')
optdepends=('alsa-lib: ALSA audio driver')
conflicts=('sdl2')
provides=('sdl2')
replaces=('sdl2')
source=("http://www.libsdl.org/tmp/release/SDL2-${pkgver}.tar.gz")
md5sums=('f5c27563e15db6a1370d4011808281c9')

prepare() {
  mkdir build
}

build() {
  cd build
  ../SDL2-$pkgver/configure --prefix=/usr \
    LDFLAGS="-L/opt/fsl/lib/" CPPFLAGS="-I/opt/fsl/include" \
    --enable-sdl-dlopen \
    --disable-arts --disable-esd --disable-nas \
    --enable-alsa \
    --disable-pulseaudio \
    --disable-video-wayland \
    --without-x --disable-video-x11 --disable-x11-shared \
    --disable-video-x11-xcursor --disable-video-x11-xinerama \
    --disable-video-x11-xinput --disable-video-x11-xrandr \
    --disable-video-x11-scrnsaver --disable-video-x11-xshape \
    --disable-video-x11-vm --disable-video-opengl \
    --disable-video-directfb --enable-video-opengles \
    --disable-rpath --enable-video-vivante --enable-video-opengles2
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
  install -Dm644 ../SDL2-$pkgver/COPYING.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}