Process mpang_start();
Begin
	y=650;
	set_start_positions(300,y,450,y,600,y,750,y);
	set_borders(50,1230,650,650);
	set_dinos_shooting(5,30,false);
	set_static_direction(b_up);
	if(players==1)
		set_countdown(60,ACTION_LOSE);
	else
		set_countdown(60,ACTION_WIN);
	end
	set_points_hud(board_top);
	set_background(mini_fpgs[1],2);
	set_running_speed(12.0,12.0);

	put_dinosaurs();

	mpang_bola(300,200,100,1);
	mpang_bola(500,200,100,0);

	minigame_ready();
	frame;
	wait_until_ready();

	loop
		if(players==1 and p[1].points=>20)
			set_winner(1);
			break;
		end
		frame;
	end
End

Process mpang_bola(x,y,size,flags);
Private
	id_col;
	height;
	rebote;
Begin
	init_actor();
	graph=1;
	frame;
	wait_until_ready();
	height=graphic_info(file,graph,g_height);
	rebote=700-((height/2)*size/100);
	gravity=-15;
	loop
		if(flags==1)
			x+=5;
		else
			x-=5;
		end
		if(x>1230 and flags==1) flags=0; end
		if(x<50 and flags==0) flags=1; end
		if(y>rebote and gravity>0)
			gravity=-(20+(size/3));
		else
			gravity++;
		end
		y+=(gravity/2);
		if(id_col=collision(type dino_shot))
			id_col.action=-1;
			add_points(id_col.player,1);
			explosion(x,y,size/2);
			if(size>25)
				mpang_bola(x,y,size-25,1);
				mpang_bola(x,y,size-25,0);
			end
			return;
		end
		hitter();
		frame;
	end
End