RFTools recipes with Thermal Expansion materials

// ----- RFTools stuff -----
recipes.removeShaped(<rftools:crafterBlock1>);
recipes.addShaped(<rftools:crafterBlock1>, [[<ore:gearCopper>, <minecraft:redstone_torch>, <ore:gearCopper>],
[<ore:crafterWood>,<ThermalExpansion:Frame:0>, <ore:crafterWood>],
[<ore:gearCopper>, <minecraft:redstone_torch>, <ore:gearCopper>]]);

recipes.removeShaped(<rftools:crafterBlock2>);
recipes.addShaped(<rftools:crafterBlock2>, [[<ore:gearSilver>, <minecraft:redstone_torch>, <ore:gearSilver>],
[<ore:crafterWood>,<ThermalExpansion:Frame:1>, <ore:crafterWood>],
[<ore:gearSilver>, <minecraft:redstone_torch>, <ore:gearSilver>]]);

recipes.removeShaped(<rftools:crafterBlock3>);
recipes.addShaped(<rftools:crafterBlock3>, [[<ore:gearInvar>, <minecraft:redstone_torch>, <ore:gearInvar>],
[<ore:crafterWood>,<ThermalExpansion:Frame:2>, <ore:crafterWood>],
[<ore:gearInvar>, <minecraft:redstone_torch>, <ore:gearInvar>]]);


//EnderIO compat.
<ore:glassHardened>.add(<ThermalExpansion:Glass>);
val hardenedGlass = <ore:glassHardened>;


val rCoil = <ThermalExpansion:material:1>;
val tCoil = <ThermalExpansion:material:2>;


recipes.removeShaped(<rftools:storageScannerBlock>);
recipes.addShaped(<rftools:storageScannerBlock>, [[<ore:ingotSignalum>, <minecraft:ender_pearl>,<ore:ingotSignalum>],
[<ore:glass>, <ore:ingotSignalum>, <ore:glass>],
[rCoil, <ThermalExpansion:Frame:0>, rCoil]]);


recipes.removeShaped(<rftools:destinationAnalyzerBlock>);
recipes.addShaped(<rftools:destinationAnalyzerBlock>, [[null, <minecraft:ender_pearl>,null],
[null, <ore:nuggetEnderium>, null],
[null, <ThermalExpansion:Frame:3>,null]]);


recipes.removeShaped(<rftools:relayBlock>);
recipes.addShaped(<rftools:relayBlock>, [[null, <minecraft:lever> ,null],
[<minecraft:redstone_torch>, <ThermalExpansion:Frame:0>,<minecraft:redstone_torch>],
[rCoil, <ore:ingotCopper>, tCoil]]);
recipes.addShaped(<rftools:relayBlock>, [[null, <minecraft:lever> ,null],
[<minecraft:redstone_torch>, <ThermalExpansion:Frame:0>,<minecraft:redstone_torch>],
[tCoil, <ore:ingotCopper>, rCoil]]);


//Change this if your pack doesn't use Tesseracts.
val portalBase = <ThermalExpansion:Frame:8>;
//Change this to enderium nuggets if you think it's expensive as-is.
val padMat = <ore:ingotEnderium>;

recipes.removeShaped(<rftools:matterTransmitterBlock>);
recipes.addShaped(<rftools:matterTransmitterBlock>, [[padMat,padMat,padMat],
[<minecraft:quartz>, portalBase,<minecraft:quartz>],
[<ore:ingotLead>, <ore:gearSignalum>, <ore:ingotLead>]]);


recipes.removeShaped(<rftools:shieldBlock>);
recipes.addShaped(<rftools:shieldBlock>, [[<ore:nuggetLumium>, <minecraft:emerald>, <ore:nuggetLumium>],
[<minecraft:redstone>, <ThermalExpansion:Frame:0>,<minecraft:redstone>],
[<ore:ingotLead>, <ore:ingotLead>, <ore:ingotLead>]]);


recipes.removeShaped(<rftools:machineBase>);
recipes.addShaped(<rftools:machineBase>*8, [[<ore:nuggetGold>, <ore:nuggetGold>,null],
[<ore:ingotTin>, <ore:ingotTin>,null],
[null,null,null]]);


recipes.removeShaped(<rftools:pearlInjectorBlock>);
recipes.addShaped(<rftools:pearlInjectorBlock>, [[null, <minecraft:chest>,null],
[<minecraft:redstone>, <ThermalExpansion:Frame:0>,<minecraft:redstone>],
[null,<minecraft:hopper>,null]]);


recipes.removeShaped(<rftools:endergenicBlock>);
recipes.addShaped(<rftools:endergenicBlock>, [[null, tCoil,null],
[<minecraft:diamond>, <ThermalExpansion:Frame:3>,<minecraft:diamond>],
[<ore:ingotEnderium>,<ore:gearEnderium>,<ore:ingotEnderium>]]);


recipes.removeShaped(<rftools:matterReceiverBlock>);
recipes.addShaped(<rftools:matterReceiverBlock>, [[padMat,<ore:gearLumium>,padMat],
[<minecraft:quartz>, portalBase,<minecraft:quartz>],
[<ore:ingotLead>, <ore:ingotLead>, <ore:ingotLead>]]);


recipes.removeShaped(<rftools:dialingDeviceBlock>);
recipes.addShaped(<rftools:dialingDeviceBlock>, [[<minecraft:quartz>, <ore:ingotSignalum>, <minecraft:quartz>],
[<ore:glass>, <ThermalExpansion:Frame:0>,<ore:glass>],
[<minecraft:quartz>, <ore:ingotSignalum>, <minecraft:quartz>]]);


recipes.removeShaped(<rftools:rfMonitorBlock>);
recipes.addShapeless(<rftools:rfMonitorBlock>, [<ThermalExpansion:Frame:0>, <ThermalExpansion:meter>]);


//Remove the now-unused machine frame.
recipes.removeShaped(<rftools:machineFrame>);