rec3

int f, elements = 30;
float[] sz = new float[elements];
float[] rot = new float[elements];
int[] col = new int[elements];
color[] palette = {
  #EFFFCD, #555152, #DCE9BE, #2E2633, #99173C
};
float theta, rotOff, scal,x,y;
boolean save;

void setup() {
  size(500, 500);
  rectMode(CENTER);
  float Sz = width*.40;

  for (int i=0; i<elements; i++) {
    Sz -= random(3, 7);
    sz[i] = Sz ;
    rot[i]= PI/elements*i;
    col[i] = (int) random(0, 5);
  }
}

void draw() {
  background(20);
  translate(width/2, height/2);

  for (int i=0; i<elements; i++) {
    pushMatrix();
    rotOff = map(sin(rot[i]+theta*2), -1, 1, -40, 40);
    scal = map(cos(rot[i]+theta), -1, 1, .7, 1.5);
    x = map(sin(rot[i]+theta), -1, 1, -100, 100);
    y = map(sin(rot[i]+theta*2), -1, 1, -150, 150);
    rotate(radians(rotOff));
    fill(palette[i%5]);
    noStroke();
    rect(x, y, sz[i]*scal, sz[i]*scal, 20);
    popMatrix();
  }
  theta += 0.0523/2;

  if (save) {
    if (frameCount%4==0 && frameCount<f+241) saveFrame("image-###.gif");
  }
}

void mouseClicked() {
  setup();
}

void keyPressed() {
  f = frameCount;
  save = true;
}