openmw1.5-ogre1.8.patch-PKGBUILD

# Maintainer: Pieter van der Kloet <pvdkloet@gmail.com>
# Fixed by Sandy Carter <bwrsandman@gmail.com>
pkgname=openmw
pkgver=0.15.0
pkgrel=1
pkgdesc="An open-source engine reimplementation for the role-playing game Morrowind."
arch=('i686' 'x86_64')
url="http://www.openmw.org"
license=('GPL3')

depends=('openal' 'ogre>=1.8.0' 'mygui' 'bullet>=2.8.0' 'mpg123' 'libsndfile' 'qt')

makedepends=('cmake' 'boost')

source=('http://openmw.googlecode.com/files/openmw-0.15.0-source.tar.gz' 'http://pastebin.com/download.php?i=7YkXWED5')
md5sums=('8896101f771ed00d59bbd3ad4c50f43d' 'a4a46874c8eb0d71e286a50179563183')

conflicts=('openmw-git')

build() {
  cd "$srcdir"/zinnschlag-openmw-94498f5

  # patch by bwrsandman
  (sed 's/\r//g' ../download.php\?i\=7YkXWED5 && echo) > ../ogre1.8.patch
  patch -p0 -d .. -i ogre1.8.patch

  cmake -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_BUILD_TYPE=RelWithDebInfo
  make

  # Install
  # There is currently no make install so we do this manually

  # Binaries
  install -d -m755 "$pkgdir"/usr/bin
  install -m755 openmw "$pkgdir"/usr/bin/
  install -m755 omwlauncher "$pkgdir"/usr/bin/
  install -m755 esmtool "$pkgdir"/usr/bin/

  # Config files
  # Replace resources location
  sed -i 's,resources=resources,resources=/usr/share/games/openmw/resources,' openmw.cfg.install || exit 1

  install -d -m755 "$pkgdir"/etc/openmw
  install -m644 openmw.cfg.install "$pkgdir"/etc/openmw/openmw.cfg
  install -m644 plugins.cfg "$pkgdir"/etc/openmw/
  install -m644 launcher.cfg "$pkgdir"/etc/openmw/
  install -m644 settings-default.cfg "$pkgdir"/etc/openmw/
  install -m644 transparency-overrides.cfg "$pkgdir"/etc/openmw/

  # Desktop file and icon
  install -d -m755  "$pkgdir"/usr/share/applications
  install -m644 files/openmw.desktop "$pkgdir"/usr/share/applications/

  install -d -m755 "$pkgdir"/usr/share/pixmaps
  install -m644 apps/launcher/resources/images/openmw.png "$pkgdir"/usr/share/pixmaps/

  # Resources
  install -d -m755 "$pkgdir"/usr/share/games/openmw
  cp -r resources "$pkgdir"/usr/share/games/openmw/ || exit 1
  install -m644 launcher.qss "$pkgdir"/usr/share/games/openmw/resources
}