Not a member of Pastebin yet?
Sign Up,
it unlocks many cool features!
- ;MachinimaOS System API
- ; Copyright (C) 2013 Jonathan Strobl ([email protected])
- ;This program is free software; you can redistribute it and/or modify
- ; it under the terms of the GNU General Public License as published by
- ; the Free Software Foundation; either version 2 of the License, or
- ; (at your option) any later version.
- ;
- ; This program is distributed in the hope that it will be useful,
- ; but WITHOUT ANY WARRANTY; without even the implied warranty of
- ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
- ; GNU General Public License for more details.
- ;
- ; You should have received a copy of the GNU General Public License along
- ; with this program; if not, write to the Free Software Foundation, Inc.,
- ; 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
- ;ASM-Merkmal für IDE, auskommentiert
- {
- option casemap:none ;Assembler Merkmal
- }
- ;Aufrufen einer API-Funktion
- SYSAPI:
- PUSH AF
- ;IY beinhaltet die Nummer der Funktion, wird nicht mehr getrashed
- ;Alle anderen Register können Parameter enthalten
- PUSH IY
- ;IY mit dem Sprungziel in der Sprungliste laden
- PUSH BC
- ADD IY, IY
- ADD IY, IY
- ADD IY, IY
- LD BC, .jumplist
- ADD IY, BC
- POP BC
- JP (IY) ;Sprung ins kalte Wasser
- .jumplist:
- ;8 Byte pro Sprungvektor, Anspringen der Funktionen mit CALL, Auffüllen von
- ;Bytes mit HALT.
- CALL .KRNL_getDeviceType ;0
- JP .finish
- HALT
- HALT
- CALL .KRNL_findDeviceWithType ;1
- JP .finish
- HALT
- HALT
- CALL .KRNL_out_byte_std_RS232 ;2
- JP .finish
- HALT
- HALT
- CALL .KRNL_init_std_RS232 ;3
- JP .finish
- HALT
- HALT
- CALL .KRNL_out_string_std_RS232 ;4
- JP .finish
- HALT
- HALT
- CALL .KRNL_get_std_RS232_out_buffer_len ;5
- JP .finish
- HALT
- HALT
- CALL .KRNL_get_std_RS232_in_buffer_len ;6
- JP .finish
- HALT
- HALT
- CALL .KRNL_in_byte_std_RS232 ;7
- JP .finish
- HALT
- HALT
- CALL .KRNL_getDeviceID ;8
- JP .finish
- HALT
- HALT
- CALL .KRNL_byte_to_str_hex ;9
- JP .finish
- HALT
- HALT
- CALL .KRNL_get_device_description_str ;10
- JP .finish
- HALT
- HALT
- CALL .KRNL_create_process_from_memory ;11
- JP .finish
- HALT
- HALT
- CALL .KRNL_start_atomic ;12
- JP .finish
- HALT
- HALT
- CALL .KRNL_end_atomic ;13
- JP .finish
- HALT
- HALT
- CALL .KRNL_process_page_switch ;14
- JP .finish
- HALT
- HALT
- CALL .KRNL_get_my_pid ;15
- JP .finish
- HALT
- HALT
- CALL .KRNL_kill_process ;16
- JP .finish
- HALT
- HALT
- CALL .PMMU_request_page ;17
- JP .finish
- HALT
- HALT
- CALL .PMMU_free_page ;18
- JP .finish
- HALT
- HALT
- CALL .PMMU_get_installed_max_page ;19
- JP .finish
- HALT
- HALT
- CALL .PMMU_estimate_free_page_count ;20
- JP .finish
- HALT
- HALT
- CALL .KRNL_empty_function ;21
- JP .finish
- HALT
- HALT
- CALL .KRNL_get_akt_mounted_page ;22
- JP .finish
- HALT
- HALT
- CALL .KRNL_suspend_process ;23
- JP .finish
- HALT
- HALT
- CALL .KRNL_resume_process ;24
- JP .finish
- HALT
- HALT
- CALL .KRNL_wait_for_message ;25
- JP .finish
- HALT
- HALT
- CALL .KRNL_get_process_flags ;26
- JP .finish
- HALT
- HALT
- CALL .KRNL_set_process_priority ;27
- JP .finish
- HALT
- HALT
- CALL .KRNL_send_message ;28
- JP .finish
- HALT
- HALT
- CALL .KRNL_get_message_count ;29
- JP .finish
- HALT
- HALT
- CALL .KRNL_get_messages ;30
- JP .finish
- HALT
- HALT
- CALL .KRNL_clear_process_message_buffer ;31
- JP .finish
- HALT
- HALT
- CALL .KRNL_register_driver ;32
- JP .finish
- HALT
- HALT
- CALL .KRNL_unregister_driver ;33
- JP .finish
- HALT
- HALT
- CALL .KRNL_get_driver_by_type ;34
- JP .finish
- HALT
- HALT
- .KRNL_getDeviceType:
- ;Auslesen des Device-Typs von Gerät C, Rückgabe in C
- PUSH AF
- PUSH DE
- PUSH BC
- LD A, C
- LD D, 0
- CP A, 0
- JP Z, .KRNL_getDeviceType_illegalPort
- LD B, 0
- IN D, (C)
- .KRNL_getDeviceType_illegalPort:
- POP BC
- LD C, D
- POP DE
- POP AF
- RET
- .KRNL_findDeviceWithType:
- ;Suchen eines Geräts mit Device-Typ C, Rückgabe in C
- PUSH DE
- PUSH AF
- PUSH BC
- LD D, C
- LD C, 1
- .KRNL_findDeviceWithType_sloop:
- PUSH BC
- CALL .KRNL_getDeviceType
- LD E, C
- POP BC
- LD A, E
- CP A, D
- JP Z, .KRNL_findDeviceWithType_loopend
- INC C
- LD A, C
- CP A, 0
- JP Z, .KRNL_findDeviceWithType_loopend
- JP .KRNL_findDeviceWithType_sloop
- .KRNL_findDeviceWithType_loopend:
- LD D, C
- POP BC
- LD C, D
- POP AF
- POP DE
- RET
- .KRNL_out_byte_std_RS232:
- PUSH BC
- PUSH DE
- PUSH AF
- LD A, (.RS232_Slot)
- CP A, 0
- JP Z, .KRNL_out_byte_std_RS232_no_device
- LD D, C
- LD C, A
- LD B, 130
- .KRNL_out_byte_std_RS232_wait_for_buffer:
- IN A, (C)
- CP A, 127
- JP NC, .KRNL_out_byte_std_RS232_wait_for_buffer
- LD B, 128
- OUT (C), D
- .KRNL_out_byte_std_RS232_no_device:
- POP AF
- POP DE
- POP BC
- RET
- .KRNL_init_std_RS232:
- PUSH AF
- PUSH BC
- LD C, 1
- CALL .KRNL_FindDeviceWithType
- LD A, C
- LD (.RS232_Slot), A
- POP BC
- POP AF
- RET
- .KRNL_out_string_std_RS232:
- PUSH AF
- PUSH BC
- PUSH HL
- LD A, (.RS232_slot)
- CP A, 0
- JP Z, .KRNL_out_string_std_RS232_no_device
- .KRNL_out_string_std_RS232_outloop:
- LD A, (HL)
- CP A, 0
- JP Z, .KRNL_out_string_std_RS232_zero_detected
- LD C, A
- CALL .KRNL_out_byte_std_RS232
- .KRNL_out_string_std_RS232_zero_detected:
- INC HL
- CP A, 0
- JP NZ, .KRNL_out_string_std_RS232_outloop
- .KRNL_out_string_std_RS232_no_device:
- POP HL
- POP BC
- POP AF
- RET
- .KRNL_get_std_RS232_out_buffer_len:
- PUSH AF
- PUSH BC
- LD C, 255
- LD A, (.RS232_slot)
- CP A, 0
- JP Z, .KRNL_get_std_RS232_out_buffer_len_no_device
- LD B, 130
- LD C, A
- IN A, (C)
- LD C, A
- .KRNL_get_std_RS232_out_buffer_len_no_device:
- LD A, C
- POP BC
- LD C, A
- POP AF
- RET
- .KRNL_get_std_RS232_in_buffer_len:
- PUSH AF
- PUSH BC
- LD C, 0
- LD A, (.RS232_slot)
- CP A, 0
- JP Z, .KRNL_get_std_RS232_in_buffer_len_no_device
- LD B, 129
- LD C, A
- IN A, (C)
- LD C, A
- .KRNL_get_std_RS232_in_buffer_len_no_device:
- LD A, C
- POP BC
- LD C, A
- POP AF
- RET
- .KRNL_in_byte_std_RS232:
- PUSH AF
- PUSH BC
- LD C, 0
- LD A, (.RS232_Slot)
- CP A, 0
- JP Z, .KRNL_in_byte_std_RS232_no_device
- LD C, A
- LD B, 129
- .KRNL_in_byte_std_RS232_wait_for_data:
- IN A, (C)
- CP A, 0
- JP Z, .KRNL_in_byte_std_RS232_wait_for_data
- LD B, 128
- IN A, (C)
- LD C, A
- .KRNL_in_byte_std_RS232_no_device:
- LD A, C
- POP BC
- LD C, A
- POP AF
- RET
- .KRNL_getDeviceID:
- ;Auslesen der Device-ID von Gerät C, Rückgabe in C
- PUSH AF
- PUSH DE
- PUSH BC
- LD A, C
- LD D, 0
- CP A, 0
- JP Z, .KRNL_getDeviceID_illegalPort
- LD B, 2
- IN D, (C)
- .KRNL_getDeviceID_illegalPort:
- POP BC
- LD C, D
- POP DE
- POP AF
- RET
- .KRNL_byte_to_str_hex:
- PUSH AF
- PUSH BC
- PUSH HL
- LD A, C
- SRA A
- SRA A
- SRA A
- SRA A
- AND A, 15
- CP A, 10
- JP NC, .KRNL_byte_to_str_hex_first_g9
- PUSH AF
- ADD A, 48
- LD (HL), A
- INC HL
- POP AF
- .KRNL_byte_to_str_hex_first_g9:
- CP A, 10
- JP C, .KRNL_byte_to_str_hex_first_k9
- PUSH AF
- ADD A, 55
- LD (HL), A
- INC HL
- POP AF
- .KRNL_byte_to_str_hex_first_k9:
- LD A, C
- AND A, 15
- CP A, 10
- JP NC, .KRNL_byte_to_str_hex_last_g9
- PUSH AF
- ADD A, 48
- LD (HL), A
- INC HL
- POP AF
- .KRNL_byte_to_str_hex_last_g9:
- CP A, 10
- JP C, .KRNL_byte_to_str_hex_last_k9
- PUSH AF
- ADD A, 55
- LD (HL), A
- INC HL
- POP AF
- .KRNL_byte_to_str_hex_last_k9:
- LD (HL), 0
- POP HL
- POP BC
- POP AF
- RET
- .KRNL_get_device_description_str:
- PUSH HL
- PUSH AF
- PUSH BC
- LD B, 4
- LD A, C
- CP A, 0
- JP Z, .KRNL_get_device_description_str_illegal_Port
- .KRNL_get_device_description_str_iloop:
- IN A, (C)
- LD (HL), A
- INC B
- INC HL
- LD A, B
- CP A, 32
- JP NZ, .KRNL_get_device_description_str_iloop
- .KRNL_get_device_description_str_illegal_Port:
- LD A, 0
- LD (HL), A
- POP BC
- POP AF
- POP HL
- RET
- .KRNL_create_process_from_memory:
- ;B: Bank 1
- ;C: Bank 2
- ;D: Bank 3
- ;E: Flags
- ;HL: Start address
- ;IX: Stack address
- PUSH AF
- EX AF, AF'
- PUSH AF
- PUSH BC
- PUSH DE
- PUSH HL
- PUSH IX
- PUSH IY
- PUSH IX
- POP IY
- CALL .KRNL_start_atomic
- ;Leeren Prozess-Slot finden (Adresse nach IX)
- PUSH BC
- PUSH DE
- LD BC, 12
- LD IX, PROCESS_LIST
- ADD IX, BC
- LD E, 1
- .KRNL_create_process_from_memory_searchloop:
- LD A, (IX + 0) ;Flags
- AND A, 0000 0001b ;Process_slot_full
- CP A, 0
- JP Z, .KRNL_create_process_from_memory_searchloop_end
- ADD IX, BC
- INC E
- LD A, E
- CP A, 0
- JP NZ, .KRNL_create_process_from_memory_searchloop
- .KRNL_create_process_from_memory_process_list_full:
- LD IX, PROCESS_LIST
- LD E, 0
- .KRNL_create_process_from_memory_searchloop_end:
- LD A, E
- EX AF, AF' ;Register sind so knapp.
- ;GGF maximale PID aktualisieren
- LD A, (TASK_SCHEDULE.MAX_PID)
- CP A, E
- JP NC, .KRNL_create_process_from_memory_no_new_pid_max
- LD A, E
- LD (TASK_SCHEDULE.MAX_PID), A
- .KRNL_create_process_from_memory_no_new_pid_max:
- POP DE
- POP BC
- EX AF, AF'
- CP A, 0
- EX AF, AF'
- JP Z, .KRNL_create_process_from_memory_noinit
- ;Flags initialisieren
- LD A, E
- OR A, 0000 0011b ;Slot belegen, Prozess anhalten
- AND A, 1111 0011b
- LD (IX + 0), A
- PUSH DE
- ;Creator PID initialisieren
- LD A, (TASK_SCHEDULE.THISPROCESS_PID)
- LD (IX + 3), A ;Creator PID
- ;Memory banks initialisieren
- LD A, 0
- LD (IX + 4), A ;bank 0
- LD (IX + 5), B ;bank 1
- LD (IX + 6), C ;bank 2
- LD (IX + 7), D ;bank 3
- ;Stack initialisieren
- PUSH IY
- POP DE
- ;Alte Pages merken
- LD C, 1
- CALL .KRNL_get_akt_mounted_page
- LD A, C
- LD (.KRNL_create_process_from_memory_pstor1), A
- LD C, 2
- CALL .KRNL_get_akt_mounted_page
- LD A, C
- LD (.KRNL_create_process_from_memory_pstor2), A
- LD C, 3
- CALL .KRNL_get_akt_mounted_page
- LD A, C
- LD (.KRNL_create_process_from_memory_pstor3), A
- ;Temporär umschalten (wir haben so lange keinen Stack!)
- LD B, 64
- LD A, (IX + 5)
- LD C, 0
- OUT (C), A
- LD B, 128
- LD A, (IX + 6)
- LD C, 0
- OUT (C), A
- LD B, 192
- LD A, (IX + 7)
- LD C, 0
- OUT (C), A
- ;Rücksprungadresse auf den Stack des neuen Prozesses schreiben
- DEC DE
- LD A, H
- LD (DE), A
- DEC DE
- LD A, L
- LD (DE), A
- ;Register-Werte auf den Stack des neuen Prozesses schreiben
- LD A, 0
- ;AF
- DEC DE
- LD (DE), A
- DEC DE
- LD (DE), A
- ;BC
- DEC DE
- LD (DE), A
- DEC DE
- LD (DE), A
- ;DE
- DEC DE
- LD (DE), A
- DEC DE
- LD (DE), A
- ;HL
- DEC DE
- LD (DE), A
- DEC DE
- LD (DE), A
- ;AF'
- DEC DE
- LD (DE), A
- DEC DE
- LD (DE), A
- ;BC'
- DEC DE
- LD (DE), A
- DEC DE
- LD (DE), A
- ;DE'
- DEC DE
- LD (DE), A
- DEC DE
- LD (DE), A
- ;HL'
- DEC DE
- LD (DE), A
- DEC DE
- LD (DE), A
- ;IX
- DEC DE
- LD (DE), A
- DEC DE
- LD (DE), A
- ;IY
- DEC DE
- LD (DE), A
- DEC DE
- LD (DE), A
- EX DE, HL
- LD (IX + 1), L
- LD (IX + 2), H
- ;Zurückschalten (Stack is back)
- LD B, 64
- LD A, (.KRNL_create_process_from_memory_pstor1)
- LD C, 0
- OUT (C), A
- LD B, 128
- LD A, (.KRNL_create_process_from_memory_pstor2)
- LD C, 0
- OUT (C), A
- LD B, 192
- LD A, (.KRNL_create_process_from_memory_pstor3)
- LD C, 0
- OUT (C), A
- POP DE
- ;Priorität setzen
- LD A, 0
- LD (IX + 8), A
- ;Prozess aktivieren
- LD A, E
- OR A, 0000 0001b
- LD (IX + 0), A
- .KRNL_create_process_from_memory_noinit:
- CALL .KRNL_end_atomic
- POP IY
- POP IX
- POP HL
- POP DE
- POP BC
- POP AF
- EX AF, AF'
- LD C, A
- POP AF
- RET
- .KRNL_start_atomic:
- PUSH AF
- LD A, 1
- LD (TASK_SCHEDULE.ATOMIC_FLAGS), A
- LD A, (TASK_SCHEDULE.ATOMIC_NESTING)
- INC A
- LD (TASK_SCHEDULE.ATOMIC_NESTING), A
- POP AF
- RET
- .KRNL_end_atomic:
- PUSH AF
- ;Wenn Nesting > 0, Nesting dekrementieren
- LD A, (TASK_SCHEDULE.ATOMIC_NESTING)
- ;CP A, 1
- ;CCF ;Invertiert Carry
- ;SBC A, 0
- SUB A, 1
- ADC A, 0 ;Trolololo
- LD (TASK_SCHEDULE.ATOMIC_NESTING), A
- CP A, 0
- JP NZ, .KRNL_end_atomic_nested
- LD A, (TASK_SCHEDULE.ATOMIC_FLAGS)
- PUSH AF
- LD A, 0
- LD (TASK_SCHEDULE.ATOMIC_FLAGS), A
- POP AF
- CP A, 1
- ;Ggf einen Task Switch nachholen
- JP Z, .KRNL_end_atomic_no_nmi
- CALL 66h
- .KRNL_end_atomic_no_nmi:
- .KRNL_end_atomic_nested:
- POP AF
- RET
- .KRNL_process_page_switch:
- ;B: Page-Position (1 - 3)
- ;C: Page-Nummer
- PUSH AF
- PUSH BC
- PUSH DE
- PUSH HL
- PUSH IX
- LD A, B
- CP A, 0
- JP Z, .KRNL_process_page_switch_invalid_page_slot
- CP A, 4
- JP NC, .KRNL_process_page_switch_invalid_page_slot
- ;Basisadresse der Prozessliste holen
- LD IX, PROCESS_LIST
- ;PID * 12 aufaddieren
- LD A, (TASK_SCHEDULE.THISPROCESS_PID)
- LD H, 0
- LD L, A
- EX DE, HL
- LD HL, 0
- ADD HL, DE
- ADD HL, DE
- ADD HL, DE
- ADD HL, HL
- ADD HL, HL
- EX DE, HL
- ADD IX, DE
- ;Page-Slot aufaddieren
- LD H, 0
- LD L, B
- EX DE, HL
- ADD IX, DE
- ;Eigentliches Page Switching
- LD (IX + 4), C
- LD A, B
- ADD A, A
- ADD A, A
- ADD A, A
- ADD A, A
- ADD A, A
- ADD A, A
- LD B, A
- LD D, C
- LD C, 0
- OUT (C), D
- .KRNL_process_page_switch_invalid_page_slot:
- POP IX
- POP HL
- POP DE
- POP BC
- POP AF
- RET
- .KRNL_get_my_pid:
- PUSH AF
- PUSH BC
- LD A, (TASK_SCHEDULE.THISPROCESS_PID)
- POP BC
- LD C, A
- POP AF
- RET
- .KRNL_kill_process:
- ;C: PID
- ;B: Flags
- PUSH AF
- PUSH BC
- PUSH DE
- PUSH HL
- PUSH IX
- ;Basisadresse der Prozessliste holen
- LD IX, PROCESS_LIST
- ;PID * 12 aufaddieren
- LD A, C
- LD H, 0
- LD L, A
- EX DE, HL
- LD HL, 0
- ADD HL, DE
- ADD HL, DE
- ADD HL, DE
- ADD HL, HL
- ADD HL, HL
- EX DE, HL
- ADD IX, DE
- PUSH BC
- CALL .KRNL_start_atomic
- PUSH BC
- ;Prozessflags auf 0 setzen
- LD A, 0
- LD (IX + 0), A
- ;Messagepuffer löschen
- CALL .KRNL_clear_process_message_buffer
- ;Speicher freigeben?
- LD A, B
- AND A, 0000 0001b
- CP A, 0
- JP Z, .KRNL_kill_process_nofpages
- LD C, 1
- CALL .KRNL_get_akt_mounted_page
- LD A, C
- CP A, 0
- CALL NZ, .PMMU_free_page
- LD C, 2
- CALL .KRNL_get_akt_mounted_page
- LD A, C
- CP A, 0
- CALL NZ, .PMMU_free_page
- LD C, 3
- CALL .KRNL_get_akt_mounted_page
- LD A, C
- CP A, 0
- CALL NZ, .PMMU_free_page
- .KRNL_kill_process_nofpages:
- POP BC
- ;Treiber entfernen
- LD IX, DRIVER_DATA.DLIST
- LD B, 0
- LD DE, 4
- .KRNL_kill_process_dremoveloop:
- LD A, (IX + 0)
- CP A, C
- JP NZ, .KRNL_kill_process_nodremove
- LD (IX + 0), 0
- LD (IX + 1), 0
- LD (IX + 2), 0
- LD (IX + 3), 0
- .KRNL_kill_process_nodremove:
- INC B
- ADD IX, DE
- LD A, B
- CP A, 0
- JP NZ, .KRNL_kill_process_dremoveloop
- CALL .KRNL_end_atomic
- POP BC
- ;Löscht sich ein Prozess selbst, ans OS zurückgeben
- LD A, (TASK_SCHEDULE.THISPROCESS_PID)
- CP A, C
- JP NZ, .KRNL_kill_process_itsnotme
- RST 20h
- .KRNL_kill_process_itsnotme:
- POP IX
- POP HL
- POP DE
- POP BC
- POP AF
- RET
- .PMMU_request_page:
- PUSH AF
- PUSH BC
- PUSH DE
- PUSH HL
- PUSH IX
- LD IX, PMMU_memory_map
- LD E, 0
- CALL .KRNL_start_atomic
- .PMMU_request_page_sloop:
- INC IX
- INC E
- LD A, (PMMU_max_page)
- INC A
- LD B, A
- LD A, E
- CP A, B
- JP NZ, .PMMU_request_page_ptr_overflow
- LD IX, PMMU_memory_map
- .PMMU_request_page_ptr_overflow:
- LD A, (IX + 0)
- CP A, 0
- JP NZ, .PMMU_request_page_sloop
- LD A, 1
- LD (IX + 0), A
- CALL .KRNL_end_atomic
- LD A, E
- POP IX
- POP HL
- POP DE
- POP BC
- LD C, A
- POP AF
- RET
- .PMMU_free_page:
- PUSH AF
- PUSH BC
- PUSH DE
- PUSH HL
- PUSH IX
- LD IX, PMMU_memory_map
- LD H, 0
- LD L, C
- EX DE, HL
- ADD IX, DE
- CALL .KRNL_start_atomic
- LD A, (IX + 0)
- CP A, 255
- JP Z, .PMMU_free_page_unfreeable
- LD A, 0
- LD (IX + 0), A
- .PMMU_free_page_unfreeable:
- CALL .KRNL_end_atomic
- POP IX
- POP HL
- POP DE
- POP BC
- POP AF
- RET
- .PMMU_get_installed_max_page:
- PUSH AF
- LD A, (PMMU_max_page)
- LD C, A
- POP AF
- RET
- .PMMU_estimate_free_page_count:
- PUSH AF
- PUSH BC
- PUSH DE
- PUSH HL
- LD HL, PMMU_memory_map
- LD B, 0
- LD E, 0
- LD A, (PMMU_max_page)
- LD D, A
- .PMMU_estimate_free_page_count_cloop:
- INC E
- INC HL
- LD A, (HL)
- CP A, 1
- LD A, B
- ADC A, 0
- LD B, A
- LD A, D
- CP A, E
- JP NZ, .PMMU_estimate_free_page_count_cloop
- POP HL
- POP DE
- LD A, B
- POP BC
- LD C, A
- POP AF
- RET
- .KRNL_empty_function:
- PUSH AF
- POP AF
- RET
- .KRNL_get_akt_mounted_page:
- PUSH AF
- PUSH IX
- PUSH HL
- PUSH DE
- PUSH BC
- ;Basisadresse der Prozessliste holen
- LD IX, PROCESS_LIST
- ;PID * 12 aufaddieren
- LD A, (TASK_SCHEDULE.THISPROCESS_PID)
- LD H, 0
- LD L, A
- EX DE, HL
- LD HL, 0
- ADD HL, DE
- ADD HL, DE
- ADD HL, DE
- ADD HL, HL
- ADD HL, HL
- EX DE, HL
- ADD IX, DE
- ;Page-Slot aufaddieren
- LD H, 0
- LD L, C
- EX DE, HL
- ADD IX, DE
- ;Speicherseite auslesen
- LD A, (IX + 4)
- POP BC
- LD C, A
- POP DE
- POP HL
- POP IX
- POP AF
- RET
- .KRNL_suspend_process:
- PUSH AF
- PUSH IX
- PUSH HL
- PUSH DE
- PUSH BC
- ;Basisadresse der Prozessliste holen
- LD IX, PROCESS_LIST
- ;PID * 12 aufaddieren
- LD A, C
- LD H, 0
- LD L, A
- EX DE, HL
- LD HL, 0
- ADD HL, DE
- ADD HL, DE
- ADD HL, DE
- ADD HL, HL
- ADD HL, HL
- EX DE, HL
- ADD IX, DE
- CALL .KRNL_start_atomic
- LD A, (IX + 0)
- OR A, 0000 0010b
- LD (IX + 0), A
- CALL .KRNL_end_atomic
- LD A, (TASK_SCHEDULE.THISPROCESS_PID)
- CP A, C
- CALL Z, 20h
- POP BC
- POP DE
- POP HL
- POP IX
- POP AF
- RET
- .KRNL_resume_process:
- PUSH AF
- PUSH IX
- PUSH HL
- PUSH DE
- PUSH BC
- ;Basisadresse der Prozessliste holen
- LD IX, PROCESS_LIST
- ;PID * 12 aufaddieren
- LD A, C
- LD H, 0
- LD L, A
- EX DE, HL
- LD HL, 0
- ADD HL, DE
- ADD HL, DE
- ADD HL, DE
- ADD HL, HL
- ADD HL, HL
- EX DE, HL
- ADD IX, DE
- CALL .KRNL_start_atomic
- LD A, (IX + 0)
- AND A, 1111 1101b
- LD (IX + 0), A
- CALL .KRNL_end_atomic
- POP BC
- POP DE
- POP HL
- POP IX
- POP AF
- RET
- .KRNL_wait_for_message:
- PUSH AF
- PUSH IX
- PUSH HL
- PUSH DE
- PUSH BC
- ;Basisadresse der Prozessliste holen
- LD IX, PROCESS_LIST
- ;PID * 12 aufaddieren
- LD A, (TASK_SCHEDULE.THISPROCESS_PID)
- LD H, 0
- LD L, A
- EX DE, HL
- LD HL, 0
- ADD HL, DE
- ADD HL, DE
- ADD HL, DE
- ADD HL, HL
- ADD HL, HL
- EX DE, HL
- ADD IX, DE
- CALL .KRNL_start_atomic
- ;Prüfen, ob noch eine Message in der Queue ist
- LD DE, MESSAGE_DATA.PBUFFERS
- LD A, (TASK_SCHEDULE.THISPROCESS_PID)
- LD H, 0
- LD L, A
- ADD HL, HL
- ADD HL, HL
- ADD HL, HL
- ADD HL, DE
- LD D, 0
- LD E, 0
- .KRNL_wait_for_message_checkloop:
- LD A, (HL)
- CP A, 0
- JP Z, .KRNL_wait_for_message_checkloop_not
- LD E, 1
- .KRNL_wait_for_message_checkloop_not:
- INC HL
- INC D
- LD A, D
- CP A, 8
- JP NZ, .KRNL_wait_for_message_checkloop
- ;Wenn keine Message in der Queue ist, warten gehen
- LD A, E
- CP A, 0
- JP NZ, .KRNL_wait_for_message_nochange
- LD A, (IX + 0)
- AND A, 1111 0011b
- OR A, PROCESS_STATE.PS_WAIT_FOR_MESSAGE * 4
- LD (IX + 0), A
- .KRNL_wait_for_message_nochange:
- CALL .KRNL_end_atomic
- LD A, E
- CP A, 0
- JP NZ, .KRNL_wait_for_message_nochange2
- RST 20h
- .KRNL_wait_for_message_nochange2:
- POP BC
- POP DE
- POP HL
- POP IX
- POP AF
- RET
- .KRNL_get_process_flags:
- PUSH AF
- PUSH IX
- PUSH HL
- PUSH DE
- PUSH BC
- ;Basisadresse der Prozessliste holen
- LD IX, PROCESS_LIST
- ;PID * 12 aufaddieren
- LD A, C
- LD H, 0
- LD L, A
- EX DE, HL
- LD HL, 0
- ADD HL, DE
- ADD HL, DE
- ADD HL, DE
- ADD HL, HL
- ADD HL, HL
- EX DE, HL
- ADD IX, DE
- LD A, (IX + 0)
- POP BC
- LD C, A
- POP DE
- POP HL
- POP IX
- POP AF
- RET
- .KRNL_set_process_priority:
- PUSH AF
- PUSH IX
- PUSH HL
- PUSH DE
- PUSH BC
- ;Basisadresse der Prozessliste holen
- LD IX, PROCESS_LIST
- ;PID * 12 aufaddieren
- LD A, C
- LD H, 0
- LD L, A
- EX DE, HL
- LD HL, 0
- ADD HL, DE
- ADD HL, DE
- ADD HL, DE
- ADD HL, HL
- ADD HL, HL
- EX DE, HL
- ADD IX, DE
- CALL .KRNL_start_atomic
- LD A, (IX + 0)
- AND A, 0000 1111b
- SLA B
- SLA B
- SLA B
- SLA B
- OR A, B
- LD (IX + 0), A
- CALL .KRNL_end_atomic
- POP BC
- POP DE
- POP HL
- POP IX
- POP AF
- RET
- .KRNL_send_message:
- PUSH AF
- PUSH BC
- PUSH DE
- PUSH IX
- PUSH IY
- PUSH HL
- CALL .KRNL_start_atomic
- ;1.: Prüfen, ob Ziel-Prozess existiert
- ;HL enthält die Adresse der Message
- LD C, (HL) ;Ziel-PID
- CALL .KRNL_get_process_flags
- LD A, C
- AND A, 0000 0001b
- LD B, 1 ;Fehlercode: Prozess existiert nicht
- CP A, 0000 0000b
- JP Z, .KRNL_send_message_dest_process_not_exist
- ;2.: Freien Speicher im Pool suchen
- ;HL enthält die Adresse der Message
- LD IX, MESSAGE_DATA.MEMPOOL + 16
- LD BC, 16
- LD D, 1
- .KRNL_send_message_mempool_search_loop:
- ;Message-Typ mit 0 vergleichen, wenn ja ---> Speicher gefunden
- LD A, (IX + 2)
- LD E, (IX + 3)
- OR A, E
- CP A, 0
- JP Z, .KRNL_send_message_mem_found
- ADD IX, BC
- INC D
- LD A, D
- CP A, 0
- JP NZ, .KRNL_send_message_mempool_search_loop
- LD B, 2 ;Fehlercode: Speicherpool voll
- JP .KRNL_send_message_mem_full
- .KRNL_send_message_mem_found:
- LD C, D
- ;3.: Freien Speicher im Puffer des Prozesses suchen
- ;HL enthält die Adresse der Message
- ;IX enthält die Adresse des Pool-Speichers
- ;C enthält die Nummer des Pool-Speichers
- LD IY, MESSAGE_DATA.PBUFFERS
- LD D, 0
- LD E, (HL)
- SLA E
- RL D
- SLA E
- RL D
- SLA E
- RL D
- ADD IY, DE
- LD D, 0
- .KRNL_send_message_procbuf_search_loop:
- LD A, (IY + 0)
- CP A, 0
- JP Z, .KRNL_send_message_procbuf_mem_found
- INC IY
- INC D
- LD A, D
- CP A, 8
- JP NZ, .KRNL_send_message_procbuf_search_loop
- LD B, 3 ;Fehlercode: Prozess-Puffer voll
- JP .KRNL_send_message_procbuf_full
- .KRNL_send_message_procbuf_mem_found:
- ;4.: Message eintragen
- ;HL enthält die Adresse der Message
- ;IX enthält die Adresse des Pool-Speichers
- ;C enthält die Nummer des Pool-Speichers
- ;IY enthält die Adresse des Puffer-Slots
- ;Pool-Speicher-Nummer wird hiernach nicht mehr benötigt ---> C ist frei
- LD (IY + 0), C
- ;Message in den Kernelspeicher kopieren
- PUSH HL
- LD BC, 16
- PUSH IX
- POP DE
- LDIR
- POP HL
- ;5.: Prozess eventuell aufwecken
- ;HL enthält die Adresse der Message
- LD C, (HL)
- CALL .KRNL_get_process_flags
- LD A, C
- AND A, 0000 1100b
- CP A, PROCESS_STATE.PS_WAIT_FOR_MESSAGE * 4
- JP NZ, .KRNL_send_message_noresume
- ;Basisadresse der Prozessliste holen
- LD IX, PROCESS_LIST
- ;PID * 12 aufaddieren
- LD A, (HL)
- LD H, 0
- LD L, A
- EX DE, HL
- LD HL, 0
- ADD HL, DE
- ADD HL, DE
- ADD HL, DE
- ADD HL, HL
- ADD HL, HL
- EX DE, HL
- ADD IX, DE
- LD A, (IX + 0)
- AND A, 1111 0011b
- OR A, PROCESS_STATE.PS_NORMAL * 4
- LD (IX + 0), A
- .KRNL_send_message_noresume:
- ;Fehlercode setzen und fertig!
- LD B, 0
- .KRNL_send_message_procbuf_full:
- .KRNL_send_message_mem_full:
- .KRNL_send_message_dest_process_not_exist:
- CALL .KRNL_end_atomic
- POP HL
- POP IY
- POP IX
- POP DE
- LD A, B
- POP BC
- LD B, A
- POP AF
- RET
- .KRNL_get_message_count:
- PUSH AF
- PUSH BC
- PUSH HL
- ;Startadresse des Messagepuffers dieses Prozesses bestimmen (--> HL)
- LD BC, MESSAGE_DATA.PBUFFERS
- LD H, 0
- LD A, (TASK_SCHEDULE.THISPROCESS_PID)
- LD L, A
- SLA L
- RL H
- SLA L
- RL H
- SLA L
- RL H
- ADD HL, BC
- LD BC, 0
- .KRNL_get_message_count_sloop:
- LD A, (HL)
- CP A, 0
- JP Z, .KRNL_get_message_count_empty_slot
- INC C
- .KRNL_get_message_count_empty_slot:
- INC HL
- INC B
- LD A, B
- CP A, 8
- JP NZ, .KRNL_get_message_count_sloop
- POP HL
- LD A, C
- POP BC
- LD C, A
- POP AF
- RET
- .KRNL_get_messages:
- PUSH AF
- PUSH BC
- PUSH DE
- PUSH HL
- PUSH IX
- PUSH IY
- EX DE, HL
- ;Startadresse des Messagepuffers dieses Prozesses bestimmen (--> IX)
- LD IX, MESSAGE_DATA.PBUFFERS
- LD B, 0
- LD A, (TASK_SCHEDULE.THISPROCESS_PID)
- LD C, A
- SLA C
- RL B
- SLA C
- RL B
- SLA C
- RL B
- ADD IX, BC
- CALL .KRNL_start_atomic
- ;Zusammenkopieren und Löschen der Messages aus dem Speicherpool
- LD C, 0
- .KRNL_get_messages_transferloop:
- LD H, 0
- LD L, (IX + 0)
- LD (IX + 0), 0
- ADD HL, HL
- ADD HL, HL
- ADD HL, HL
- ADD HL, HL
- PUSH DE
- LD DE, MESSAGE_DATA.MEMPOOL
- ADD HL, DE
- POP DE
- LD B, 16
- .KRNL_get_messages_copyloop:
- LD A, (HL)
- LD (DE), A
- LD (HL), 0
- INC HL
- INC DE
- DJNZ .KRNL_get_messages_copyloop
- INC C
- INC IX
- LD A, C
- CP A, 8
- JP NZ, .KRNL_get_messages_transferloop
- CALL .KRNL_end_atomic
- POP IY
- POP IX
- POP HL
- POP DE
- POP BC
- POP AF
- RET
- .KRNL_clear_process_message_buffer:
- PUSH AF
- PUSH BC
- PUSH DE
- PUSH HL
- PUSH IX
- PUSH IY
- EX DE, HL
- ;Startadresse des Messagepuffers dieses Prozesses bestimmen (--> IX)
- LD IX, MESSAGE_DATA.PBUFFERS
- LD B, 0
- LD A, (TASK_SCHEDULE.THISPROCESS_PID)
- LD C, A
- SLA C
- RL B
- SLA C
- RL B
- SLA C
- RL B
- ADD IX, BC
- CALL .KRNL_start_atomic
- ;Löschen der Messages aus dem Speicherpool
- LD C, 0
- .KRNL_clear_process_message_buffer_transferloop:
- LD H, 0
- LD L, (IX + 0)
- LD (IX + 0), 0
- ADD HL, HL
- ADD HL, HL
- ADD HL, HL
- ADD HL, HL
- PUSH DE
- LD DE, MESSAGE_DATA.MEMPOOL
- ADD HL, DE
- POP DE
- LD B, 16
- .KRNL_clear_process_message_buffer_copyloop:
- LD A, (HL)
- ;LD (DE), A
- LD (HL), 0
- INC HL
- INC DE
- DJNZ .KRNL_clear_process_message_buffer_copyloop
- INC C
- INC IX
- LD A, C
- CP A, 8
- JP NZ, .KRNL_clear_process_message_buffer_transferloop
- CALL .KRNL_end_atomic
- POP IY
- POP IX
- POP HL
- POP DE
- POP BC
- POP AF
- RET
- .KRNL_register_driver:
- PUSH AF
- PUSH BC
- PUSH DE
- PUSH HL
- PUSH IX
- CALL .KRNL_start_atomic
- LD IX, DRIVER_DATA.DLIST
- LD DE, 4
- LD B, 0
- .KRNL_register_driver_memsearch:
- ADD IX, DE
- INC B
- LD A, (IX + 2)
- OR A, (IX + 3)
- JP Z, .KRNL_register_driver_memfound
- LD A, B
- CP A, 255
- JP NZ, .KRNL_register_driver_memsearch
- LD B, 0
- JP .KRNL_register_driver_memfull
- .KRNL_register_driver_memfound:
- LD A, (TASK_SCHEDULE.THISPROCESS_PID)
- LD (IX + 0), A
- LD (IX + 1), C
- LD (IX + 2), L
- LD (IX + 3), H
- .KRNL_register_driver_memfull:
- CALL .KRNL_end_atomic
- POP IX
- POP HL
- POP DE
- LD A, B
- POP BC
- LD C, A
- POP AF
- RET
- .KRNL_unregister_driver:
- PUSH AF
- PUSH BC
- PUSH HL
- LD H, 0
- LD L, C
- ADD HL, HL
- ADD HL, HL
- LD BC, DRIVER_DATA.DLIST
- ADD HL, BC
- CALL .KRNL_start_atomic
- LD (HL), 0
- INC HL
- LD (HL), 0
- INC HL
- LD (HL), 0
- INC HL
- LD (HL), 0
- CALL .KRNL_end_atomic
- POP HL
- POP BC
- POP AF
- RET
- .KRNL_get_driver_by_type:
- PUSH AF
- PUSH BC
- PUSH DE
- ;PUSH HL
- PUSH IX
- LD A, C
- CP A, 1
- ADC A, 0
- LD C, A
- EX DE, HL
- LD H, 0
- LD L, C
- ADD HL, HL
- ADD HL, HL
- EX DE, HL
- LD IX, DRIVER_DATA.DLIST
- ADD IX, DE
- LD DE, 4
- .KRNL_get_driver_by_type_sloop:
- LD A, L
- CP A, (IX + 2)
- JP NZ, .KRNL_get_driver_by_type_nohit
- LD A, H
- CP A, (IX + 3)
- JP Z, .KRNL_get_driver_by_type_hit
- .KRNL_get_driver_by_type_nohit:
- INC C
- ADD IX, DE
- LD A, C
- CP A, 0
- JP NZ, .KRNL_get_driver_by_type_sloop
- .KRNL_get_driver_by_type_hit:
- LD H, (IX + 0)
- LD L, (IX + 1)
- LD A, C
- CP A, 0
- JP NZ, .KRNL_get_driver_by_type_noerr
- LD HL, 0
- .KRNL_get_driver_by_type_noerr:
- POP IX
- ;POP HL
- POP DE
- LD A, C
- POP BC
- LD C, A
- POP AF
- RET
- .finish:
- POP IY
- POP AF
- RET
- .KRNL_create_process_from_memory_pstor1:
- DB 0
- .KRNL_create_process_from_memory_pstor2:
- DB 0
- .KRNL_create_process_from_memory_pstor3:
- DB 0
Advertisement
Add Comment
Please, Sign In to add comment