Tao3D: State machine

Direction -> "horizontal"
Movement  -> "sinus"

locally
    adjust_position Direction
    adjust_movement Movement
    draw_shape_for Direction, Movement

button -1, 0, "Horizontal", Direction, "horizontal"
button  0, 0, "Vertical",   Direction, "vertical"
button  1, 0, "Changing",   Direction, "changing"

button -1, 1, "Sinus",      Movement, "sinus"
button  0, 1, "Step",       Movement, "step"
button  1, 1, "Wave",       Movement, "wave"


adjust_position "horizontal" -> false
adjust_position "vertical"   -> rotate_z 90
adjust_position "changing"   -> rotate_z 20 * time

adjust_movement "sinus"      -> translate_x 200 * sin time
adjust_movement "step"       -> translate_x 50 * seconds mod 500 - 250
adjust_movement "wave"       -> translate 50 * time mod 500 - 250, 100 * sin time, 0


draw_shape_for "horizontal", "sinus" ->
    color "orange"
    triangle 0, 0, 100, 100

draw_shape_for "horizontal", Mov ->
    color "green"
    circle 0, 0, 100

draw_shape_for Dir, "step" ->
    color "blue"
    star 0, 0, 100, 100, 5, 0.5

draw_shape_for Dir, Mov ->
    color "red"
    rounded_rectangle 0, 0, 320, 200, 200

button X, Y, Label, Variable, Value ->
    active_widget
        color "white"
        linear_gradient 0, 0, 0, 32, 32, 32,
            gradient_color 0%, "grey"
            gradient_color 50%, "black"
            gradient_color 100%, "darkblue"
        rounded_rectangle X*120, Y*50, 100, 30, 30
        on_click
            Variable := Value
            refresh 0

    text_box X*120, Y*50, 100, 30,
        color (if Variable = Value then "yellow" else "white")
        align_center
        vertical_align_center
        font "Ubuntu", 18
        text Label

draw_selection X, Y, W, H -> false