PrivateCars (c) by Kaliber

/* Sa-Mp Include Privat-Cars
 *
 * (c) by Kaliber, 2012
 *
 */
#include <a_samp>
#pragma tabsize 0 //Nur hier in pastebin

enum Privat_Enum_Info {
    _modelid,
    Float:_X,
    Float:_Y,
    Float:_Z,
    Float:_A,
    _c1,
    _c2,
    _respawn,
    vID
};
new Player_Info[MAX_PLAYERS][3],Privat_Car[MAX_VEHICLES][Privat_Enum_Info];

stock bool:IsAPrivatCar(vehicleid)
{
    new count, i;
    for(; i<MAX_VEHICLES; i++)
    {
        if(Privat_Car[i][vID] == vehicleid) {
            count++; break;
        }
    }
    if(!count) return false;
    else return true;
}
stock bool:IsPrivatOwner(playerid,vehicleid)
{
    for(new i; i<3; i++)
    {
        if(Player_Info[playerid][i] == vehicleid) return true;
    }
    return false;
}
stock RemovePrivatCar(playerid,vehicleid)
{
    for(new i; i<3; i++)
    {
        if(Player_Info[playerid][i] == vehicleid)
        {
            Player_Info[playerid][i] = 0;
            break;
        }
    }
    return 1;
}

stock GetPrivatOwner(vehicleid)
{
    new i;
    for(; i<MAX_PLAYERS; i++)
    {
        if(!IsPlayerConnected(i)) continue;
        if(IsPrivatOwner(i,vehicleid)) return i;
    }
    return -1;
}

stock GetFreeSlots(playerid)
{
    new i;
    for(; i<3; i++)
    {
        if(Player_Info[playerid][i] == 0) return i;
    }
    return -1;
}

stock CreatePrivatCar(modelid,Float:X,Float:Y,Float:Z,Float:A,farbe1,farbe2,respawn)
{
    new veh = CreateVehicle(modelid,X,Y,Z,A,farbe1,farbe2,respawn);
    Privat_Car[veh][vID] = veh;
    Privat_Car[veh][_modelid] = modelid;
    Privat_Car[veh][_X] = X;
    Privat_Car[veh][_Y] = Y;
    Privat_Car[veh][_Z] = Z;
    Privat_Car[veh][_A] = A;
    Privat_Car[veh][_c1] = farbe1;
    Privat_Car[veh][_c2] = farbe2;
    Privat_Car[veh][_respawn] = respawn;
    return veh;
}

stock GetPrivatId(playerid, slotid)
{
    return Player_Info[playerid][slotid];
}

stock GivePlayerPrivatCar(playerid,vehicleid)
{
    if(!IsAPrivatCar(vehicleid)) return SendClientMessage(playerid,0xFF0000FF,"Dieses Fahrzeug ist kein Privat Auto !");
    if(GetFreeSlots(playerid) == -1) return SendClientMessage(playerid,0xFF0000FF,"Du besitzt schon 3 PrivatCars !");
    Player_Info[playerid][GetFreeSlots(playerid)] = vehicleid;
    return 1;
}

stock SellPlayerPrivatCar(playerid,pID,vehicleid,Preis)
{
    if(!IsAPrivatCar(vehicleid)) return SendClientMessage(playerid,0xFF0000FF,"Dieses Fahrzeug ist kein Privat Auto !");
    if(!IsPrivatOwner(playerid,vehicleid)) return SendClientMessage(playerid,0xFF0000FF,"Du bist nicht der Besitzer dieses Fahrzeuges !");
    if(GetFreeSlots(pID) == -1) return SendClientMessage(playerid,0xFF0000FF,"Dieser Spieler besitzt schon 3 PrivatCars !");
    if(GetPlayerMoney(pID) < Preis) return SendClientMessage(playerid,0xFF0000FF,"Dieser Spieler besitzt nicht genug Geld für dieses Auto !");
    RemovePrivatCar(playerid,vehicleid);
    GivePlayerPrivatCar(pID,vehicleid);
    GivePlayerMoney(playerid, Preis);
    GivePlayerMoney(pID, -Preis);
    return 1;
}