/*  TITULO: Detector de partículas de polvo en el aire con sensor GP2Y10

    AUTOR:

    MARIANO DEL CAMPO GARCÍA (@2016) --> INGENIERO TÉCNICO INDUSTRIAL ESPECIALIDAD ELECTRÓNICA
    - FACEBOOK: https://www.facebook.com/mariano.delcampogarcia
    - TWITTER: https://twitter.com/MarianoCampoGa
    - CORREO: [email protected]


    DESCRIPCIÓN DEL PROGRAMA

    En este programa vamos a obtener el valor de densidad de partículas del polvo en mg/m³ y la
    concentración de partículas de polvo en ppm, además de obtener el voltaje entre los terminales
    de salida del sensor GP2Y10 de SHARP. Podremos visualizar dichos valores a través del LCD 1602
    que tenemos conectado mediante comunicación I2C a nuestro Arduino.


    ESQUEMA DE CONEXION

                                        +-----+
           +----[PWR]-------------------| USB |--+
           |                            +-----+  |
           |         GND/RST2  [ ][ ]            |
           |       MOSI2/SCK2  [ ][ ]  A5/SCL[ ] |  SCL del módulo I2C
           |          5V/MISO2 [ ][ ]  A4/SDA[ ] |  SDA del módulo I2C
           |                             AREF[ ] |
           |                              GND[ ] |
           | [ ]N/C                    SCK/13[ ] |
           | [ ]IOREF                 MISO/12[ ] |
           | [ ]RST                   MOSI/11[ ]~|
           | [ ]3V3    +---+               10[ ]~|
           | [ ]5v    -| A |-               9[ ]~|
           | [ ]GND   -| R |-               8[ ] |
           | [ ]GND   -| D |-                    |
           | [ ]Vin   -| U |-               7[ ] |
           |          -| I |-               6[ ]~|
Pin 5 (Vo) | [ ]A0    -| N |-               5[ ]~|
           | [ ]A1    -| O |-               4[ ] |
           | [ ]A2     +---+           INT1/3[ ]~|
           | [ ]A3                     INT0/2[ ] |  Pin 3 (LED) del sensor GP2Y10
           | [ ]A4/SDA  RST SCK MISO     TX>1[ ] |
           | [ ]A5/SCL  [ ] [ ] [ ]      RX<0[ ] |
           |            [ ] [ ] [ ]              |
           |  UNO_R3    GND MOSI 5V  ____________/
            \_______________________/

  NOTAS:

   - Conexiones del sensor GP2Y10:
       - Pin 1 (V-LED) del sensor GP2Y10 --> +5V de Arduino a través de una resistencia de R=150 ohm.
       - Pin 2 (LED-GND) del sensor GP2Y10 --> GND de Arduino.
       - Pin 1 ((V-LED) del sensor GP2Y10 --> Pin 2 (LED-GND) del sensor a través de C=220uF.
       - Pin 4 (S-GND) del sensor GP2Y10 --> GND de Arduino.
       - Pin 6 (VCC) del sensor GP2Y10 --> +5V de Arduino
   - La alimentación y la masa del módulo LCM 1602 I2C V1 van directamente conectadas a VCC (+5V) y GND
     respectivamente.
*/

  // Importar librerías
  #include <Wire.h> // Librería comunicación I2C
  #include <LiquidCrystal_I2C.h> // Librería LCD I2C

  // Declaración del objeto
  // Poner la dirección del LCD a 0x27 para display 16x2, 20x2 y 20x4
  // Terminales de conexión del LCD
  //                    addr, en,rw,rs,d4,d5,d6,d7,bl,blpol
  LiquidCrystal_I2C lcd(0x27, 2, 1, 0, 4, 5, 6, 7, 3, POSITIVE);

  int muestreo = 0; // Pin analógico para el pin Vo del sensor GP2Y10
  int IRED = 2; // Pin digital para el IRED

  // Tiempos constantes para el pulso de control del IRED
  int retardo_1 = 280;
  int retardo_2 = 40;
  int retardo_3 = 9680;

  // Variables auxiliares del programa
  int valor = 0;
  float ppm = 0;
  float voltaje = 0;
  float densidad_polvo = 0;
  float ppm_real = 0;
  int i=0;

  void setup()
  {
    lcd.begin(16,2);   // Inicializa el LCD para 16x2
    pinMode(IRED,OUTPUT); // Pin digital 2 como salida

    // Mostramos un mensaje a través del LCD 1602
    lcd.clear();
    lcd.setCursor(0,0);
    lcd.print("  DETECTOR  DE  ");
    lcd.setCursor(0,1);
    lcd.print("PARTICULAS POLVO");
    delay(3000);
  }

  void loop()
  {
    i=i+1; // Contador de pulsos de control
    // El IRED se va a activar con LOW y se desactiva con HIGH según las conexiones internas del sensor
    digitalWrite(IRED,LOW); // LED activado
    delayMicroseconds(retardo_1); // Retardo de 0,28ms
    valor = analogRead(muestreo); // Se muestrea el valor de Vo a través del pin analógico A0
    ppm = ppm + valor; // Media ponderada de Vo
    delayMicroseconds(retardo_2); // Retardo de 0,04ms
    digitalWrite(IRED,HIGH); // LED desactivado
    delayMicroseconds(retardo_3); // Retardo de 9,68ms
    // retardo_1 + retardo_2 + retardo_3 = 10ms

    // Fórmulas matemáticas para el cálculo de los valores del sensor GP2Y10
    voltaje = ppm/i*0.0049; // Voltaje en voltios (media de los valores ppm obtenidos)
    densidad_polvo = 0.17*voltaje-0.1; // Densidad de partículas de polvo en mg/m³
    ppm_real = (voltaje-0.0356)*120000; // Concentración de partículas de polvo en ppm
    if (ppm_real < 0)
      ppm_real = 0;
    if (densidad_polvo < 0 )
      densidad_polvo = 0;
    if (densidad_polvo > 0.5)
      densidad_polvo = 0.5;

    // Presentamos el voltaje a través del LCD 1602
    lcd.clear();
    lcd.setCursor(0,0);
    lcd.print("-> VOLTAJE");
    lcd.setCursor(0,1);
    lcd.print(voltaje,3); // Tres decimales
    lcd.print(" V");
    delay(2000);

    // Presentamos la densidad de partículas de polvo a través del LCD 1602
    lcd.clear();
    lcd.setCursor(0,0);
    lcd.print("-> DENSIDAD");
    lcd.setCursor(0,1);
    lcd.print(densidad_polvo,3); // Tres decimales
    lcd.print(" mg x m3");
    delay(2000);

    // Presentamos la concentración de partículas de polvo a través del LCD 1602
    lcd.clear();
    lcd.setCursor(0,0);
    lcd.print("-> CONCENTRACION");
    lcd.setCursor(0,1);
    lcd.print(ppm_real,3); // Tres decimales
    lcd.print(" ppm");
    delay(2000);
  }