assoctomap:{x[;0]!x[;1]}
htmlcharassoc:(("&";"&amp;");(" ";"&nbsp;");("'";"&#39;");("\"";"&quot;");("<";"&lt;");(">";"&gt;"))
htmlmap:assoctomap htmlcharassoc
convertvia:{[map;thing] raze {f:x[y];$[""~f;y;f]}[map;] each thing}
htmlescape:{convertvia[htmlmap;x]}
/urlcharassoc:(("+";" ");("x";"x"))
/urlmap:assoctomap urlcharassoc
conv:{y sv x vs z}
fromurl:{conv["%2C";","] conv["%20";" "] conv["+";" "] x}
attrtostring:{[a]$[a~();"";" "sv{string[x],"=\"",y[x],"\""}[;a] each key a]}
tag:{[namesym;attrib]"<",string[namesym]," ",attrtostring[attrib],">"}
etag:{"</",string[x],">"}
htmli:{t:type x;c:count x;
       $[t;t;$[c=2;tag[x[0];()];tag[x[0];x[1]]],$[type x[c-1];htmlescape x[c-1];$[type x[c-1][0];html x[c-1];html each x[c-1]]],etag x[0]]}
html:{raze htmli x}
successhtml:"HTTP/1.1 200 OK\r\nContent-Type: text/html\r\n"
page:{successhtml,"\r\n",html x}
pageh:{successhtml,sv["\r\n";(string each key x) ,' ,[": "] each (value x)],"\r\n\r\n", html y}
/ need cookie stuff
/ Set-Cookie: HSID=AYQEVn….DKrdst; Domain=.foo.com; Path=/; Expires=Wed, 13 Jan 2021 22:23:01 GMT; HttpOnly
/ MaxAge or expiry (forgot exact name for "expiry")
params:{assoctomap each[fromurl] each vs["="] each vs["&"] vs["?";x[0]][1]}
cookies:{c:x[1][`Cookie];$[""~c;0;assoctomap vs["="] each  "; " vs c]}


pages:(("home";
        {page (`html;
               ((`h1;"WELCOME TO THE HOMEPAGE");
                (`form;`id`action!("search";"/greet");
                      ((`input;(enlist `name)!enlist"name";());
                       (`input;`type`value!("submit";"say hello");())));
                (`body;(`p;"this page is awesome"))))});
       ("data.tsv";{"HTTP/1.1 200 OK\r\nContent-Type: text/tsv\r\n\r\n","\n"sv read0 `:data.tsv});
       ("greet";
        {page (`html;
               (`h1; "greetings ", 0N!params[x]["name"],"!!!"))});
       ("cookies";
        {page (`html; .Q.s cookies x)});
       ("newcookie";
        {pageh[enlist[`$"Set-Cookie"]!enlist "value=",(string rand 1000),"; Path=/cookies;"]
         (`html;(`h1; "This Page Gives You A Cookie!"))});
       ("another";
        {"HTTP/1.1 200 OK\r\nContent-Type: text/html\r\n\r\n", raze sv["\n";read0 `:graph.js], html (`html;
               ((`h1;"ANOTHER PAGE");
                (`body;(`p;"this is for stuff that doesn't fit on the homepage"))))}))
p:assoctomap pages

.z.ph:{0N!x[0];r:p[vs["?";x[0]][0]];$[100h~type r;r[x];"UNKNOWN PAGE"]}
.z.w:{}
.z.ws:{}