Guest User

wallch pro file

a guest
Nov 23rd, 2014
217
Never
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
  1. TEMPLATE = app
  2. TARGET = wallch
  3. DEPENDPATH += . data/translations src/
  4. INCLUDEPATH += .
  5.  
  6. CONFIG += c++11
  7.  
  8. QT += network widgets webkitwidgets
  9.  
  10. win32 {
  11. QT += gui-private
  12. DEFINES += ON_WIN32
  13. } else {
  14. DEFINES += ON_LINUX
  15. CONFIG += link_pkgconfig
  16. PKGCONFIG += appindicator-0.1 unity libnotify libexif keybinder
  17. }
  18.  
  19. isEmpty(PREFIX) {
  20. PREFIX = /usr
  21. }
  22.  
  23. DEFINES += "PREFIX=\\\"$$PREFIX\\\""
  24.  
  25. # Input
  26. VPATH += ./src
  27. HEADERS += about.h \
  28. glob.h \
  29. history.h \
  30. mainwindow.h \
  31. preferences.h \
  32. properties.h \
  33. statistics.h \
  34. website_preview.h \
  35. crop_image.h \
  36. colors_gradients.h \
  37. nongui.h \
  38. potd_viewer.h \
  39. notification.h \
  40. potd_preview.h \
  41. websitesnapshot.h \
  42. customwebpage.h \
  43. wallpapermanager.h
  44.  
  45. FORMS += about.ui \
  46. history.ui \
  47. mainwindow.ui \
  48. preferences.ui \
  49. properties.ui \
  50. statistics.ui \
  51. website_preview.ui \
  52. crop_image.ui \
  53. colors_gradients.ui \
  54. potd_viewer.ui \
  55. notification.ui \
  56. potd_preview.ui
  57.  
  58. SOURCES += about.cpp \
  59. glob.cpp \
  60. history.cpp \
  61. main.cpp \
  62. mainwindow.cpp \
  63. preferences.cpp \
  64. properties.cpp \
  65. statistics.cpp \
  66. website_preview.cpp \
  67. crop_image.cpp \
  68. colors_gradients.cpp \
  69. nongui.cpp \
  70. potd_viewer.cpp \
  71. notification.cpp \
  72. potd_preview.cpp \
  73. websitesnapshot.cpp \
  74. wallpapermanager.cpp
  75.  
  76. RESOURCES += src/resources.qrc
  77.  
  78. TRANSLATIONS += data/translations/wallch_el.ts
  79.  
  80. configfiles.files += data/to_usr_share/*
  81. configfiles.path = $$PREFIX/share
  82. unix:configfiles.extra = lrelease -silent data/translations/wallch_el.ts -qm data/to_usr_share/wallch/translations/wallch_el.qm
  83. INSTALLS += configfiles
RAW Paste Data