// synthdef copied from "stealthissound" -> https://composerprogrammer.com/code.html

(
SynthDef(\everythingrhodes,{|out= 0 freq = 440 amp = 0.1 gate=1 lforate = 4.85 lfowidth= 0.5 cutoff= 2000 rq=0.5 pan = 0.0|
    var pulse, filter, env;
    pulse = Pulse.ar(freq*[1,33.5.midiratio],[0.2,0.1],[0.7,0.3]);
    env = EnvGen.ar(Env.adsr(0.0,1.0,0.8,3.0),gate,doneAction:2);
    //keyboard tracking filter cutoff
    filter = BLowPass4.ar(pulse,(cutoff*(env.squared))+200+freq,rq);
    Out.ar(out,Pan2.ar(Mix(filter)*env*amp,pan));
}).add;
)

(
Pbind(
    \instrument,\everythingrhodes,

    \midinote, Pseq([
        Pseq([[-8,-3,1]], 4),
        [-8,-3,1], [-11,-4,-1], [-8,1,4], [13,18], [11,16],
        Pseq([[8, 13], [11, 16], [13, 18], [11, 16]], 2),
        [8, 13], [6, 11], [8, 13], [6, 11], [8, 13], [13, 18], [11, 16]
    ]+60, inf),

    \dur,Pseq([
        0.75, 0.50, 0.50, 0.25,
        0.50, 0.50, 0.50, 0.25, 0.25,
        Pseq([0.25], 8),
        Pseq([0.26], 6), 0.5
    ],inf),

    \cutoff,Pstutter(11,Pn(Pseries(500,500,4),inf)),
    \legato, 0.5
).play(TempoClock(86/60))
)