OLC Challenge #18

SuperStrict
SetGraphicsDriver(GLMax2DDriver())
AppTitle = "Fly Tesko Home"
Graphics(640, 480, 0, 144)
SetVirtualResolution(160, 120)
SetMaskColor(255, 0, 255)

'Variables
Global PlayerX:Float = 80
Global PlayerY:Float = 140
Global PlayerVX: Float = 0
Global PlayerScore:Int = 0

Global BackgroundScrollY:Float = 0

Global SpawnTime:Int
Global SpawnOldTime:Int

Global GameTime:Int
Global GameOldTime:Int

Global GameState:Int = 0 '0 = Menu, 1 = Main Game, 2 = Game Over

'GFX
Global GFXBackground:TImage = LoadImage("gfx\background_stars.bmp")
Global GFXPlayer:TImage = LoadImage("gfx\ship.bmp", MASKEDIMAGE | FILTEREDIMAGE)
Global GFXAsteroid:TImage = LoadImage("gfx\asteroid.bmp", MASKEDIMAGE | FILTEREDIMAGE); MidHandleImage(GFXAsteroid)
Global GFXExplosion:TImage = LoadAnimImage("gfx\explosion.bmp", 24, 24, 0, 7, MASKEDIMAGE | FILTEREDIMAGE); MidHandleImage(GFXExplosion)

'Types
Type Entity
    Field X:Float
    Field Y:Float
    Field A:Float

    Method Update() Abstract
EndType

Type Asteroid Extends Entity
    Function Spawn:Asteroid()
        Local A:Asteroid = New Asteroid
        A.X = Rand(0, 15) * 10 + 5
        A.Y = -10
        A.A = Rand(0, 360)

        Return A
    EndFunction

    Method Update()
        Y = Y + 1
        A = A + 0.5; If A > 360 Then A = 0

        SetRotation(A); DrawImage GFXAsteroid, X, Y; SetRotation(0)
    EndMethod
EndType

Type Explosion Extends Entity
    Field Frame:Int
    Field Time:Int
    Field OldTime:Int = 0

    Function Spawn:Explosion(x:Int, y:Int)
        Local E:Explosion = New Explosion
        E.X = x
        E.Y = y

        Return E
    EndFunction

    Method Update()
        If OldTime = 0 Then OldTime = MilliSecs()
        Time = MilliSecs() - OldTime

        If Time > 71 Then
            Frame = Frame + 1
            OldTime = 0
        EndIf

        SetScale(0.5, 0.5); DrawImage(GFXExplosion, X, Y, Frame); SetScale(1, 1)
    EndMethod
EndType

Global AstList:TList = New TList
Global Ast:Asteroid
Global ExpList:TList = New TList
Global Exp1:Explosion

While Not AppTerminate()
    Select GameState
    Case 0 'Main menu
        UpdateMainMenu()
    Case 1 'Game
        UpdateGame()
    Case 2 'Game Over Screen
        UpdateGameOverScreen()
    EndSelect

    Flip(True)

    Cls
Wend

End

'Functions

Function UpdateMainMenu()
    If KeyDown(KEY_ENTER) Then
        GameState = 1
        GameTime = 0
        GameOldTime = 0
    EndIf

    If GameOldTime = 0 Then GameOldTime = MilliSecs()
    GameTime = MilliSecs() - GameOldTime

    BackgroundScrollY = BackgroundScrollY + 1
    TileImage(GFXBackground, 0, BackgroundScrollY)

    SetColor(255, 200, 0); DrawText2("-FLY TESKO HOME-", 80, 15, 1, 1); SetColor(255, 255, 255)
    If GameTime > 500 Then DrawText2("Press [Enter]", 80, 60, 1, 1)
    If GameTime > 1000 Then GameOldTime = 0
EndFunction

Function UpdateGameOverScreen()
    If GameOldTime = 0 Then GameOldTime = MilliSecs()
    GameTime = MilliSecs() - GameOldTime

    BackgroundScrollY = BackgroundScrollY + 1
    TileImage(GFXBackground, 0, BackgroundScrollY)

    For Ast = EachIn AstList
        If Ast.Y > 130 Then AstList.Remove(Ast)

        Ast.Update()
    Next

    For Exp1 = EachIn ExpList
        If Exp1.Frame = 6 Then ExpList.Remove(Exp1)
        Exp1.Update()
    Next

    If GameTime > 1000
        SetColor(255, 0, 0); DrawText2("GAME OVER!", 80, 60, 1, 1); SetColor(255, 255, 255)
        DrawText2("Score: " + PlayerScore, 80, 10, 1, 1)

        If KeyDown(KEY_ENTER) Then 'If Enter is pressed Then Play again!
            GameTime = 0
            GameOldTime = 0
            PlayerScore = 0
            PlayerX = 80
            PlayerY = 130
            PlayerVX = 0
            GameState = 1
        ElseIf GameTime > 10000 Or KeyDown(KEY_ESCAPE) 'If Escape or no key are pressed then return to main menu
            GameTime = 0
            GameOldTime = 0
            PlayerScore = 0
            PlayerX = 80
            PlayerY = 130
            PlayerVX = 0
            GameState = 0
        EndIf
    EndIf
EndFunction

Function UpdateGame()
    If GameOldTime = 0 Then GameOldTime = MilliSecs()
    GameTime = MilliSecs() - GameOldTime

    If GameTime > 2000 Then
        If KeyDown(KEY_A) And PlayerX > 0 Then
            PlayerVX = PlayerVX - 0.25
        ElseIf KeyDown(KEY_D) And PlayerX < 150  Then
            PlayerVX = PlayerVX + 0.25
        Else
            PlayerVX = 0
        EndIf

        'Clamp Player Vel
        If PlayerVX >  1 Then PlayerVX = 1
        If PlayerVX < -1 Then PlayerVX =-1

        PlayerX = PlayerX + PlayerVX

        If SpawnOldTime = 0 Then SpawnOldTime = MilliSecs()
        SpawnTime = MilliSecs() - SpawnOldTime

        'Spawn Asteroids every 100 millisecs
        If SpawnTime > 100 Then
            AstList.AddLast(Asteroid.Spawn())
            SpawnOldTime = 0
        EndIf

        PlayerScore = (GameTime - 2000) / 10
    Else
        'Ship entry animation
        PlayerY = PlayerY - 0.5
        If PlayerY < 100 Then PlayerY = 100
    EndIf

    'Draw GFX
    BackgroundScrollY = BackgroundScrollY + 1
    TileImage(GFXBackground, 0, BackgroundScrollY)

    'Draw Player
    DrawImage(GFXPlayer, PlayerX, PlayerY)

    'Update Asteroids
    For Ast = EachIn AstList
        If Ast.Y > 130 Then AstList.Remove(Ast)

        'Check collision between player and asteroids
        If RectsOverlap(PlayerX + 2, PlayerY, 6, 10, Ast.X - 5, Ast.Y - 5, 10, 10) Then
            ExpList.AddLast(Explosion.Spawn(PlayerX + 5, PlayerY + 5))
            GameTime = 0
            GameOldTime = 0
            GameState = 2
        EndIf

        Ast.Update()
    Next

    'Update Explosions
    For Exp1 = EachIn ExpList
        If Exp1.Frame = 6 Then ExpList.Remove(Exp1)
        Exp1.Update()
    Next

    DrawText2(PlayerScore, 80, 10, 1, 1)
EndFunction

Function DrawText2(text:String, x:Float, y:Float, cx:Int = 0, cy:Int = 0)
    If cx Then x = x - (TextWidth(text) * 0.5)
    If cy Then y = y - (TextHeight(text) * 0.5)

    DrawText(text, x, y)
EndFunction

Rem
Function DrawWireRect(x:Float,y:Float,w:Float,h:Float)
    DrawLine(x, y, x + w, y)
    DrawLine(x + w, y, x + w, y + w)
    DrawLine(x + w, y + h, x, y + h)
    DrawLine(x, y, x, y + h)
EndFunction
EndRem

Function RectsOverlap:Int(x1:Float, y1:Float, w1:Float, h1:Float, x2:Float, y2:Float, w2:Float, h2:Float)
    If x1 > (x2 + w2) Or (x1 + w1) < x2 Then Return False
    If y1 > (y2 + h2) Or (y1 + h1) < y2 Then Return False
    Return True
End Function