Projector shader code

Shader "Custom/Projector" {
   Properties {
      _ShadowTex ("Projected Image", 2D) = "white" {}
      _speed("Speed",Range(0.01,0.1)) = 0.05
      _ShadowIntensity ("Opacity of the shadows",Range(3,10)) = 5
   }
   SubShader {
      Pass {
         Blend One One
            // add color of _ShadowTex to the color in the framebuffer
         ZWrite Off // don't change depths
         Offset -1, -1 // avoid depth fighting

         CGPROGRAM

         #pragma vertex vert
         #pragma fragment frag

         // User-specified properties
         uniform sampler2D _ShadowTex;
         float _speed;
         float _ShadowIntensity;

        // Projector-specific uniforms
        uniform float4x4 unity_Projector; // transformation matrix
        // from object space to projector space

          struct vertexInput {
            float4 vertex : POSITION;
            float3 normal : NORMAL;
         };
         struct vertexOutput {
            float4 pos : SV_POSITION;
            float4 posProj : TEXCOORD0;
               // position in projector space
         };

         vertexOutput vert(vertexInput input)
         {
            vertexOutput output;

            output.posProj = mul(unity_Projector, input.vertex);
            output.pos = UnityObjectToClipPos(input.vertex);

            return output;
         }


         float4 frag(vertexOutput input) : COLOR
         {
            if (input.posProj.w > 0.0)
            {
                fixed2 scrolledUV = input.posProj.xy / input.posProj.w;

                //Makes the texture moves
                fixed xScrollValue = frac(_speed * _Time.y);
                fixed yScrollValue = frac(_speed * _Time.y);
                scrolledUV += fixed2(xScrollValue, yScrollValue);


                float4 color =  tex2D(_ShadowTex , scrolledUV);
                color.a = 1 - color.a;
                return color/(1-_ShadowIntensity);
            }
            else
            {
               return float4(0.0, 0.0, 0.0, 0.0);
            }
         }

         ENDCG
      }
   }
   Fallback "Projector/Light"
}