function y=TrMxAlg(A,B,C,D) //Прогонка
    N = length(B);
    c(1) = C(1)/B(1);
    d(1) = D(1)/B(1);
    for i = 2:N-1
        k = B(i) - A(i)*c(i-1);
        c(i) = C(i)/k;
        d(i) = (D(i) - A(i)*d(i-1))/k;
    end
    y(N) = (D(N) - A(N)*d(N-1))/(B(N) - A(N)*c(N-1));
    for i = N-1:-1:1
        y(i) = d(i) - c(i)*y(i+1);
    end
    endfunction

    function y = u(x,t)//точное решение
    y = t*t*exp(x);
    endfunction

    function y=f(x,t)
    y= (2*t-t*t)*exp(x); //функция f в нашем решении
    endfunction

    function y=solve(Nx,Nt)
    h = (b-a)/Nx;
    tau = T/Nt;
    x = a:h:b;
    t = 0:tau:T;
    A = zeros(Nx+1,1);
    B = zeros(Nx+1,1);
    C = zeros(Nx+1,1);
    D = zeros(Nx+1,1);
    W = zeros(Nt+1,Nx+1);
    for n = 1:Nt
        for i = 2:Nx
        B(i) = -h*h-2*tau*sigma;
        A(i) = tau*sigma;
        C(i) = tau*sigma;
        D(i) = (-h*h+2*tau*(1-sigma))*W(n,i)-tau*(1-sigma)*(W(n,i+1)+W(n,i-1))-tau*h*h*f(x(i),t(n));
        end
    C(1) = 4 + B(2)/C(2);
    B(1) = -3 + A(2)/C(2);
    D(1) = 2*t(n+1)*t(n+1)*h + D(2)/C(2);
    B(Nx+1) = 3  - C(Nx)/A(Nx);
    A(Nx+1) = -4 - B(Nx)/A(Nx);
    D(Nx+1) = 2*t(n+1)*t(n+1)*h*exp(b) - D(Nx)/A(Nx);
    W(n+1,:) = TrMxAlg(A,B,C,D)';
    end
    y = W;
endfunction
//W-Приближенное рещение
//U-Точное
    a = 0;b = 2;
    T = 1;
    Nx = 200; Nt = 400;
    sigma = 0.5;
    W = solve(Nx,Nt);
    h = (b-a)/Nx;
    tau = T/Nt;
    x = a:h:b;
    t = 0:tau:T;
for i=1:Nx+1
    for n=1:Nt+1
        U(n,i) = u(x(i),t(n));
        end
end

Epsilon=max(abs( W - U )); //


Pucture1=scf(1);

xtitle ('x', 't', 'Точное решение');


plot3d1(t,x,U);

Picture2=scf(2);

xtitle ('x', 't', 'Приближенное');


plot3d1(t,x,W);

Picture3=scf(3);

xtitle ('x', 't', 'Погрешность');

plot3d1(t,x,abs(W - U));