//--------------------------------------------------------------------------
#version 3.6; // 3.7;
global_settings{ assumed_gamma 1.0 }

//--------------------------------------------------------------------------

#include "colors.inc"
#include "textures.inc"
// camera -----------------------------------------------------------

camera {
    angle 120
    location    <0.0 , 0.0 ,  2.0>
    look_at     <0.0 , 0.0 ,  0.0>
}

// sun ---------------------------------------------------------------
light_source{
    <1500,2500,-2500>
    color White
}

background {
    color <1,1,1>
}

cylinder {
    <0,-64000,0>, <0, 64000, 0>, 8000

    pigment{
        gradient <0,1,0>
        color_map {
            [0 rgb <1.00,1.00,1.00>]
            [1 rgb <0.00,0.50,1.00>]
        }
        turbulence 0.15 + (clock/100)
        scale <8000,64000,8000>
        translate <0,-32000,0>

    }
    finish {
        ambient 1.00
    }

    hollow

    rotate <0,clock*10,0>
}

#if (clock > 15)
box {
    <-2,-2,0>, <2,2,0>

    pigment {
        #if ((clock > 10) & (clock < 20))
        rgbt <0, 0, 0, 1-((clock-15)/5)>
        #else
        rgb <0, 0, 0>
        #end
    }

    finish {
        ambient 1.0
    }

    rotate <0,180,0>
    translate <0,0, 1.2>
}
#end


box {
    <-1,-1,0>, <1,1,0>

    texture {
        pigment {
            image_map {
                png "titlescreen.png"
                interpolate 4
                once
            }

            translate <-0.5,-0.5,1>
            scale < 2,  2, 1>

        }

        finish {
            ambient 1.0
        }
    }

    rotate <0,180,0>
    #if (clock < 15)
    translate <0,0, 1.3 - (pow(15-clock,3)/2)>
    #else
    translate <0,0, 1.3>
    #end
}


//--------------------------------------------- rgbf

cylinder {
    <0,-32000,0>, <0, 32000, 0>, 100
    pigment{
        rgbt <0, 0, 0, 0.75>
    }

    hollow
    interior{
        media{
            emission <1,1,1>
            scattering{
                1, <1,1,1>
            }
            density{
                spherical
                turbulence 1.5 + (clock/50)
                color_map {
                    [0 rgb <0,0,0>]
                    [1 rgb <0.125,0.125,0.125>]
                }
            }
            rotate <0, -clock * 5, 0>
            scale <200, 200, 200>
        }
    }
}