actor LGBoi : DoomPlayer
{
	Player.StartItem "QCLightningGun", 1
}



ACTOR QCWeapon : Weapon
{
	Weapon.Kickback 100 //this changes in many weapons
	Weapon.BobStyle Alpha
	Weapon.BobSpeed 2.3
	Weapon.BobRangeX 0.7
	Weapon.BobRangeY 0.5
	Inventory.PickupSound "QC/Items/WeaponPick"
	Inventory.Respawntics 175 //5sec
	+WEAPON.NOALERT
	+WEAPON.NOAUTOAIM
	+CHEATNOTWEAPON
	Tag "Lightning Gun (DM)"
}


Actor QCLightningGun : QCWeapon
{
	Height 40
	+FLOORCLIP
	+INVENTORY.IGNORESKILL
	Weapon.SelectionOrder 1300
	Weapon.KickBack 100
	Weapon.AmmoType "overheatinventory"
	Obituary "%o was electrocuted by %k."
	Inventory.PickupMessage "Picked up a Lightning Gun."
	Tag "Lightning Gun"
	Scale 0.5
	States
	{
	Spawn:
		QCG6 Z 0 Bright A_ChangeFlag("FLOATBOB", 1)
		"####" "###############" 35 Bright
		Stop
	Idle:
		QCG6 Y -1
		Wait

	//-----------------------
	// Ready Seq
	//-----------------------
	Ready:
		TNT1 A 0 A_PlaySound("QC/Weapons/LightningGun/Idle",5 , 1, 1)
		QCG6 AABB 1 A_WeaponReady
		TNT1 A 0 A_TakeInventory("overheatinventory",2)
		QCG6 CCBB 1 A_WeaponReady
		TNT1 A 0 A_TakeInventory("overheatinventory",2)
		Goto Ready+1

	//-----------------------
	// Select/Deselect Seq
	//-----------------------
	Select:
		QCG6 A 0 A_PlaySound("QC/Weapons/Switch",6,1,0,3) //Not in Weapon.UpSound because it interrupts CHAN_WEAPON sounds
		QCG6 A 0 A_StopSound(CHAN_WEAPON) // Looper
		"####" "#" 0 A_StopSound(5) //stops any other weapon looping sound
		"####" "#" 0 A_ZoomFactor(1.0)
	SelectLooper:
		QCG6 A 1 A_Raise
		TNT1 AAAA 0 A_Raise
		Loop

	Deselect:
		TNT1 A 0 A_StopSound(CHAN_WEAPON)
		TNT1 A 0 A_StopSound(5)
		TNT1 A 0 A_StopSound(6)
		TNT1 A 0 A_StopSound(7)
		"####" "#" 0 A_ZoomFactor(1.0)
	DeselectLooper:
		QCG6 A 1 A_Lower
		TNT1 AAAA 0 A_Lower
		Loop


	//-----------------------
	// Fire Seq
	//-----------------------
	Fire:
			QCG6 A 0 A_PlaySound("QC/Weapons/LightningGun/FireStartLoop", 5, 1.0, 1)
			Goto DMHold

		//*******************************
		// Deathmatch: rebalance + 3rd person beam
		DMHold:
			TNT1 A 0 A_JumpIfInventory("overheatinventory",100,"cantfire")
			QCG6 A 0 A_GiveInventory("overheatinventory",1)
			"####" A 0 A_GunFlash
			"####" A 0 A_RailAttack(0,0,0,None,"White",RGF_SILENT|RGF_FULLBRIGHT|RGF_NOPIERCING,0,"None",0,0,768,1,30,1.0,"LGworldactor",-4)
			"####" D 1 Bright A_FireBullets(0,0,1,8,"LGPuff",FBF_NORANDOM|FBF_NORANDOMPUFFZ,768)
			"####" E 1 Bright
			"####" A 0 A_ReFire("DMHold2")
			Goto FireEnd
		DMHold2:
			TNT1 A 0 A_JumpIfInventory("overheatinventory",100,"cantfire")
			QCG6 A 0 A_GiveInventory("overheatinventory",1)
			"####" A 0 A_GunFlash
			"####" A 0 A_RailAttack(0,0,0,None,"White",RGF_SILENT|RGF_FULLBRIGHT|RGF_NOPIERCING,0,"None",0,0,768,1,30,1.0,"LGworldactor",-4)
			"####" D 1 Bright A_FireBullets(0,0,1,8,"LGPuff",FBF_NORANDOM|FBF_NORANDOMPUFFZ,768)
			"####" G 1 Bright
			"####" A 0 A_ReFire("DMHold")
			Goto FireEnd


	FireEnd:
		TNT1 A 0 A_PlaySound("QC/Weapons/LightningGun/FireEnd", CHAN_WEAPON, 1.0, 0)
		Goto Ready
	Flash:
		ZZZZ C 1 A_Light2
		ZZZZ C 0 A_Light0
		Stop

	cantfire:
		TNT1 A 0 A_PlaySound("QC/Weapons/LightningGun/Idle",5 , 1, 1)
		QCG6 CCCCCCC 5 A_TakeInventory("overheatinventory",1)
		goto ready

	}
}


Actor LGPuff
{
	+CLIENTSIDEONLY +NONETID
	Radius 10
	+NOINTERACTION +NOTONAUTOMAP
	+ALWAYSPUFF
	+PUFFGETSOWNER
	+PUFFONACTORS
	-MTHRUSPECIES
	Scale 0.35
	Renderstyle Add
	Obituary "%o was electrified by %k." // variation line
	+FORCEXYBILLBOARD
	+MTHRUSPECIES
	Decal "LGDecal"
	States
	{
	Spawn:
	XDeath:
		TNT1 A 0
		TNT1 A 0 A_GiveToTarget("HitBeepLow",1)
		Goto Choose
	Crash:
		TNT1 A 0
	Choose:
		TNT1 A 2
		Stop
	}
}

Actor LGworldactor
{
	+CLIENTSIDEONLY +NONETID
	+NOINTERACTION +NOTONAUTOMAP
	+FORCEXYBILLBOARD
	RenderStyle Add
	Alpha 0.8
	Scale 0.4
	Translation "0:255=%[0,0,0]:[0.8,1.2,1.6]"
	States
	{
	Spawn:
		LGWR Z 3 Bright
		Stop
	}
}

Actor Token : Inventory { +INVENTORY.UNDROPPABLE }

Actor PlayHitBeep    : Token {}

ACTOR HitBeepLow : CustomInventory
{
	+INVENTORY.ALWAYSPICKUP
	RenderStyle None
	States
	{
	Spawn:
		MEGA A 6
		Loop
	Pickup:
		TNT1 A 0 A_JumpIfInventory("PlayHitBeep",1,"Play")
	Play:
		TNT1 A 0 A_PlaySound("QC/UI/HitBeepLow",CHAN_7|CHAN_UI,0.7,0,140)
		Stop
	}
}

actor overheatinventory : ammo
{
	inventory.maxamount 100
}

actor nothing
{
	states
	{
		spawn:
		tnt1 a 1
		death:
		tnt1 a 0
		stop
	}
}

actor nothing_stimpack : nothing replaces stimpack {}
actor nothing_healthbonus : nothing replaces healthbonus {}
actor nothing_medikit : nothing replaces medikit {}
actor nothing_soulsphere : nothing replaces soulsphere {}
actor nothing_megasphere : nothing replaces megasphere {}
actor nothing_greenarmor : nothing replaces greenarmor {}
actor nothing_bluearmor : nothing replaces bluearmor {}
actor nothing_armorbonus : nothing replaces armorbonus {}
actor nothing_cell : nothing replaces cell {}
actor nothing_clip : nothing replaces clip {}
actor nothing_cellpack : nothing replaces cellpack {}
actor nothing_clipbox : nothing replaces clipbox {}
actor nothing_shell : nothing replaces shell {}
actor nothing_shellbox : nothing replaces shellbox {}
actor nothing_rocketammo : nothing replaces rocketammo {}
actor nothing_rocketbox : nothing replaces rocketbox {}
actor nothing_chainsaw : nothing replaces chainsaw {}
actor nothing_shotgun : nothing replaces shotgun {}
actor nothing_supershotgun : nothing replaces supershotgun {}
actor nothing_chaingun : nothing replaces chaingun {}
actor nothing_rocketlauncher : nothing replaces rocketlauncher {}
actor nothing_plasmarifle : nothing replaces plasmarifle {}
actor nothing_bfg9000 : nothing replaces bfg9000 {}
actor nothing_pistol : nothing replaces pistol {}