PKGBUILD for lighttable-git

# Maintainer: Tony Sokhon <tonyskn@gmail.com>
# Contributor: Ebubekir KARUL <ebubekirkarul@yandex.com>
# Contributor: Gaurish Sharma <contact@gaurishsharma.com>
# Contributor: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
# Contributor: Katrina L. Halliwell <rambaldi.kat.47@gmail.com>
# Contributor: Alexey Stukalov <astukalov@gmail.com>

pkgname=lighttable-git
_pkgname=LightTable
pkgver=0.7.2.r161.g8b9b4c9
pkgrel=1
pkgdesc="New interactive IDE that lets you modify running programs and embed anything from websites to games."
url="http://www.lighttable.com/"
license=('GPLv3')
conflicts=('lighttable')
depends=(nss libx11 libxrandr libpng gconf)
makedepends=(npm leiningen git)
options=(!strip)
arch=('i686' 'x86_64')

source=(git://github.com/LightTable/LightTable
    lighttable.desktop
    lighttable.png)
md5sums=('SKIP'
     '04a62702b59810a36bca7623bf9e932c'
     'f8c055be2f047ff4aaffdd028f62f027')

pkgver() {
  cd "$_pkgname"
  git describe --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd LightTable
  bash ./script/build.sh
}

package() {
  _destdir="$pkgdir/opt/LightTable"

  install -dm755 $_destdir
  mv LightTable/builds/lighttable-*-linux/* $_destdir

  mkdir -p "${pkgdir}"/usr/share/{applications,pixmaps}
  install -m644 "${startdir}"/lighttable.desktop "${pkgdir}/usr/share/applications/"
  install -m644 "${startdir}"/lighttable.png "${pkgdir}"/usr/share/pixmaps/lighttable.png

  mkdir -p "${pkgdir}"/usr/bin
  ln -s /opt/LightTable/light "$pkgdir/usr/bin/lighttable"
}