Reaper

# Contributor: Alessio 'alexwizard' Sergi <sergi.alessio {at} gmail.com>

pkgname=gnome-do-bzr
_realname=gnome-do
pkgver=1325
pkgrel=1
pkgdesc="A launcher application for GNOME"
arch=('i686' 'x86_64')
url="https://launchpad.net/do"
license=('GPL3')
depends=('gnome-desktop-sharp' 'gnome-keyring-sharp' 'gtk2' 'mono-addins' \
         'hicolor-icon-theme' 'ndesk-dbus-glib' 'notify-sharp-svn' 'xdg-utils')
makedepends=('bzr' 'intltool')
provides=(${_realname})
conflicts=(${_realname})
options=('!libtool' '!emptydirs')
install=${pkgname}.install
source=(https://bugs.launchpad.net/do/+bug/634550/+attachment/1563347/+files/cs0200.patch
https://bugs.launchpad.net/do/+bug/647495/+attachment/1727779/+files/compiler_fix.patch)
md5sums=(91b4dff5fb7afed4d5c61da9de62daef 263257b1d9e96dfc3858e62bbbda4302)

_bzrtrunk=lp:do
_bzrmod=trunk

build() {
  export MONO_SHARED_DIR=${srcdir}/.wabi
  mkdir -p ${MONO_SHARED_DIR}

  cd ${srcdir}

  msg "Connecting to the server...."

  if [ ! -d ./${_bzrmod} ]; then
    bzr co ${_bzrtrunk} ${_bzrmod} -r ${pkgver}
  else
    bzr up ${_bzrmod}
  fi

  msg "BZR checkout done or server timeout"
  msg "Starting make..."

  [ -d ./${_bzrmod}-build ] && rm -rf ./${_bzrmod}-build
  cp -r ./${_bzrmod} ./${_bzrmod}-build
  cd ./${_bzrmod}-build
  patch -p0 < ${srcdir}/cs0200.patch || return 1
  patch -p0 < ${srcdir}/compiler_fix.patch || return 1
  ./autogen.sh && ./configure --prefix=/usr --sysconfdir=/etc --disable-schemas-install || return 1
  make || return 1
}

package() {
  cd ${srcdir}/${_bzrmod}-build

  make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR=${pkgdir} install || return 1

  mkdir -p ${pkgdir}/usr/share/gconf/schemas
  gconf-merge-schema ${pkgdir}/usr/share/gconf/schemas/${_realname}.schemas ${pkgdir}/etc/gconf/schemas/*.schemas || return 1
  rm -f ${pkgdir}/etc/gconf/schemas/*.schemas

  rm -rf ${pkgdir}/usr/lib/gnome-do/*.mdb
#  rm -rf ${srcdir}/${_bzrmod}-build
}

# vim:set ts=2 sw=2 et: