entregador_de_item

//===== Cronus Script =========================================
//= Entregador de Item
//===== Por: ==================================================
//= Zawe
//===== Versão Atual: =========================================
//= 0.3
//===== Descrição: ==========================================
//= Entregador de Item que entrega para offline. Com
//= modificação para Alterar e Deletar Envios não Completados.
//===== Comentários Adicionais: ===============================
//= 0.1 Criação do Script [Zawe]
//= 0.2 Melhorando no envio Online [Zawe]
//= 0.3 Correção de erros [Zawe]
//===== Observações: ==========================================
//= O Entregador aguenta somente 40 entregas salvas.
//= Não esqueca de alterar as configurações no final do script.
//=============================================================
sec_in02.gat,133,141,2  script  Entregador de Itens 92,{

function    Manager {
    if(attachrid(getarg(0))) {
        mes "Olá, "+strcharinfo(0)+".";
        mes "Você possui "+getarg(2)+" "+getitemname(getarg(1))+" esperando para ser resgatado.";
        mes "Você gostária de resgata-los nesse exato momento?";
        mes " ";
        mes "Obs: Tenha cuidado na hora de pegar itens não transferiveis. Tenha certeza de estar com o personagem certo.";
        getitem getarg(1),getarg(2);
        end;
    }
    if(getarraysize($itemsmanage) > 125) {
        mes "Espaço insuficiente. Por favor delete algum envio ou espere um envio ser completado.";
        end;
    }
    for(set .@i,0; .@i < 3; set .@i,.@i + 1) {
        setarray $itemsmanage[getarraysize($itemsmanage)],getarg(.@i);
    }
}

function    InputEntreg {
    mes "Digite o ID do Item.";
    while(.@itemid < 512) {
        input .@itemid;
        if(.@itemid < 512) {
            mes "ID de Item inválido.";
            mes "Por favor redigite o ID.";
            next;
        }
    }
    mes "Agora digite a Quantidade de Item a ser dado.";
    while(.@itemquant > .item_quant || .@itemquant == 0) {
        input .@itemquant;
        if(.@itemquant > .item_quant || .@itemquant == 0) {
            mes "Numero inválido. Digite um numero entre(1 ~ "+.item_quant+").";
            mes "Por favor redigite a Quant.";
            next;
        }
    }
    Manager(getarg(0),.@itemid,.@itemquant);
}

if(getgmlevel() < .gm_lvl) end;
mes "O que você deseja fazer?";
switch(select("~ Adicionar Envio:~ Alterar Envio:~ Deletar Envio:~ Sair")) {
next;

case 1:
    if(.sql) {
        mes "De que maneira você deseja enviar?";
        set .@menu,select("~ Accound ID:~ Personagem:~ Login:~ Sair");
        if(.@menu == 4) end;
        while(.@temp2 < 2000000){
            input .@temp$;
            if(.@temp$ == "0") end;
            if(.@menu == 1) {
                set .@temp2,.@temp$;
            } else if(.@menu == 2) {
                query_sql "SELECT `account_id` FROM `char` WHERE `name` = '"+.@temp$+"'",.@temp2;
            } else {
                query_sql "SELECT `account_id` FROM `login` WHERE `userid` = '"+.@temp$+"'",.@temp2;
            }
        }
        InputEntreg(.@temp2);
    } else {
        mes "Por favor digite o Account ID da Conta.";
        input .@temp;
        InputEntreg(.@temp);
    }
    end;

case 2:
    mes "Escolha um dos Envios que você deseja alterar.";
    mes " ";
    mes "Account ID | Item | Quantidade";
    for(set .@i,0; .@i < getarraysize($itemsmanage); set .@i,.@i + 3) {
        set .@temp$,"~ "+$itemsmanage[.@i]+" | "+getitemname($itemsmanage[.@i+1])+" | "+$itemsmanage[.@i+2]+"";
        set .@menu$,.@menu$ + .@temp$ + ":";
    }
    set .@menu$,.@menu$ + "~ Sair" + ":";
    set .@menu,select(.@menu$);
    if(.@menu == (.@i/3)+1) end;
    mes "Account ID: "+$itemsmanage[(.@menu-1)*3]+"";
    mes "Item ID: "+$itemsmanage[((.@menu-1)*3)+1]+"";
    mes "Item Name: "+getitemname($itemsmanage[((.@menu-1)*3)+1])+"";
    mes "Quantidade: "+$itemsmanage[((.@menu-1)*3)+2]+"";
    set .@menu2,select("~ Alterar Item:~ Alterar Quantidade:~ Sair");
    if(.@menu2 == 3) end;
    if(.@menu2 == 1) {
        input .@newid;
        setarray $itemsmanage[((.@menu-1)*3)+1],.@newid;
    } else {
        input .@newquant;
        setarray $itemsmanage[((.@menu-1)*3)+2],.@newquant;
    }
    mes "Alteração completada.";
    end;

case 3:
    mes "Escolha um dos Envios que você deseja deletar.";
    mes " ";
    mes "Account ID | Item | Quantidade";
    for(set .@i,0; .@i < getarraysize($itemsmanage); set .@i,.@i + 3) {
        set .@temp$,"~ "+$itemsmanage[.@i]+" | "+getitemname($itemsmanage[.@i+1])+" | "+$itemsmanage[.@i+2]+"";
        set .@menu$,.@menu$ + .@temp$ + ":";
    }
    set .@menu$,.@menu$ + "~ Sair" + ":";
    set .@menu,select(.@menu$);
    if(.@menu == (.@i/3)+1) end;
    mes "Tem certeza que deseja deletar esse Envio?";
    if(select("Sim:Não") == 2) end;
    deletearray $itemsmanage[((.@menu-1)*3)],3;
    mes "Envio deletado com sucesso.";
    end;

}

OnPCLoginEvent:
    for(set .@i,0; .@i < getarraysize($itemsmanage); set .@i,.@i + 3) {
        if(getcharid(3) == $itemsmanage[.@i]) {
            mes "Olá, "+strcharinfo(0)+".";
            mes "Você possui "+$itemsmanage[.@i+2]+" "+getitemname($itemsmanage[.@i+1])+" esperando para ser resgatado.";
            mes "Você gostária de resgata-los nesse exato momento?";
            mes " ";
            mes "Obs: Tenha cuidado na hora de pegar itens não transferiveis. Tenha certeza de estar com o personagem certo.";
            if(select("Sim:Não") == 2) end;
            getitem $itemsmanage[.@i+1],$itemsmanage[.@i+2];
            deletearray $itemsmanage[.@i],3;
            next;
        }
    }
    end;

OnInit:
    set .gm_lvl,90;         // Level minimo do GM para utilizar o Npc
    set .sql,1;             // Servidor usa SQL? 0 = Não | 1 = Sim
    set .item_quant,999;        // Quantidade maxima de item para enviar
    end;

}