#!/bin/sed -rnf
# usage: ./config_defaults.sed config_defaults.pl > config_defaults.py
s/\(('[^']*')\)/[\1]/g;
s/\teval "use constant ([A-Z_]+) ?=> ?('.*'|[0-9\*]+|\[.*\])" unless.*$/\1 = \2/g;
s/^1;$//;
s/^BEGIN \{$//;
s/^\}$//;
s/^use strict;$//;
s/^\tuse constant S_.*$//g;
s/^\tdie S_.*$//g;
1h;1!H;
${
    g;
    s/\n\n+/\n/g;
    s/$/\
# add default values to config.py\
import util as _util\
_util.module_default('config', locals())/;
    p;
}
#!/bin/sed -rnf
# usage: ./config.sed config.pl > config.py

s/use constant ([A-Z_]+) ?=> ?(['"].*['"]|[0-9\*]+);(\s*#?.*)$/\1 = \2\3/g;
s/^1;$//;
s/^#? ?(use|no) encoding.*$//;
s/^##use constant CONVERT_COMMAND.*$//;
s/^# ffffffff.*$//;
1h;1!H;
$ {
    g;
    s#SQL_DBI_SOURCE = 'DBI:([^:]+):database=([^:]+);host=([^']+)'.*\nSQL_USERNAME = '([^']+)'.*\nSQL_PASSWORD = '([^']+)'[^\n]*\n#SQL_ENGINE = '\1://\4:\5@\3/\2'\n#;
    s/\n\n+/\n/g;
    p
}
#!/bin/sed -rf
# usage: ./strings.sed strings_en.pl > strings.py

s/use constant S_([A-Z0-9_]+) ?=> ?(['"].*['"]|[0-9\*]+);(\s*#?.*)$/\1 = \2\3/;
s/use constant S_([A-Z0-9_]+) ?=> ?\(?(['"].*['"])\);(\s*#?.*)$/\1 = [\2]\3/;
s/use constant S_([A-Z0-9_]+) ?=> ?(['"].*['"])\. *$/\1 = \2 + \\/;
s/^\s+(['"].*['"])\.\s*$/    \1 + \\/;
s/^\s+(['"].*['"]);(\s*#?.*)$/    \1\2/;
s/use constant S_([A-Z0-9_]+) ?=> ?\[\s*$/\1 = [/;
/^\s*\{/ s/=>/\: /g;
s/^\];\s*$/]/;
s/^1;$//;