@echo off

set username=self_slaughter
set password=***Censored***
set memory=8192
set java=C:\Program Files\Java\jre7\bin

setlocal enabledelayedexpansion
title self_slaughter rocks your jocks :P

:detection

cd /d %~dp0
set /a count=0

FOR /D %%g IN (*) DO (
    set /a count+=1
    set var!count!=%%g
)

set /a linecount=(%count% + 8)
mode con: cols=52 lines=%linecount%

:menu

cls
echo.
echo     ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
echo     º   Automagic Minecraft version selector   º
echo     ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍͼ
echo.

for /l %%a in (1,1,%count%) do (
    echo              %%a - !var%%a!
)

echo.
set /p choice=Enter a number between 1-%count% and press enter:

:errordetect

echo %choice%|findstr /r /c:"^[0-9][0-9]*$" >nul
if errorlevel 1 goto :menu
if %choice% geq 1 if %choice% leq %count% goto :minecraft
goto :menu

:minecraft

set appdata=%~dp0\!var%choice%!
start "" "%java%\javaw.exe" -Xincgc -Xmx%memory%M -cp minecraft.jar net.minecraft.LauncherFrame %username% %password%