//
// We'll use face #1 (south facing) for our picture.  That will mean changes in Y for swapping.
// 0.001 seems to be plenty to keep faces from glitching.
//
float   gfTimerLength       = 15.0;
integer giPreviousChoice    = -1;
integer giShowingPrim       = 1;        // This is either 1 or 2, for the two prims.  1 is root.
//

Initialize()
{
    giShowingPrim = 1;
    // Make sure the child is behind and the same size.
    vector vRootSize = llList2Vector(llGetLinkPrimitiveParams(1, [PRIM_SIZE]), 0);
    llSetLinkPrimitiveParamsFast(2, [PRIM_POS_LOCAL, <0, 0.001, 0>, PRIM_SIZE, vRootSize]);
    llSetTimerEvent(gfTimerLength);         // Can't hurt.
    //
    // All sides except 1 to transparent.
    llSetLinkTexture(1, TEXTURE_TRANSPARENT, 0); llSetLinkTexture(1, TEXTURE_TRANSPARENT, 2); llSetLinkTexture(1, TEXTURE_TRANSPARENT, 3); llSetLinkTexture(1, TEXTURE_TRANSPARENT, 4); llSetLinkTexture(1, TEXTURE_TRANSPARENT, 5);
    llSetLinkTexture(2, TEXTURE_TRANSPARENT, 0); llSetLinkTexture(2, TEXTURE_TRANSPARENT, 2); llSetLinkTexture(2, TEXTURE_TRANSPARENT, 3); llSetLinkTexture(2, TEXTURE_TRANSPARENT, 4); llSetLinkTexture(2, TEXTURE_TRANSPARENT, 5);
    //
    // Set side 1 color to white.
    llSetLinkColor(1, <1,1,1>, 1);
    llSetLinkColor(2, <1,1,1>, 1);
}


string GetRandomTexture()
{
    integer iCount;
    integer iChoice;
    //
    iCount = llGetInventoryNumber(INVENTORY_TEXTURE);
    if (iCount == 0) return "";
    if (iCount == 1) return llGetInventoryName(INVENTORY_TEXTURE, 0);
    // We've got more than one, so make sure we don't return the same one twice.
    do iChoice = llFloor(llFrand(iCount));
    while (iChoice == giPreviousChoice);
    giPreviousChoice = iChoice;
    return llGetInventoryName(INVENTORY_TEXTURE, iChoice);
}

FadePictures(integer iLinkHide, integer iLinkShow)
{
    float fAlphaHide = llList2Float(llGetLinkPrimitiveParams(iLinkHide, [PRIM_COLOR, 1]), 1);
    float fAlphaShow = llList2Float(llGetLinkPrimitiveParams(iLinkShow, [PRIM_COLOR, 1]), 1);
    do
    {
        fAlphaHide -= 0.05;
        if (fAlphaHide < 0.0) fAlphaHide = 0.0;
        llSetLinkAlpha(iLinkHide, fAlphaHide, 1);
        //
        fAlphaShow += 0.05;
        if (fAlphaShow > 1.0) fAlphaShow = 1.0;
        llSetLinkAlpha(iLinkShow, fAlphaShow, 1);
        //
        llSleep(0.02);
    }
    while (fAlphaHide != 0.0 || fAlphaShow != 1.0);
}

ShowPicture(string sPicture)
{
    if (sPicture == "") return;
    //
    if (giShowingPrim == 1)
    {
        giShowingPrim = 2;
        llSetLinkAlpha(2, 0, 1);            // Link, Alpha, Face.  So it doesn't show when the front one goes transparent.
        FadePictures(1, 2);
        llSetLinkPrimitiveParamsFast(2, [PRIM_POS_LOCAL, <0, -0.001, 0>]);  // Show prim 2 (moves prim 2 in front).
        llSetLinkTexture(1, sPicture, 1);
        llSetLinkAlpha(1, 1, 1);            // Link, Alpha, Face.  Make opaque to make sure it loads.
    }
    else
    {
        giShowingPrim = 1;
        llSetLinkAlpha(1, 0, 1);            // Link, Alpha, Face.  So it doesn't show when the front one goes transparent.
        FadePictures(2, 1);
        llSetLinkPrimitiveParamsFast(2, [PRIM_POS_LOCAL, <0, 0.001, 0>]);   // Show prim 1 (moves prim 2 behind).
        llSetLinkTexture(2, sPicture, 1);
        llSetLinkAlpha(2, 1, 1);            // Link, Alpha, Face.  Make opaque to make sure it loads.
    }
}

default
{
    on_rez(integer iStartParam)
    {
        Initialize();
    }
    state_entry()
    {
        Initialize();
    }
    changed(integer iChangeBitFlags)
    {
        if (iChangeBitFlags & CHANGED_INVENTORY)
        {
            llSetTimerEvent(0);
            ShowPicture(GetRandomTexture());
            ShowPicture(GetRandomTexture());        // We do it twice because the first one is just loading into the background.
            llSetTimerEvent(gfTimerLength);
        }
    }
    touch_start(integer iNumDetected)
    {
        llSetTimerEvent(0);
        ShowPicture(GetRandomTexture());
        llSetTimerEvent(gfTimerLength);
    }
    timer()
    {
        ShowPicture(GetRandomTexture());
    }
}