gigger.pov

// Persistence of Vision Ray Tracer Scene Description File
// File: gigger.pov
// Vers: 3.7
// Desc: Good Idea Gaming Nationalistic Flag
// Date: 10/01/2014
// Auth: PovRayMan

#include "colors.inc"


// final camera angle setup for 16:9 rendering.

camera {
        location <0,10,-7>
        look_at <0,-1.25,0>
        right 16/9*x
        }


// boring light source
//light_source { <-50,50,-50> color White }

// fancy light source giving soft shadows
light_source {
  <0,0,0>
  color rgb 2.0
  area_light
  <45, 0, 0> <0, 0, 45>
  30, 30
  adaptive 1
  jitter
  circular
  orient
  //translate <-40,40,20>
  translate <0,40,20>
}

// radiosity because reasons
global_settings {

      radiosity {
                pretrace_start 0.08
                pretrace_end   0.04
                count 1600
                nearest_count 9
                error_bound 4.8
                recursion_limit 20
                low_error_factor .6
                gray_threshold 0
                minimum_reuse 0.015
                brightness 1
                adc_bailout 0.01/2
                always_sample on
                }
}


// Flat red ground
plane{y,0 pigment {Red}}


/*

The "G" Logo

I used a pixel art program
to dictate how I should draw
each block as a 1x1x1 pixel
in a 3d space.  This allowed
me to setup the logo to unit
dimensions.


Each numbered line represents
the appropriate "box" line
object to reference in code.

     5
 ||=====
 ||
4||   3
 ||  ==||
 ||    ||2
 ||    ||
 ||=====
   1

*/

// Toto
#declare G_Logo_Color = Black;

// GiG Nation
#declare Gigger =
union{
// 1
box { <0,0,0> <5,1,1> }
// 2
box { <4,0,0> <5,1,3> }
// 3
box { <2,0,2> <5,1,3> }
// 4
box { <0,0,0> <1,1,5> }
// 5
box { <0,0,4> <5,1,5> }
// Toto
pigment {G_Logo_Color }
}

// The Pure White platform.
cylinder { <0,0,0> <0,1,0>, 5 pigment { White }}

// Declaring the object and translating
// off center to make it look closer in
// the low camera angle.  I probably
// could have designed the camera angle
// more correctly to not need to fake it
// this way but again... reasons.
object { Gigger translate <-2.75,1,-3> rotate -45*y}