; ===========================================================================
; Colour test screen
; ===========================================================================

Load_Colour_Test:
; fade out
		bsr.w	Pal_FadeFrom

		bsr.w	ClearPlane

; clear sprite list
		lea	($FFFFF800).w,a1
		moveq	#0,d0
		move.w	#$7F,d1
	@clearobjects:
		move.l	d0,(a1)+
		dbf	d1,@clearobjects 	; clear sprite RAM

; load palette
		lea	Pal_ColourTest,a1
		lea	($FFFFFB80).w,a2	; palette transition ram location
		moveq	#63,d0
	@copypal:	
		move.w	(a1)+,(a2)+
		dbf	d0,@copypal

		move.w	#$8700,($C00004).l	; set background colour (line 0, palette entry 0)

; load graphics
		locVRAM	$0000
		lea	(Nem_ColourTest).l,a0 
		bsr.w	NemDec

;load mappings
		lea	($FF0000).l,a1
		lea	(Eni_ColourTest).l,a0	
		move.w	#$0000,d0
		bsr.w	EniDec
		lea	($FF0000).l,a1
                move.l  #$40000003,d0
		moveq	#40-1,d1
		moveq	#28-1,d2
		bsr.w	ShowVDPGraphics


; fade in
		bsr.w	Pal_FadeTo

; --------------------------------------------------------------------------

Colour_Test_Loop:
		move.b	#$16,($FFFFF62A).w
		bsr.w	DelayProgram       	; wait for vblank

; check for start		
		andi.b	#$80,($FFFFF605).w 	; check if Start is pressed
		beq.w	Colour_Test_Loop	; if not, branch

; fade out
		bsr.w	Pal_FadeFrom

; clear colour test mappings
		locVRAM	$C000                 
                moveq   #0,d0
		move.w	#$1EF,d1
        @cleartext:
		move.w	d0,(a6)
		dbf	d1,@cleartext

; reload title logo mappings
		lea	($FF0000).l,a1
		lea	(Eni_Title).l,a0 ; load	title screen mappings
		move.w	#0,d0
		bsr.w	EniDec
		lea	($FF0000).l,a1
		move.l	#$42060003,d0
		moveq	#$21,d1
		moveq	#$15,d2
		bsr.w	ShowVDPGraphics
		jsr	(ObjectsLoad).l
		jsr	(BuildSprites).l
		bra.w	LoadOptionMenuFromColourTest
; ===========================================================================