#include <WiFi.h> //Wifi library
#include "esp_wpa2.h" 
const char* ssid = "INTRAK"; //  SSID
const char* host = "intrak.sk"; //externy server pre HTTP spojenie po autentizacii a autorizacii
int counter = 0; //pocitadlo restartu
#define EAP_IDENTITY "meno.priezvisko" //meno.priezvisko je identita a aj meno do siete INTRAK
#define EAP_PASSWORD "heslo" //heslo
void setup() {
  Serial.begin(115200);
  delay(10);
  Serial.println();
  Serial.print("Pripojenie na siet: ");
  Serial.println(ssid);
  WiFi.disconnect(true);  //odpoj wifi pred novym nastavenim wifi
  WiFi.mode(WIFI_STA); //init wifi modu - vyzadovane od Juna 2018 v Arduino core
  esp_wifi_sta_wpa2_ent_set_identity((uint8_t *)EAP_IDENTITY, strlen(EAP_IDENTITY)); //preukazanie identity
  esp_wifi_sta_wpa2_ent_set_username((uint8_t *)EAP_IDENTITY, strlen(EAP_IDENTITY)); //preukazanie mena
  esp_wifi_sta_wpa2_ent_set_password((uint8_t *)EAP_PASSWORD, strlen(EAP_PASSWORD)); //preukazanie hesla
  esp_wpa2_config_t config = WPA2_CONFIG_INIT_DEFAULT(); //nastav pociatocne parametre
  esp_wifi_sta_wpa2_ent_enable(&config);
  WiFi.begin(ssid); //pripoj sa na wifi siet
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
    counter++;
    if(counter>=60){ //po 30 sekundach restartuj dosku
      ESP.restart();
    }
  }
  Serial.println("");
  Serial.println("WiFi pripojene");
  Serial.println("IP addresa nastavena: "); 
  Serial.println(WiFi.localIP()); //vypis LAN IP
}
void loop() {
  if (WiFi.status() == WL_CONNECTED) { //ak je doska pripojena
    counter = 0; //vynuluj pocitadlo
    Serial.println("Wifi je stale pripojene s IP: "); 
    Serial.println(WiFi.localIP());
  }else if (WiFi.status() != WL_CONNECTED) { //if we lost connection, retry
    WiFi.begin(ssid);      
  }
  while (WiFi.status() != WL_CONNECTED) { //during lost connection, print dots
    delay(500);
    Serial.print(".");
    counter++;
    if(counter>=60){ //30 seconds timeout - reset board
    ESP.restart();
    }
  }
  Serial.print("Pripajanie na web: ");
  Serial.println(host);
  WiFiClient client;
  if (client.connect(host, 80)) {
    String url = "/";
    client.print(String("GET ") + url + " HTTP/1.1\r\n" + "Host: " + host + "\r\n" + "User-Agent: NodeMCU\r\n" + "Connection: close\r\n\r\n");

    while (client.connected()) {
      String line = client.readStringUntil('\n');
      if (line == "\r") {
        break;
      }
    }
    while (client.available()) {
      char c = client.read();
      Serial.write(c);
    }
  }else{
      Serial.println("Pripojenie neuspesne");
    }  
    delay(30000); //pockaj 30 sekund pred novym pripojenim
}