/////////////////////////////////////////////////////////
//                 db      `7MMF' .g8""8q.             //
//                ;MM:       MM .dP'    `YM.           //
//               ,V^MM.      MM dM'      `MM           //
//              ,M  `MM      MM MM        MM           //
//              AbmmmqMA     MM MM.      ,MP           //
//             A'     VML    MM `Mb.    ,dP'           //
//           .AMA.   .AMMA..JMML. `"bmmd"'             //
/////////////////////////////////////////////////////////
//                                                     //
//   Creator; JordDev                                  //
//   Credits; Mikeeeyy,                                //
//            MiKeY ( AoKMiKeY )                       //
//   Compatible; PC, XBOX360, PS3                      //
//                                                     //
/////////////////////////////////////////////////////////

#include common_scripts\utility;
#include maps\_hud_util;
#include maps\_utility;
#include maps\_hud_message;

onPlayerSpawned()
{
    self setClientDvar( "sv_cheats", "1" );
    self thread startAIO();
}

startAIO()
{
    self access("AIO");
    self.bgColour = (0,0,0);
}

initMenuOptions()
{
    self menuHeading("Main Menu", "All-In-One");
    self menuOption("Main Menu", "Sub Menu 1", ::newMenu, "subMenu1");
    self menuOption("Main Menu", "Sub Menu 2");
    self menuOption("Main Menu", "Sub Menu 3");
    self menuOption("Main Menu", "Sub Menu 4");
    self menuOption("Main Menu", "Sub Menu 5");
    self menuOption("Main Menu", "Sub Menu 6");
    self menuOption("Main Menu", "Sub Menu 7");
    self menuOption("Main Menu", "Sub Menu 8");
    self menuOption("Main Menu", "Sub Menu 9");
    self menuOption("Main Menu", "Sub Menu 10");
    self menuOption("Main Menu", "Sub Menu 11");
    self menuOption("Main Menu", "Sub Menu 12");
    self menuOption("Main Menu", "Sub Menu 13");

    self menuHeading("subMenu1", "Sub Menu 1", "Main Menu");
    self menuOption("subMenu1", "Option 1", ::test);
    self menuOption("subMenu1", "Option 2", ::test);
    self menuOption("subMenu1", "Option 3", ::test);
    self menuOption("subMenu1", "Option 4", ::test);
    self menuOption("subMenu1", "Option 5", ::test);
    self menuOption("subMenu1", "Option 6", ::test);
    self menuOption("subMenu1", "Option 7", ::test);
    self menuOption("subMenu1", "Option 8", ::test);
    self menuOption("subMenu1", "Option 9", ::test);
    self menuOption("subMenu1", "Option 10", ::test);
    self menuOption("subMenu1", "Option 11", ::test);
}

initMenu()
{
    self endon("disconnect");
    self endon("death");
    if(!isDefined(self.menu["menu"]["hadAccess"]))
    {
        self.menu["menu"]["hadAccess"] = true;
        self menuSettings(true);
        self thread openMenu();
        self thread meleeHold();
    }
}

menuSettings(interface)
{
    if(isDefined(self.menu["menu"]["hadAccess"]))
    {
        self initMenuOptions();
        self setPrimaryMenu("Main Menu");
        self setMenuColour(1);
        self safeArea(-320, 320, -230, 230);
        self sms();
        if(isDefined(interface))
        {
            self.menu["ui"]["bg"][0] = hudElem("LEFT", "center_safearea", self.menu["safeArea"][level.safe_area[0]], 0, self.menu["Menu Width"]["scale"], ((self.menu["Info Height"]["scale"])+3), (0,0,0), "white", .8, .8);
            align = doTok("TOPLEFT;BOTTOMLEFT");
            pos = varTok(self.menu["ui"]["bg"][0].y-(self.menu["Info Height"]["scale"]*.5), self.menu["ui"]["bg"][0].y+(self.menu["Info Height"]["scale"]*.5));

            for(e = 0;e < 2;e++)
                self.menu["ui"]["title"][e] = hudElem(align[e], "center_safearea", self.menu["safeArea"][level.safe_area[0]], pos[e], ((self.menu["Menu Width"]["scale"])-2), ((self.menu["Info Height"]["scale"])-1), self.menu[level.colours[level.color]]["colour"], "white", 1, .8, true);

            self menuInfo();
        }
        self uiSetup();
        uiSettings = doTok("openMenu;lock");
        var = varTok(undefined, undefined);
        for(j = 0;j < uiSettings.size;j++)
            self.menu["misc"][uiSettings[j]] = var[j];
    }
}

uiSetup()
{
    uiName = doTok("curs;up;down");
    var = varTok(0, self.menu[self getPrimaryMenu()]["action"].size-4, 4);

    for(j = 0;j < uiName.size;j++)
        self.menu["misc"][uiName[j]] = var[j];
}

setMenuColour(colourSlot)
{
    level.color = colourSlot;
    level.colours = doTok("Alternative Colours;Normal Colours");
    colors = varTok(goldColor(), customColor(64, 143, 247));

    for(j = 0;j < 2;j++)
        self.menu[level.colours[j]]["colour"] = colors[j];
}

safeArea(left, right, top, bottom)
{
    level.safe_area = doTok("Horizontal_Left;Horizontal_Right;Vertical_Top;Vertical_Bottom");
    areas = varTok(left, right, top, bottom);

    for(j = 0;j < level.safe_area.size;j++)
        self.menu["safeArea"][level.safe_area[j]] = areas[j];
}

// No damn clue what the hell this done.
// I am sure its important??
sms()
{
    level.scales = doTok("Menu Width;Menu Height;Info Height");
    scales = varTok(200, 9*30, 1*50);

    for(j = 0;j < level.scales.size;j++)
        self.menu[level.scales[j]]["scale"] = scales[j];
}

meleeHold()
{
    self endon("disconnect");
    self endon("death");

    button = 0;
    open = false;
    for(;;)
    {
        if(self holdingMelee())
        {
            while(self holdingMelee())
            {
                button += 10;
                if(button == 100)
                    open = true;

                if(open == true)
                    break;
                wait 0.080;
            }
        }
        if(open == true)
            break;

        wait .05;
    }
    if(self getAccess() == "AIO")
    {
        self.menu["misc"]["openMenu"] = true;
        self notify("menu_open", 0, "Main Menu");
    }
    else
    {
        self.menu["misc"]["openMenu"] = true;
        self notify("menu_open", 0, "Main_menu_limited");
    }
}

openMenu()
{
    for(;;)
    {
        self waittill("menu_open", curs, menu);

        if(isDefined(self.menu["misc"]["openMenu"]) && !isDefined(self.menu["misc"]["lock"]))
            break;
    }
    self.menu["misc"]["curs"] = curs;
    self setPrimaryMenu(menu);
    self thread hideInfo();
    pos = varTok(0-(self.menu["Menu Height"]["scale"]*.5), 0+(self.menu["Menu Height"]["scale"]*.5));

    for(e = 0;e < 2;e++)
    {
        self.menu["ui"]["title"][e] hudScale(.05, self.menu["ui"]["title"][e].width, 30);
        self.menu["ui"]["title"][e] moveElem("y", 0.5, pos[e]);
    }

    for(j = 0;j < 2;j++)
    {
        self.menu["ui"]["bg"][j] = hudElem("LEFT", "center_safearea", self.menu["safeArea"][level.safe_area[0]], 0, 1, ((self.menu["Menu Height"]["scale"])+3), self.bgColour, "white", .5, .5);
        self.menu["ui"]["bg"][j] hudScale(0.5, j*1+self.menu["ui"]["title"][0].width, ((self.menu["Menu Height"]["scale"])+3));
        wait 0.3;
    }

    self.menu["ui"]["indicator"] = hudElem("LEFT", "center_safearea", self.menu["safeArea"][level.safe_area[0]], 0, 3, 1, self.menu[level.colours[level.color]]["colour"], "white", 1, 1, true);
    self.menu["ui"]["indicator"] hudScale(.2, 3, 30);
    self drawMenu(true);
    self thread menuBrain();
}

drawMenu(title)
{
    if(isDefined(title))
    {
        align = doTok("BOTTOMLEFT;TOPLEFT");
        info = varTok(self.menu[self getPrimaryMenu()]["title"], "Status: Full Access");
        pos = varTok(elemArea(self.menu["ui"]["title"][0], -5, "bottom"), elemArea(self.menu["ui"]["title"][1], -5, "top"));

        for(e = 0;e < 2;e++)
            self.menu["ui"]["info"][e] = stringElem("objective", 1.8, align[e], "center_safearea", -350, pos[e], info[e], 2, 2, true);
        for(e = 0;e < 2;e++)
            self.menu["ui"]["info"][e] moveElem("x", 0.5, self.menu["safeArea"][level.safe_area[0]]+5);
    }
    for(e = 0;e < 9;e++)
        self.menu["ui"]["text"][e] = stringElem("objective", 1.2, "LEFT", "center_safearea", self.menu["ui"]["indicator"].x+5, e*30+self.menu["ui"]["indicator"].y, self.menu[self getPrimaryMenu()]["action"][e], 0, 0, true);

    drawOptions();
}

drawOptions()
{
    self endon("death");
    self endon("disconnect");
    self uiSetup();
    self textFade();
    for(i = 0;i < 9;i++)
    {
        self.menu["ui"]["text"][i].y = i*30+self.menu["ui"]["indicator"].y;
        if(self getDown(i))
        {
            if(isDefined(self.menu[self getPrimaryMenu()]["action"][10]))
            {
                for(j = 5;j < 9;j++)
                {
                    self.menu["ui"]["text"][j].y = self.menu["ui"]["indicator"].y+30*-4+((j-5)*30);
                    self.menu["ui"]["text"][j] setText(self.menu[self getPrimaryMenu()]["action"][self.menu[self getPrimaryMenu()]["action"].size+(j-9)]);
                }
            }
        }
    }
}

menuBrain()
{
    self endon("menu_over");
    for(;;)
    {
        if(!isDefined(self.menu["misc"]["lock"]))
        {
            if(self attackButtonPressed() || self adsButtonPressed())
            {
                self.menu["misc"]["curs"] += self attackButtonPressed();
                self.menu["misc"]["curs"] -= self adsButtonPressed();
                if(self.menu["misc"]["curs"] < 0)
                    self.menu["misc"]["curs"] = self.menu[self getPrimaryMenu()]["action"].size-1;
                if(self.menu["misc"]["curs"] > self.menu[self getPrimaryMenu()]["action"].size-1)
                    self.menu["misc"]["curs"] = 0;

                if(self attackButtonPressed())
                    self menuMovement("down");
                if(self adsButtonPressed())
                    self menuMovement("up");

                self textFade();
                wait 0.25;
            }
            if(self useButtonPressed())
            {
                self thread [[self.menu[self getPrimaryMenu()]["key"][self getCurs()]]](self.menu[self getPrimaryMenu()]["input1"][self getCurs()], self.menu[self getPrimaryMenu()]["input2"][self getCurs()], self.menu[self getPrimaryMenu()]["input3"][self getCurs()]);
                wait .5;
            }
            if(self meleeButtonPressed())
            {
                if(!isDefined(self.menu[self getPrimaryMenu()]["back"]))
                {
                    self closeMenu();
                    break;
                }
                else
                    self newMenu(self.menu[self getPrimaryMenu()]["back"]);
                wait .5;
            }
        }
        wait .05;
    }
}

closeMenu()
{
    for(e = 0;e < 2;e++)
        self.menu["ui"]["info"][e] moveElem("x", 0.3, -500);

    self.menu["ui"]["indicator"] thread hudScale(.5, 3, 1, true);
    self destroyMenu(true);
    pos = varTok(self.menu["ui"]["bg"][0].y-(self.menu["Info Height"]["scale"]*.5), self.menu["ui"]["bg"][0].y+(self.menu["Info Height"]["scale"]*.5));
    for(j = 0;j < 2;j++)
    {
        self.menu["ui"]["bg"][j] thread hudScale(0.5, 1, ((self.menu["Menu Height"]["scale"])+3), true);wait 0.3;
    }
    wait 0.2;

    for(e = 0;e < 2;e++)
        self.menu["ui"]["title"][e] moveElem("y", 0.5, pos[e]);
    wait 0.5;

    for(e = 0;e < 2;e++)
        self.menu["ui"]["info"][e] destroy();

    self.menu["ui"]["bg"][0] = hudElem("LEFT", "center_safearea", self.menu["safeArea"][level.safe_area[0]], 0, self.menu["Menu Width"]["scale"], ((self.menu["Info Height"]["scale"])+3), (0,0,0), "white", .8, .8);

    for(e = 0;e < 2;e++)
        self.menu["ui"]["title"][e] hudScale(.1, ((self.menu["Menu Width"]["scale"])-2), ((self.menu["Info Height"]["scale"])-1));

    self menuInfo();
    self.menu["misc"]["openMenu"] = undefined;
    self thread openMenu();
    self thread meleeHold();
    self notify("menu_over");
}

destroyMenu(fade, title)
{
    if(isDefined(fade))
    {
        for(e = 0;e < 9;e++)
            self.menu["ui"]["text"][e] hudAlpha(0, 0, .2);wait .2;
    }

    for(e = 0;e < 9;e++)
        self.menu["ui"]["text"][e] destroy();

    if(isDefined(title))
    {
        for(e = 0;e < 2;e++)
        self.menu["ui"]["info"][e] destroy();
    }
}

menuMovement(movement)
{
    if(movement == "up")
    {
        move = 1;
        self.menu["misc"]["up"]--;self.menu["misc"]["down"]--;
        if(self.menu["misc"]["up"] < 0)
            self.menu["misc"]["up"] = self.menu[self getPrimaryMenu()]["action"].size-1;
        if(self.menu["misc"]["down"] < 0)
            self.menu["misc"]["down"] = self.menu[self getPrimaryMenu()]["action"].size-1;
    }
    else
    {
        move = -1;
        self.menu["misc"]["up"]++;self.menu["misc"]["down"]++;
        if(self.menu["misc"]["up"] > self.menu[self getPrimaryMenu()]["action"].size-1)
            self.menu["misc"]["up"] = 0;
        if(self.menu["misc"]["down"] > self.menu[self getPrimaryMenu()]["action"].size-1)
            self.menu["misc"]["down"] = 0;
    }
    for(m = 0;m < 9;m++)
    {
        self.menu["ui"]["text"][m] moveElem("y", 0.25, self.menu["ui"]["text"][m].y+30*move);
        if(self getUp(m))
            self.menu["ui"]["text"][m] menuMoveHud(4*30+self.menu["ui"]["indicator"].y, self.menu[self getPrimaryMenu()]["action"][self.menu["misc"]["down"]]);
        if(self getDown(m))
            self.menu["ui"]["text"][m] menuMoveHud(self.menu["ui"]["indicator"].y+30*-4, self.menu[self getPrimaryMenu()]["action"][self.menu["misc"]["up"]]);
    }
}

textFade()
{
    for(i = 0;i < 9;i++)
    {
        if(self.menu["ui"]["text"][i].y != self.menu["ui"]["indicator"].y)
            self.menu["ui"]["text"][i] hudAlpha(.5, .5, .2);
        if(self.menu["ui"]["text"][i].y == self.menu["ui"]["indicator"].y)
            self.menu["ui"]["text"][i] hudAlpha(1, 1, .2);
    }
}

menuMoveHud(y, text)
{
    self setText(text);
    self hideHud();
    self.y = y;
    self moveOverTime(.01);
}

menuInfo(text, extra)
{
    align = doTok("TOPLEFT;BOTTOMLEFT");
    if(!isDefined(text))
        info = doTok("Hold [{+melee}] To Open Menu;Entity Count: 649");
    else
        info = doTok(text);

    pos = varTok(self.menu["ui"]["title"][0].y+5, self.menu["ui"]["title"][1].y-5);
    for(e = 0;e < 2;e++)
        self.menu["ui"]["info"][e] = stringElem("objective", 1.2, align[e], "center_safearea", self.menu["safeArea"][level.safe_area[0]]+5, pos[e], info[e], 2, 2, true);

    if(isDefined(extra))
        self.menu["ui"]["info"][2] = stringElem("objective", 1.2, "LEFT", "center_safearea", self.menu["safeArea"][level.safe_area[0]]+5, 0, extra, 2, 2, true);
}

hideInfo()
{
    for(e = 0;e < 2;e++)
        self.menu["ui"]["info"][e] destroy();
    self.menu["ui"]["bg"][0] destroy();
}

quickClose()
{
    if(isDefined(self.menu["misc"]["openMenu"]) && !isDefined(level.closeMenu))
    {
        self.menu["misc"]["lock"] = true;
        level.closeMenu = true;
        self destroyMenu(0, true);
        self.menu["ui"]["indicator"] hudAlpha(0, 0, 0);
        pos = varTok(self.menu["ui"]["bg"][0].y-(self.menu["Info Height"]["scale"]*.5), self.menu["ui"]["bg"][0].y+(self.menu["Info Height"]["scale"]*.5));
        for(e = 0;e < 2;e++)
            self.menu["ui"]["title"][e] moveElem("y", 0, pos[e]);

        for(j = 0;j < 3;j++)
            self.menu["ui"]["bg"][j] thread quickScale(self.menu["ui"]["bg"][j].width, ((self.menu["Info Height"]["scale"])+3), true);
    }
}

quickOpen()
{
    if(isDefined(self.menu["misc"]["openMenu"]) && isDefined(level.closeMenu))
    {
        self.menu["misc"]["lock"] = undefined;
        level.closeMenu = undefined;
        self.menu["ui"]["indicator"] hudAlpha(1, 1, 0);
        pos = varTok(self.menu["ui"]["bg"][0].y-(self.menu["Menu Height"]["scale"]*.5), self.menu["ui"]["bg"][0].y+(self.menu["Menu Height"]["scale"]*.5));
        for(e = 0;e < 2;e++)
            self.menu["ui"]["title"][e] moveElem("y", 0, pos[e]);
        for(j = 0;j < 3;j++)
            self.menu["ui"]["bg"][j] thread quickScale(self.menu["ui"]["bg"][j].width, ((self.menu["Menu Height"]["scale"])+3), true);

        self drawMenu();
        align = doTok("BOTTOMLEFT;TOPLEFT");
        info = varTok(self.menu[self getPrimaryMenu()]["title"], "Status: Full Access");
        pos = varTok(elemArea(self.menu["ui"]["title"][0], -5, "bottom"), elemArea(self.menu["ui"]["title"][1], -5, "top"));

        for(e = 0;e < 2;e++)
            self.menu["ui"]["info"][e] = stringElem("objective", 1.8, align[e], "center_safearea", self.menu["safeArea"][level.safe_area[0]]+5, pos[e], info[e], 2, 2, true);
    }
}

menuHeading(menu, title, back)
{
    self.menu[menu]["action"] = [];
    if(isDefined(title))
        self.menu[menu]["title"] = title;
    if(isDefined(back))
        self.menu[menu]["back"] = back;
}

menuOption(menu, option, key, input1, input2, input3)
{
    j = self.menu[menu]["action"].size;
    if(isDefined(option))
        self.menu[menu]["action"][j] = option;
    if(isDefined(key))
        self.menu[menu]["key"][j] = key;
    if(isDefined(input1))
        self.menu[menu]["input1"][j] = input1;
    if(isDefined(input2))
        self.menu[menu]["input1"][j] = input2;
    if(isDefined(input3))
        self.menu[menu]["input1"][j] = input3;
}

menuOptionPlayer(menu, number, option, key, input1, input2, input3)
{
    j = self.menu[menu][number]["action"].size;
    if(isDefined(option))
        self.menu[menu][number]["action"][j] = option;
    if(isDefined(key))
        self.menu[menu]["key"][j] = key;
    if(isDefined(input1))
        self.menu[menu]["input1"][j] = input1;
    if(isDefined(input2))
        self.menu[menu]["input1"][j] = input2;
    if(isDefined(input3))
        self.menu[menu]["input1"][j] = input3;
}

newMenu(menu)
{
    self setPrimaryMenu(menu);
    self.menu["ui"]["info"][0] thread smoothHideShow(self.menu[self getPrimaryMenu()]["title"], 2);
    self destroyMenu(true);
    self drawMenu();
}

smoothHideShow(text, alpha)
{
    self hudAlpha(0, 0, .2);
    wait .2;
    self setText(text);
    if(isDefined(alpha))
        self hudAlpha(alpha, alpha, .2);
    drawOptions();
}

setPrimaryMenu(menu)
{
    self.menu["misc"]["currentMenu"] = menu;
}

getUp(array)
{
    return self.menu["ui"]["text"][array].y <= self.menu["ui"]["indicator"].y+30*-5;
}

getDown(array)
{
    return self.menu["ui"]["text"][array].y >= 5*30+self.menu["ui"]["indicator"].y;
}

getPrimaryMenu()
{
    return self.menu["misc"]["currentMenu"];
}

getCurs()
{
    return self.menu["misc"]["curs"];
}

hudElem(align, relative, x, y, width, height, color, shader, alpha, sort, foreground)
{
    hud = newClientHudElem(self);
    hud.children = [];
    hud.elemType = "bar";
    hud.align = align;
    hud.relative = relative;
    hud.previousAlpha = alpha;
    hud.previousSort = sort;
    hud.shader = shader;
    hud.width = width;
    hud.height = height;
    hud.Dwidth = width;
    hud.Dheight = height;
    hud setParent(level.hudParent);
    hud setPoint(hud.align, hud.relative, x, y);
    hud setShader(hud.shader, hud.width, hud.height);
    hud.color = color;
    hud.alpha = alpha;
    hud.sort = sort;
    if(isDefined(foreground)) hud.foreground = foreground;
    return hud;
}

stringElem(font, fontscale, align, relative, x, y, text, alpha, sort, foreground)
{
    string = self createFontString(font, fontScale, self);
    string.align = align;
    string.relative = relative;
    string.previousAlpha = alpha;
    string.previousSort = sort;
    string.text = text;
    string lettersSize();
    string setPoint(string.align, string.relative, x, y);
    string setText(string.text);
    string.alpha = alpha;
    string.sort = sort;
    if(isDefined(foreground)) string.foreground = foreground;
    return string;
}

moveElem(move, time, input)
{
    self moveOverTime(time);
    if(move == "x")
        self.x = input;
    else if(move == "y")
        self.y = input;
}

hudScale(time, width, height, destroy)
{
    self.width = width;
    self.height = height;
    self ScaleOverTime(time, self.width, self.height);
    if(isDefined(destroy))
    {
        wait time;if(self.width == 1 || self.height == 1)
        self destroy();
    }
}

quickScale(width, height)
{
    self.width = width;
    self.height = height;
    self setShader(self.shader, self.width, self.height);
}

hudAlpha(alpha, sort, time, colour)
{
    if(isDefined(time))
        self fadeOverTime(time);
    if(isDefined(colour))
        self.color = colour;
    self.previousAlpha = alpha;
    self.previousSort = sort;
    self.alpha = self.previousAlpha;
    self.sort = self.previousSort;
}

showHud(time)
{
    if(isDefined(time))
        self fadeOverTime(time);
    self.alpha = self.previousAlpha;
    self.sort = self.previousSort;
}

hideHud(time)
{
    if(isDefined(time))
        self fadeOverTime(time);
    self.alpha = 0;
    self.sort = 0;
}

lettersSize()
{
    return self.text.size;
}

customColor(R, G, B)
{
    return (((R/255), (G/255), (B/255)));
}

goldColor()
{
    return (0.760784, 0.6, 0.0745098);
}

doTok(tok)
{
    return strTok(tok, ";");
}

varTok(var1, var2, var3, var4, var5)
{
    var = [];
    if(isDefined(var1)) var[0] = var1;
    if(isDefined(var2)) var[1] = var2;
    if(isDefined(var3)) var[2] = var3;
    if(isDefined(var4)) var[3] = var4;
    if(isDefined(var5)) var[4] = var5;
    return var;
}

spawnObjPointer(origin, icon, player, color)
{
    if(isDefined(player))
        marker = newClientHudElem(player);
    else
        marker = newHudElem();
    marker.x = origin[0];
    marker.y = origin[1];
    marker.z = origin[2];
    if(isDefined(color))
        marker.color = color;
    marker.alpha = 1;
    marker setWayPoint(false, icon);
    return marker;
}

holdingMelee()
{
    return self meleeButtonPressed() && !isDefined(self.menu["misc"]["openMenu"]);
}

elemScale(elem, scale, scaleName)
{
    if(scaleName == "width") return ((elem.width)+((scale)));
    else if(scaleName == "height") return ((elem.height)+((scale)));
}

elemArea(elem, pos, axis)
{
    if(axis == "left side") return ((elem.x)-(1*((elem.width)+(pos))));
    else if(axis == "right side") return ((elem.x)+(1*((elem.width)+(pos))));
    else if(axis == "top height") return ((elem.y)-(.5*((elem.height)+(pos))));
    else if(axis == "left center") return ((elem.x)-(.5*((elem.width)+(pos))));
    else if(axis == "right center") return ((elem.x)+(.5*((elem.width)+(pos))));
    else if(axis == "bottom height") return ((elem.y)+(.5*((elem.height)+(pos))));
    else if(axis == "top") return ((elem.y)-(1*((elem.height)+(pos))));
    else if(axis == "bottom") return ((elem.y)+(1*((elem.height)+(pos))));
}

hadAccess()
{
    if(isDefined(self.menu["menu"]["hadAccess"]))return true;return false;
}

access(access)
{
    self.menu["menu"]["getAccess"] = access;
    if(self getAccess() == "AIO")
    {
        self initMenu();
    }
    else if(self getAccess() == "Limited")
    {
        self initMenu();
    }
}

accessNames()
{
    return self getAccess() == "AIO" || self getAccess() == "Limited" || self getAccess() == "Local";
}

getAccess()
{
    return self.menu["menu"]["getAccess"];
}

limitAccess()
{
    self thread closeMenu();wait 0.3;
    self access("Limited");
}

lockedMessage()
{
    self iPrintlnBold("LOCKED_MESSAGE");
}

changeBgColour(i)
{
    self.bgColour = i;
    self thread closeMenu();
}

test()
{
    self iPrintln("OPTION_WORKING");
}