prontera,155,180,5	script	Card Recycle	4_M_JOB_WIZARD,{

	mes ".::[ Card Recycle ]::."," ";
	mes "Você tem "+#Rcy_PTs+" PTs de Reciclagem, o que gostaria de fazer?";
	if(select("Reciclar Cartas:Trocar PTs")==1)
	{
		next;
		mes ".::[ Card Recycle ]::."," ";
		mes "Cards MVPs e Mini-Boss vão lhe render 10 PTs de reciclagem, as outras 1 PT (por unidade).";
		next;
		
		mes ".::[ Card Recycle ]::."," ";
		mes "O shopping de venda irá abrir, e então escolha com cuidado as cards que deseja reciclar em troca de PTs de reciclagem!";
		close2;
		callshop "shop_Rcy",2;
		end;
	}
	
	next;
	mes ".::[ Card Recycle ]::."," ";
	mes "Fique a vontade!";
	close2;
	callshop "shop_Rcy",1;
	end;
	
OnBuyItem:

	for(set .@i,0; .@i<getarraysize(@bought_nameid); set .@i,.@i+1)
	{
		for(set .@y,0; .@y<getarraysize(.RcyBIDs); set .@y,.@y+2)
		{	if(@bought_nameid[.@i] == .RcyBIDs[.@y]){	set .@total_cost,.@total_cost+(.RcyBIDs[(.@y+1)]*@bought_quantity[.@i]);	}}
	}
	
	if (#Rcy_PTs < .@total_cost){ message strcharinfo(0),"Você Não tem PTs de Reciclagem suficientes!"; end; }
	
	for (set .@i,0; .@i < getarraysize(@bought_nameid); set .@i,.@i+1)
	{	getitem @bought_nameid[.@i],@bought_quantity[.@i];	}
	
	set #Rcy_PTs,#Rcy_PTs-.@total_cost;
	message strcharinfo(0),"Compra efetuada, total do custo: "+.@total_cost+", Ainda lhe restam "+#Rcy_PTs+" PTs de Reciclagem!";
	end;	

OnSellItem:

	set .@rct,#Rcy_PTs;	
	for(set .@i,0; .@i < getarraysize(@sold_nameid); set .@i,.@i+1)
	{
		for(set .@y,0; .@y<getarraysize(.RcyIDs); set .@y,.@y+1)
		{
			if(@sold_nameid[.@i] == .RcyIDs[.@y])
			{	set #Rcy_PTs,#Rcy_PTs+(10*@sold_quantity[.@i]); delitem @sold_nameid[.@i],@sold_quantity[.@i]; set .@rcymvp,1; set .@actsel,1;	}			
		}
		
		if(getiteminfo(@sold_nameid[.@i],2)==6 && !.@rcymvp)
		{	set #Rcy_PTs,#Rcy_PTs+(1*@sold_quantity[.@i]); delitem @sold_nameid[.@i],@sold_quantity[.@i];  set .@actsel,1;	}
		
		set .@rcymvp,0;
	}
	
	if(.@actsel) dispbottom "A sua reciclagem lhe rendeu "+(#Rcy_PTs-.@rct)+", Total: "+#Rcy_PTs+" PTs";
	end;


OnInit:
/*	======================
		CONFIGURAÇÕES
	======================	*/	

//	Adicione abaixo as cartas (IDs) que terá o valor de 10 pts (as outras vão ter o valor 1).
setarray .RcyIDs[0],4372,4236;

// Adicione os IDs dos itens que vão ser vendidos (só será possível comprar com os pontos de reciclagem!)
//OBS: ID,Custo
setarray .RcyBIDs[0],645,5,12214,50,662,3;

//Attch Shopp
npcshopattach "shop_Rcy",1;
npcshopdelitem "shop_Rcy",512;

for(set .@i,0; .@i < getarraysize(.RcyBIDs); set .@i,.@i+2)
{	npcshopadditem "shop_Rcy",.RcyBIDs[.@i],.RcyBIDs[(.@i+1)];	}

end;

}

-	shop	shop_Rcy	-1,512:-1 // Não altere