makehuman 1.2.0 for arch linux

# Maintainer: Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Contributor: 3ED_0 <krzysztofas at protonmail>

pkgname=makehuman
pkgver=1.2.0
pkgrel=1
pkgdesc="Parametrical modeling program for creating human bodies"
arch=('any')
url="http://www.makehumancommunity.org/"
depends=('python-numpy' 'python-pyqt5' 'python-opengl')
makedepends=('git' 'git-lfs')
license=('AGPL3')
source=("$pkgname::git+https://github.com/makehumancommunity/makehuman.git#tag=v$pkgver"
        "makehuman.desktop"
        "makehuman.sh")
md5sums=('SKIP'
         'f54fdfbc6c783effc4624808d2547563'
         '534db191b7c6cd5cf976c9a7089b524c')

prepare() {
  cd "$pkgname"

  rm -rf "$srcdir/build"
}

build() {
  cd "$srcdir/$pkgname/buildscripts"
  cp "$srcdir/$pkgname/buildscripts/build.conf"{.example,}
  python build_prepare.py "$srcdir/makehuman" "$srcdir/build"

  cd "$srcdir/build/makehuman"
  # compile all modules so that they can be tracked by pacman
  python -m compileall .
  # and also optimize them
  python -OO -m compileall .
}

package() {
  cd "$srcdir/build/"
  install -d -m755 "$pkgdir/opt/"
  bsdtar -cf - "makehuman" | bsdtar -xf - -C "$pkgdir/opt/"

  install -D -m644 "$srcdir/build/makehuman/icons/makehuman.png" "$pkgdir/usr/share/pixmaps/makehuman.png"
  install -D -m755 "$srcdir/$pkgname.sh" "$pkgdir/usr/bin/$pkgname"
  install -D -m644 "$srcdir/$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"
}