@echo off

:start
    cls
    echo ----------------
    echo Wybierz z listy
    echo ----------------
    echo.
    echo 1) Oblicz rozmiar katalogu
    echo 2) Podaj status pliku lub katalogu
    echo 3) Dodaj nowego uzytkownika do systemu
    echo 4) Informacje o systemie
    echo 5) Wyjscie
    echo.
    set /p opcja=Wybierz opcje:
    if %opcja%==1 goto dirsize
    if %opcja%==2 goto filestatus
    if %opcja%==3 goto adduser
    if %opcja%==4 goto sysinfo
    if %opcja%==5 (
        echo Koniec
        exit
    )
    goto zly_wybor

:dirsize
    cls
    set /p dir="Podaj sciezke do katalogu: "
    dir /s %dir%
    pause
    goto start

:filestatus
    cls
    set /p file="Podaj sciezke do pliku lub katalogu: "
    icacls %file%
    pause
    goto start

:adduser
    cls
    echo Sprawdzam uprawnienia administratora...

    net session >nul 2>&1
    if %errorLevel% == 0 (
        echo Posiadasz uprawnienia administratora
    ) else (
        echo Blad: nie posiadasz wymaganych uprawnien
        pause
        goto start
    )
    set /p user="Podaj nazwe uzytkownika: "
    set /p pass="Podaj haslo: "
    net user %user% %pass% /add
    pause
    goto start

:sysinfo
    cls
    echo Uptime:
    systeminfo  | find "System Boot Time:"
    echo --------------------------
    setlocal EnableDelayedExpansion
    echo Zuzycie
    echo Zuzycie procesora %%
    for /f "skip=1" %%p in ('wmic cpu get loadpercentage') do echo %%p
    echo --------------------------
    echo Najbardziej zasobozerne procesy
    (for /F "skip=1 tokens=1,2" %%a in ('wmic process get name^,workingsetsize') do (
    set "size=         %%b"
    echo !size:~-10!    %%a
    )) > wmic.txt
    set i=0
    for /F "skip=1 delims=" %%a in ('sort /R wmic.txt') do (
    echo %%a
    set /A i+=1
    if !i! equ 10 goto :end
    )
    :end
    del wmic.txt
    pause
    goto start

:zly_wybor
    echo Bledny wybor. Sprobuj ponownie.
    pause
    goto start