;==================================
; Script Name: Mine All Can See
; Author: Vostran
; Version: 1.0.3 (stripped and released)
; Client Tested with: 3.0.0c
; EUO version tested with: 1.33
; Shard OSI / FS: Free Shard (Deusovis)
; Revision Date: 08th Febuary 2004
; Public Release: 17th January 2004
; Global Variables Used: none
; Purpose: Written specifically for a Deusovis, it mines all the ore from a cave floor, stopping when you're full. It's intentionally simple and should remain that way.
;==================================
initialise:
initevents
config:
;   This can be set a few ways, remember to comment out the way you don't want it set. Must be set atleast one way.
;   set %maxweight #maxweight - 50
;   set %maxweight 300
   set %maxweight #maxweight

;   if raresonly is 1 then it will ignore the lesser ores and gold coins it finds, soon gems to.
   set %raresonly 0
;   if raresonly is 1 then these will determine which ores are not skipped, set to -1 to skip, 1 to mine.
   set %rusty -1
   set %iron -1
   set %copper -1
   set %bronze -1
   set %silver -1
   set %pure -1

;   Set this option to halt once you mined the 9x9 box you're standing in, so you can move and press play again to continue.
   set %pausePerPass 0

;   Will attempt to hide if this is 1.
   set %hide 0

;   Higher number for busier mines.
   set %scanjournalloops 100

start:
   gosub mineallhere
goto start

sub mineallhere
   for %mineloopX -4 4
   {
      for %mineloopY -4 4
      {
         set %mineX #CHARPOSX
         set %mineY #CHARPOSY
         set %mineX %mineX + %mineloopX
         set %mineY %mineY + %mineloopY
         event sysMessage %mineX %mineY
         gosub mineXY %mineX %mineY
         if #weight > %maxweight
         {
            gosub hide
            halt
         }
      }
   }
   if %pausePerPass = 1
   {
      event sysMessage Pausing because we've mined this area dry.
      gosub hide
      pause
   }
return
sub mineXY
   set %success 1
   for %mineloop 1 -1
   {
      gosub hide
      finditem NPF_TWF_QPF_WWF
      set #lobjectid #findid
      event macro 17 0
      set #lTargetKind 2
      set #lTargetX %1
      set #lTargetY %2
      target
      event macro 22
      scanJournal 0
      deleteJournal
      event sysMessage
      wait 20
      for %journalloop 0 %scanjournalloops
      {
         scanjournal %journalloop
         if there_is_no_ore_here in #journal
         {
            set %journalloop %scanjournalloops
            set %mineloop -1
            set %success 0
         }
         if that_is_too_far_away in #journal
         {
            set %journalloop %scanjournalloops
            set %mineloop -1
            set %success 0
         }
         if no_line_of_sight in #journal
         {
            set %journalloop %scanjournalloops
            set %mineloop -1
            set %success 0
         }
         if try_mining_in_rock in #journal
         {
            set %journalloop %scanjournalloops
            set %mineloop -1
            set %success 0
         }
      }
      if %success = 1
      {
         wait 130
         for %journalloop 0 %scanjournalloops
         {
            scanjournal %journalloop
            if you_loosen_some_rocks_but_fail in #journal
            {
               set %journalloop %scanjournalloops
               set %mineloop 1
            }
            if you_put_the in #journal
            {
               set %journalloop %scanjournalloops
               set %mineloop 1
               if %raresonly = 1
               {
                  if rusty in #journal
                  {
                     set %mineloop %rusty
                  }
                  if iron in #journal
                  {
                     set %mineloop %iron
                  }
                  if copper in #journal
                  {
                     if chrome notin #journal
                     {
                        set %mineloop %copper
                     }
                  }
                  if bronze in #journal
                  {
                     set %mineloop %bronze
                  }
                  if silver in #journal
                  {
                     set %mineloop %silver
                  }
                  if pure in #journal
                  {
                     set %mineloop %pure
                  }
                  if gold_coin_in in #journal
                  {
                     set %mineloop -1
                  }
               }
            }
            if previous_targeting_cancelled in #journal
            {
               set %journalloop %scanjournalloops
               set %mineloop 1
            }
         }
      }
   }
return
sub hide
   if %hide = 1
   {
      if H notin #charstatus
      {
         event macro 13 21
         wait 65
         gosub hide
      }
   }
return